*** Settings ***
Documentation     Notification des demandeurs via le portail citoyen -
...  Tests dédiés aux validations du message de confirmation lorsqu'on
...  clique sur l'action de notification.

# On inclut les mots-clefs
Resource    resources/resources.robot
# On ouvre et on ferme le navigateur respectivement au début et à la fin
# du Test Suite.
Suite Setup    For Suite Setup
Suite Teardown    For Suite Teardown

*** Test Cases ***
Constitution du jeu de données
    [Documentation]  L'objet de ce 'Test Case' est de constituer le jeu de données
    Run Keyword If  '${CONTEXT_NOTIFICATION_CREATED}' == 'False'  Constitution du jeu de données - Notification
    Set Global Variable  ${CONTEXT_NOTIFICATION_CREATED}  True

    Construction du Parametrage - Notification

Activation de la notification par le portail citoyen
    [Documentation]  Activation de la notification par le portail citoyen

    # Modification du paramétrage de notification
    &{param_args} =  Create Dictionary
    ...  libelle=option_notification
    ...  valeur=portal
    ...  om_collectivite=LIBRECOM_NOTIFDEM
    Gerer le paramètre par WS  ${param_args}
    # Ajout de l'option_bloquer_notif_auto_dln avec une erreur sur le type
    &{om_param} =  Create Dictionary
    ...  libelle=option_bloquer_notif_auto_dln
    ...  valeur=incompletude;majorasmask_delai
    ...  om_collectivite=agglo
    Gerer le paramètre par WS  ${om_param}

    Set Suite Variable  ${message_confirmation}  Êtes-vous sûr de vouloir effectuer cette action ?
    Set Suite Variable  ${message_confirmation_hors_delai}  Vous êtes sur le point de notifier un document alors que la date limite d’instruction est dépassée.

Notification automatique avec l'option_bloquer_notif_auto_dln et une finalisation
    [Documentation]  Vérifie le bon fonctionnement de la notification automatique
    ...  via le portail citoyen des demandeurs
    Depuis la page d'accueil  mpaulet  mpaulet

    &{args_petitionnaire_principal} =  Create Dictionary
    ...  particulier_nom=Desoptions
    ...  particulier_prenom=finalise
    ...  om_collectivite=LIBRECOM_NOTIFDEM
    ...  courriel=sdesjardins@notif.fr
    ...  notification=t

    &{args_petitionnaire1} =  Create Dictionary
    ...  particulier_nom=Avecoption
    ...  particulier_prenom=Finalise
    ...  om_collectivite=LIBRECOM_NOTIFDEM
    ...  courriel=rboisclair@notif.fr
    ...  notification=t

    &{args_autres_demandeurs} =  Create Dictionary
    ...  petitionnaire=${args_petitionnaire1}
    
    &{args_demande} =  Create Dictionary
    ...  dossier_autorisation_type_detaille=Permis de construire pour une maison individuelle et / ou ses annexes
    ...  demande_type=Dépôt Initial
    ...  om_collectivite=LIBRECOM_NOTIFDEM
    ...  depot_electronique=true
    ...  date_demande=${date_ddmmyyyy}
    ${di_notif_auto_mauvais_param} =  Ajouter la demande par WS  ${args_demande}  ${args_petitionnaire_principal}  ${args_autres_demandeurs}

    &{args_demande} =  Create Dictionary
    ...  dossier_autorisation_type_detaille=Permis de construire pour une maison individuelle et / ou ses annexes
    ...  demande_type=Dépôt Initial
    ...  om_collectivite=LIBRECOM_NOTIFDEM
    ...  depot_electronique=true
    ...  date_demande=01/01/2018
    ${di_notif_hors_date} =  Ajouter la demande par WS  ${args_demande}  ${args_petitionnaire_principal}  ${args_autres_demandeurs}

    # Ajout de l'instruction de notification automatique sans la finaliser pour vérifier
    # que l'action d'envoi manuelle de la notification n'est pas visible
    Ajouter une instruction au DI  ${di_notif_auto_mauvais_param}  TEST_NOTIF_AUTO_OPTION_BLOQUER_DLN_FINALISE
    Portlet Action Should Not Be In SubForm  instruction  notification_manuelle_portal
    # Finalisation de l'instruction ce qui doit déclencher l'envoi de la notification automatique
    Depuis l'instruction du dossier d'instruction  ${di_notif_auto_mauvais_param}  TEST_NOTIF_AUTO_OPTION_BLOQUER_DLN_FINALISE
    Click On SubForm Portlet Action  instruction  finaliser
    One Of Messages Should Be  La notification a été générée.

    # Rétablissement du paramètre
    Depuis la page d'accueil  admin  admin
    &{om_param} =  Create Dictionary
    ...  libelle=option_bloquer_notif_auto_dln
    ...  valeur=incompletude;majoration_delai
    ...  om_collectivite=agglo
    Gerer le paramètre par WS  ${om_param}
    
    ## Test de la condition de date ##
    Depuis la page d'accueil  mpaulet  mpaulet
    # Ajout de l'instruction de notification automatique sans la finaliser pour vérifier
    # que l'action d'envoi manuelle de la notification n'est pas visible
    Ajouter une instruction au DI  ${di_notif_hors_date}  TEST_NOTIF_AUTO_OPTION_BLOQUER_DLN_FINALISE
    Portlet Action Should Not Be In SubForm  instruction  notification_manuelle_portal
    # Finalisation de l'instruction ce qui doit déclencher l'envoi de la notification automatique
    Depuis l'instruction du dossier d'instruction  ${di_notif_hors_date}  TEST_NOTIF_AUTO_OPTION_BLOQUER_DLN_FINALISE
    Click On SubForm Portlet Action  instruction  finaliser
    One Of Messages Should Be  La notification n'a pas été générée, car la date limite de notification au demandeur est dépassée.
    Element Should Contain  css=#suivi_notification_jsontotab table tbody tr td:nth-child(6)  Echec
    Element Should Contain  css=#suivi_notification_jsontotab table tbody tr td:nth-child(7)  La date limite de notification au demandeur est dépassée

