#
# Description
#
# @package openads
# @version SVN : $Id $
#

*** Settings ***
Documentation  Test les pièces numérisées et leur historisations.

# On inclut les mots-clefs
Resource  resources/resources.robot
# On ouvre/ferme le navigateur au début/à la fin du Test Suite.
Suite Setup  For Suite Setup
Suite Teardown  For Suite Teardown

*** Keywords ***

Retour signature
    [Arguments]    ${di}
    [Documentation]  L'objet de ce 'Test Case' est d'eviter d'avoir des bloc de code
    ...  identique en realisant la tache d'ajouter une infinité de fichier en retour signature.
    ...
    ...  ! WARNING !
    ...  Ce code n'est pas fou mais c'est parce que ce que le test case
    ...  veut faire n'est pas possible car le bouton submit n'est plus
    ...  trouvable par le robot.
    ...  ! WARNING !  
    ...  
    ...  A ameliorer, faire une boucle avec en valeur entrée un tableau des fichiers

    Depuis l'onglet instruction du dossier d'instruction  ${di}
    Click On Link  Notification du delai legal maison individuelle
    Click On SubForm Portlet Action  instruction  modale_selection_document_signe  modale
    Wait Until Page Contains Element  css=input#modale_date_retour_signature

*** Test Cases ***
Constitution d'un jeu de données

    [Documentation]  L'objet de ce 'Test Case' est de constituer un jeu de de
    ...  données cohérent pour les scénarios fonctionnels qui suivent.

    &{om_param} =  Create Dictionary
    ...  libelle=option_notification_piece_numerisee
    ...  valeur=true
    ...  om_collectivite=agglo
    Gerer le paramètre par WS  ${om_param}

    # Liste des arguments pour la demande
    &{args_demande} =  Create Dictionary
    ...  dossier_autorisation_type_detaille=Permis de construire pour une maison individuelle et / ou ses annexes
    ...  demande_type=Dépôt Initial
    ...  om_collectivite=MARSEILLE
    # Liste des arguments pour le pétitionnaire
    &{args_petitionnaire} =  Create Dictionary
    ...  particulier_civilite=Madame
    ...  particulier_nom=Histo
    ...  particulier_prenom=Rie
    ...  om_collectivite=MARSEILLE
    #
    ${di} =  Ajouter la demande par WS  ${args_demande}  ${args_petitionnaire}
    #

    # Les dossiers sont accessibles dans la suite du test
    Set Suite Variable  ${di}

Test historisation
    [Documentation]  L'objet de ce 'Test Case' est de tester
    ...  l'historisation et la bonne nomenclature lors des retours signatures.

    # Connexion à l'admin et à la page du dossier d'instruction
    Depuis la page d'accueil  admin  admin

    # Liste des arguments pour la demande
    &{args_demande} =  Create Dictionary
    ...  dossier_autorisation_type_detaille=Permis de construire pour une maison individuelle et / ou ses annexes
    ...  demande_type=Dépôt Initial
    ...  om_collectivite=MARSEILLE
    # Liste des arguments pour le pétitionnaire
    &{args_petitionnaire} =  Create Dictionary
    ...  particulier_civilite=Madame
    ...  particulier_nom=Histo
    ...  particulier_prenom=Rique
    ...  om_collectivite=MARSEILLE
    ${di_th} =  Ajouter la demande par WS  ${args_demande}  ${args_petitionnaire}

    Retour signature  ${di_th}
    Wait Until Keyword Succeeds  ${TIMEOUT}  ${RETRY_INTERVAL}  Add File  document_signe  document_1_test_retour_signature.pdf
    Click On Submit Button In Subform
    
    Retour signature  ${di_th}
    Wait Until Keyword Succeeds  ${TIMEOUT}  ${RETRY_INTERVAL}  Add File  document_signe  document_2_test_retour_signature.pdf
    Click On Submit Button In Subform

    Retour signature  ${di_th}
    Wait Until Keyword Succeeds  ${TIMEOUT}  ${RETRY_INTERVAL}  Add File  document_signe  document_3_test_retour_signature.pdf
    Click On Submit Button In Subform

    # Ajout des nouveau document
    Depuis l'onglet des pièces du dossier d'instruction  ${di_th}
    # Verifier que le document historiser n'est pas présent dans les téléchargements
    Click Element Until New Element
    ...    css=div[data-view="document_instruction"]
    ...    css=div.switcher__label.onglet_active[data-view="document_instruction"]

    Page Should Contain  document_1_test_retour_signature
    Page Should Contain  document_2_test_retour_signature

Test la création du fichier historiser lors de l'import d'un document signé

    # Connexion à l'admin et à la page du dossier d'instruction
    Depuis la page d'accueil  admin  admin    
    Depuis l'onglet instruction du dossier d'instruction  ${di}

    # Acceder a l'intruction
    Click On Link  Notification du delai legal maison individuelle

    # On accède à la modale de modification du document
    Click On SubForm Portlet Action  instruction  modale_selection_document_signe  modale
    Wait Until Page Contains Element  css=input#modale_date_retour_signature

    # Ajout de la date de retour signature
    ${date_retour_sign} =  Convert Date  ${DATE_FORMAT_YYYY-MM-DD}  result_format=%d/%m/%Y
    Input Datepicker  modale_date_retour_signature  ${date_retour_sign}

    # Ajout du nouveau document
    Add File  document_signe  testImportManuel.pdf

    # Validation de l'ajout
    Click On Submit Button In Subform

    # Vérification de réussite
    Valid Message Should Contain  Le document a bien été mis à jour.

    # On ferme la modale
    Click Element Until No More Element  css=.ui-dialog-titlebar-close

    # On vérifie que la date de retour signature s'est bien mise à jour
    Wait Until Element Contains  css=#date_retour_signature  ${date_retour_sign}

    # On se préparer à verifier les pièces
    Depuis l'onglet des pièces du dossier d'instruction  ${di}

    # Verifier que le document historiser n'est pas présent dans les téléchargements
    Click Element Until New Element
    ...    css=div[data-view="document_numerise_telechargement"]
    ...    css=div.switcher__label.onglet_active[data-view="document_numerise_telechargement"]
    La page ne doit pas contenir d'erreur
    Page Should Not Contain  _remplace_le_

    # Vérifier que le document historisée n'est pas présent dans l'onglet dossier final
    Click Element Until New Element
    ...    css=div[data-view="document_numerise_dossier_final"]
    ...    css=div.switcher__label.onglet_active[data-view="document_numerise_dossier_final"]
    La page ne doit pas contenir d'erreur
    Page Should Not Contain  _remplace_le_

    # Vérifier que le document historisée est présent dans les documents intruction 
    # Accéder à l'onglet documents de l'onglet pièces par le dossier d'instruction  ${di}
    Click Element Until New Element
    ...    css=div[data-view="document_instruction"]
    ...    css=div.switcher__label.onglet_active[data-view="document_instruction"]
    La page ne doit pas contenir d'erreur

    Click Element  partial link: _remplace_le_
    Open PDF  ${OM_PDF_TITLE}
    PDF Page Number Should Contain  1  Permis de construire pour une maison individuelle et / ou ses annexes
    Close PDF

Reset du jeu de données
    &{param} =  Create Dictionary
    ...  delete=true
    ...  libelle=option_notification_piece_numerisee
    ...  om_collectivite=agglo
    Gerer le paramètre par WS  ${param}