Notification automatique avec l'option_bloquer_notif_auto_dlnet et un retour signature
    [Documentation]  Vérifie le bon fonctionnement de la notification automatique
    ...  via le portail citoyen des demandeurs
    Depuis la page d'accueil  admin  admin

    # Ajout d'un dossier et d'une instruction de notification auto
    # Seul le pétitionnaire principal a un courriel et accepte les notification
    # c'est donc le seul pétitionnaire qui devra être notifié
    &{args_petitionnaire_principal} =  Create Dictionary
    ...  qualite=personne morale
    ...  personne_morale_denomination=Denomination
    ...  personne_morale_nom=Tabor
    ...  personne_morale_prenom=Phaneuf
    ...  om_collectivite=LIBRECOM_NOTIFDEM
    ...  courriel=tphaneuf@notif.fr
    ...  notification=t

    &{args_petitionnaire1} =  Create Dictionary
    ...  qualite=personne morale
    ...  personne_morale_raison_sociale=raison sociale
    ...  personne_morale_nom=Labrosse
    ...  personne_morale_prenom=Patrick
    ...  om_collectivite=LIBRECOM_NOTIFDEM
    ...  courriel=plabosse@notif.fr
    ...  notification=t

    &{args_autres_demandeurs} =  Create Dictionary
    ...  petitionnaire=${args_petitionnaire1}

    &{args_demande} =  Create Dictionary
    ...  dossier_autorisation_type_detaille=Permis de construire pour une maison individuelle et / ou ses annexes
    ...  demande_type=Dépôt Initial
    ...  date_demande=01/01/2018
    ...  om_collectivite=LIBRECOM_NOTIFDEM
    ...  depot_electronique=true
    ${di_notif_auto1} =  Ajouter la demande par WS  ${args_demande}  ${args_petitionnaire_principal}  ${args_autres_demandeurs}

    # Ajout de l'instruction de notification automatique avec lettretype avec signature
    # La notification doit se faire à l'ajout de la date de retour
    Ajouter une instruction au DI et la finaliser  ${di_notif_auto1}  TEST_NOTIF_AUTO_OPTION_BLOQUER_DLN_RETOUR_SIGNATURE
    Depuis l'instruction du dossier d'instruction  ${di_notif_auto1}  TEST_NOTIF_AUTO_OPTION_BLOQUER_DLN_RETOUR_SIGNATURE
    Portlet Action Should Not Be In SubForm  instruction  notification_manuelle_portal
    Page Should Not Contain Element  css=fieldset#fieldset-sousform-instruction-suivi-notification
    # Remplissage de la date de retour de signature
    ${date_retour_sign} =  Convert Date  ${DATE_FORMAT_YYYY-MM-DD}  result_format=%d/%m/%Y
    Click On SubForm Portlet Action  instruction  modifier_suivi
    Input Datepicker  date_retour_signature  ${date_retour_sign}
    Click On Submit Button In Subform

    One Of Messages Should Be  La notification n'a pas été générée, car la date limite de notification au demandeur est dépassée.
    Element Should Contain  css=#suivi_notification_jsontotab table tbody tr td:nth-child(6)  Echec
    Element Should Contain  css=#suivi_notification_jsontotab table tbody tr td:nth-child(7)  La date limite de notification au demandeur est dépassée


Notification manuelle via portal - Demande de confirmation - Date limite d'instruction non dépassée
    [Documentation]  Avec un profil instructeur, depuis le contexte d'un dossier en cours,
    ...   lors de la notification d'une instruction via le portail citoyen, vérifie le
    ...   contenu du message de demande de confirmation.

    # Ajout d'un dossier et d'une instruction notifiable
    &{args_petitionnaire} =  Create Dictionary
    ...  particulier_nom=145_02
    ...  particulier_prenom=MSG_CONF_DATE_LIM_INSTR_OK
    ...  om_collectivite=LIBRECOM_NOTIFDEM
    ...  courriel=mail@notif.fr
    ...  notification=t
    &{args_demande} =  Create Dictionary
    ...  dossier_autorisation_type_detaille=Permis de construire pour une maison individuelle et / ou ses annexes
    ...  demande_type=Dépôt Initial
    ...  om_collectivite=LIBRECOM_NOTIFDEM
    ...  depot_electronique=true
    ${di_msg_conf_1} =  Ajouter la demande par WS  ${args_demande}  ${args_petitionnaire}

    Depuis la page d'accueil  mpaulet  mpaulet
    Ajouter une instruction au DI et la finaliser  ${di_msg_conf_1}  TEST_NOTIF_MAN_LETTRETYPE

    # Clique sur l'action de notification et vérifie le contenu du message
    Click On SubForm Portlet Action  instruction  notification_manuelle_portal  modale
    Le message de demande de confirmation doit contenir  ${message_confirmation}
    La page ne doit pas contenir d'erreur

    # Clique sur confirmer pour fermer la modale et ne pas risquer d'impacter les
    # autre test. Vérifie également que le déclenchement du traitement n'entraine
    # pas d'erreur.
    Cliquer sur le bouton de la fenêtre modale  Confirmer
    La page ne doit pas contenir d'erreur

Notification manuelle via portal - demande de confirmation - Date limite d'instruction dépassée
    [Documentation]  Avec un profil instructeur, depuis le contexte d'un dossier dont la date
    ...  limite d'instruction est dépassé, lors de la notification d'une instruction via
    ...  le portail citoyen, vérifie le contenu du message de demande de confirmation.

    # Ajout d'un dossier et d'une instruction notifiable
    # La date de dépôt du dossier fait que sa date limite d'instruction est déjà dépassée
    &{args_petitionnaire} =  Create Dictionary
    ...  particulier_nom=145_02
    ...  particulier_prenom=MSG_CONF_HORS_DELAI
    ...  om_collectivite=LIBRECOM_NOTIFDEM
    ...  courriel=mail@notif.fr
    ...  notification=t
    &{args_demande} =  Create Dictionary
    ...  dossier_autorisation_type_detaille=Permis de construire pour une maison individuelle et / ou ses annexes
    ...  demande_type=Dépôt Initial
    ...  om_collectivite=LIBRECOM_NOTIFDEM
    ...  depot_electronique=true
    ...  date_demande=01/01/2024
    ${di_msg_conf_2} =  Ajouter la demande par WS  ${args_demande}  ${args_petitionnaire}

    Depuis la page d'accueil  mpaulet  mpaulet
    Ajouter une instruction au DI et la finaliser  ${di_msg_conf_2}  TEST_NOTIF_MAN_LETTRETYPE

    # Clique sur l'action de notification et vérifie le contenu du message
    Click On SubForm Portlet Action  instruction  notification_manuelle_portal  modale
    Le message de demande de confirmation doit contenir  ${message_confirmation_hors_delai}
    La page ne doit pas contenir d'erreur

    # Clique sur confirmer pour fermer la modale et ne pas risquer d'impacter les
    # autre test. Vérifie également que le déclenchement du traitement n'entraine
    # pas d'erreur.
    Cliquer sur le bouton de la fenêtre modale  Confirmer
    La page ne doit pas contenir d'erreur

Reset Params - TNR Message lorsque la notification n'est pas possible

    Destruction du Parametrage - Notification

    # Suppression du paramètre de notification
    &{param_args} =  Create Dictionary
    ...  delete=true
    ...  libelle=option_notification
    ...  om_collectivite=LIBRECOM_NOTIFDEM
    Gerer le paramètre par WS   ${param_args}

    # Suppression du paramètre option_bloquer_notif_auto_dln
    &{param_args} =  Create Dictionary
    ...  delete=true
    ...  libelle=option_bloquer_notif_auto_dln
    ...  om_collectivite=agglo
    Gerer le paramètre par WS   ${param_args}