*** Settings ***
Documentation  Gestion des consultations.

# On inclut les mots-clefs
Resource  resources/resources.robot
# On ouvre/ferme le navigateur au début/à la fin du Test Suite.
Suite Setup  For Suite Setup
Suite Teardown  For Suite Teardown

*** Variables ***
${json_consultation}  {"module":"consultation"}


*** Test Cases ***
Les services proposés pour la consultation d'un dossier non transmissible à Plat'AU ne doivent pas être des services de type Plat'AU
    [Documentation]  Lors de l'instruction d'un dossier non-transmissible à Plat'AU, 
    ...  dans l'onglet Consultations, la selection de services disponibles 
    ...  après avoir appuyé sur + ne doit pas proposer de services de type Plat'AU.

    &{args_petitionnaire} =  Create Dictionary
    ...  particulier_nom=081SelectServiceNonPlatauNom
    ...  particulier_prenom=081SelectServiceNonPlatauPrenom
    ...  om_collectivite=MARSEILLE
    &{args_demande} =  Create Dictionary
    ...  dossier_autorisation_type_detaille=Permis de construire pour une maison individuelle et / ou ses annexes
    ...  demande_type=Dépôt Initial
    ...  om_collectivite=MARSEILLE
    ${di} =  Ajouter la demande par WS  ${args_demande}  ${args_petitionnaire}

    Depuis la page d'accueil  admin  admin

    Ajouter une consultation depuis l'onglet du dossier d'instruction  ${di}
    Wait Until Element Is Visible  service
    @{select_service} =  Get List Items  service
    Should Contain Match  ${select_service}  1ER - Maire 1er Secteur

    # On modifie le type de service choisi vers un type Plat'AU
    &{args_service} =  Create Dictionary
    ...  service_type=Plat'AU
    Modifier le service  1ER  Maire 1er Secteur  ${args_service}

    # On vérifie que le 'select' des services disponibles à la consultation pour le dossier PCI utilisé, 
    # ne contient pas le service choisi (1ER - Mairie 1er Secteur)
    Ajouter une consultation depuis l'onglet du dossier d'instruction  ${di}
    Wait Until Element Is Visible  service
    @{select_service} =  Get List Items  service
    Should Not Contain Match  ${select_service}  1ER - Maire 1er Secteur

    # On affiche le Statut Plat'AU du dossier d'autorisation détaillés utilisés : PCI qui n'est Jamais transmissible à Plat'AU
    &{args_type_DA_detaille_modification} =  Create Dictionary
    ...  dossier_platau=true
    Modifier type de dossier d'autorisation détaillé  PCI  ${args_type_DA_detaille_modification}

    # On vérifie que le 'select' des services disponibles à la consultation pour le dossier PCI utilisé, 
    # ne contient toujours pas le service choisi (1ER - Mairie 1er Secteur)
    Ajouter une consultation depuis l'onglet du dossier d'instruction  ${di}
    Wait Until Element Is Visible  service
    @{select_service} =  Get List Items  service
    Should Not Contain Match  ${select_service}  1ER - Maire 1er Secteur


Reset Params - Les services proposés pour la consultation d'un dossier non transmissible à Plat'AU ne doivent pas être des services de type Plat'AU
    # On retire l'affichage du Statut Plat'AU du dossier d'autorisation détaillés utilisés
    &{args_type_DA_detaille_modification} =  Create Dictionary
    ...  dossier_platau=false
    Modifier type de dossier d'autorisation détaillé  PCI  ${args_type_DA_detaille_modification}

    # On remodifie le type de service choisi vers un type openADS
    &{args_service} =  Create Dictionary
    ...  service_type=openADS
    Modifier le service  1ER  Maire 1er Secteur  ${args_service}


L'ajout de consultation à des tiers ne dois pas être possible si aucun tiers n'est paramétré
    [Documentation]  Dans le cas, où aucun tiers n'a été paramétré, le + bleu
    ...  servant à ajouter une consultation vers un tiers ne dois pas apparaître
    ...  dans l'onglet consultation.

    # Ajout d'un nouveau dossier et accès à l'onglet consultation
    &{args_petitionnaire} =  Create Dictionary
    ...  particulier_nom=080btnbleuNom
    ...  particulier_prenom=080btnbleuPrenom
    ...  om_collectivite=MARSEILLE
    &{args_demande} =  Create Dictionary
    ...  dossier_autorisation_type_detaille=Permis de construire pour une maison individuelle et / ou ses annexes
    ...  demande_type=Dépôt Initial
    ...  om_collectivite=MARSEILLE
    ${di} =  Ajouter la demande par WS  ${args_demande}  ${args_petitionnaire}

    # Comme il n'y a pas de tiers consulté l'icone d'ajout ne dois pas être affichée
    Depuis la page d'accueil  instr  instr
    Depuis l'onglet consultation du dossier  ${di}
    Page Should Not Contain Element  css=a#action-soustab-consultation-corner-ajouter_consultation_tiers

    # Ajout de tiers consulté
    Depuis la page d'accueil  admin  admin
    &{args_tiers} =  Create Dictionary
    ...  categorie_tiers_consulte=Catégorie Marseille
    ...  abrege=TNR_ACT
    ...  libelle=TNR ajout consultation tiers
    Ajouter le tiers consulte depuis le listing  ${args_tiers}
    # Comme il y a des tiers consulté l'icone d'ajout dois être affichée
    Depuis la page d'accueil  instr  instr
    Depuis l'onglet consultation du dossier  ${di}
    Page Should Contain Element  css=a#action-soustab-consultation-corner-ajouter_consultation_tiers


Mise en places du jeu de données Consultation
    [Documentation]  L'objet de ce 'Test Case' est de constituer le jeu de données

    Initialisation Variables Consultation

    Run Keyword If  '${CONTEXT_CONSULTATION_1_CREATED}' == 'False'  Initialisation du jeu de données Consultation 1er tier
    Set Global Variable  ${CONTEXT_CONSULTATION_1_CREATED}  True


TNR Routine de mise à jour des consultations tacites

    [Documentation]  Permet de vérifier l'état des consultations après le
    ...  traitement tacite.
    ...  Attention ! ce test est en premier car il utilise les données du init_data
    ...  il est nécessaire d'améilorer ce point

    # Isolation d'un contexte
    &{isolation_values} =  Create Dictionary
    ...  om_collectivite_libelle=MIROUFCITY
    ...  departement=013
    ...  commune=188
    ...  insee=13018
    ...  direction_code=MIROUF
    ...  direction_libelle=Direction de MIROUFCITY
    ...  direction_chef=Chef
    ...  division_code=MIROUF
    ...  division_libelle=Division MIROUF
    ...  division_chef=Chef
    ...  guichet_om_utilisateur_nom=Sylvain Mirouf
    ...  guichet_om_utilisateur_email=smirouf@openads-test.fr
    ...  guichet_om_utilisateur_login=smirouf
    ...  guichet_om_utilisateur_pwd=smirouf
    ...  instr_om_utilisateur_nom=Pom Pote
    ...  instr_om_utilisateur_email=pompote@openads-test.fr
    ...  instr_om_utilisateur_login=pompote
    ...  instr_om_utilisateur_pwd=pompote
    Isolation d'un contexte  ${isolation_values}
    
    Modifier l'utilisateur
    ...  ${isolation_values.instr_om_utilisateur_nom}
    ...  ${isolation_values.instr_om_utilisateur_email}
    ...  ${isolation_values.instr_om_utilisateur_login}
    ...  ${isolation_values.instr_om_utilisateur_pwd}
    ...  ADMINISTRATEUR TECHNIQUE ET FONCTIONNEL

    # Création de dossiers dans le profil isolé :
    # Création d'un dossier et ajout d'un tiers consulté avec un délais pour tester le tacite
    &{args_petitionnaire} =  Create Dictionary
    ...  particulier_nom=TACITA
    ...  particulier_prenom=Louise
    ...  om_collectivite=MARSEILLE
    &{args_demande} =  Create Dictionary
    ...  dossier_autorisation_type_detaille=Permis de construire pour une maison individuelle et / ou ses annexes
    ...  demande_type=Dépôt Initial
    ...  date_demande=12/04/2015
    ...  om_collectivite=MARSEILLE
    ${di_tacite_tiers} =  Ajouter la demande par WS  ${args_demande}  ${args_petitionnaire}

    # Création du tiers a consulter et d'un utilisateur lié
    Depuis la page d'accueil  admin  admin

    ${tiers_1} =  Create Dictionary
    ...  categorie_tiers_consulte=Catégorie Marseille
    ...  tiers_consulte=TM1 - 1er tiers de Marseille
    ...  motif_consultation=Premier motif de consultation
    ...  date_envoi=12/04/2015
    Ajouter une consultation vers un tiers depuis un dossier  ${di_tacite_tiers}  ${tiers_1}

    # On exécute le WS de mise à jour des consultations
    Vérifier le code retour du web service et vérifier que son message est  Post  maintenance  ${json_consultation}  200  3 consultations mise(s) à jour.

    # On vérifie que la valeur de la consultation qui a été passée en tacite
    # est bien marquée comme 'non lu'
    # Définition de l'id du widget des retours de consultation du profil INSTRUCTEUR
    ${widget_id} =  Set Variable  widget_3
    # En tant que profil 'INSTRUCTEUR'
    Depuis la page d'accueil  instr  instr
    # On vérifie que les consultations apparaissent bien sur le tableau de bord de l'instructeur
    # Element Should Contain  css=#${widget_id} .widget-content-wrapper span.box-icon  2
    # On clique sur le lien "Voir +" du widget
    Click Element  css=#${widget_id} .widget-footer a
    # On accède au listing des restours de consultation
    Le titre de la page doit être  Instruction > Consultations > Mes Retours
    Page Should Contain  ${di_tacite_tiers}
    # On clique sur le dossier en question
    Click On Link  PC 013055 12 00002P0

    # On vérifie que les champs ont bien été mis à jour par le webservice
    Wait Until Keyword Succeeds  ${TIMEOUT}  ${RETRY_INTERVAL}  Form Static Value Should Be  css=#lu  Non
    Form Static Value Should Be  css=#avis_consultation  Tacite
    Form Static Value Should Be  css=#date_retour  01/02/2013


TNR les catégories tiers consultés correspondent au service utilisateur
    [Documentation]  Test lors de l'ajout de la consultation d'un tiers,
    ...  si les catégories de tiers consultés affichées sont uniquement
    ...  celles liées au même service (collectivité) que celui 
    ...  du dossier d'instruction en cours
    
    Depuis la page d'accueil  admin  admin

    # Création d'un dossier
    &{args_petitionnaire} =  Create Dictionary
    ...  particulier_nom=TESTCATETIERSNOM
    ...  particulier_prenom=TESTCATETIERSPRENOM
    ...  om_collectivite=MARSEILLE
    &{args_demande} =  Create Dictionary
    ...  dossier_autorisation_type_detaille=Certificat d'urbanisme
    ...  demande_type=Dépôt Initial
    ...  om_collectivite=MARSEILLE
    ${di} =  Ajouter la demande par WS  ${args_demande}  ${args_petitionnaire}
   
    # Création et ajout du tiers
    &{args_tiers} =  Create Dictionary
    ...  categorie_tiers_consulte=Catégorie Marseille
    ...  abrege=TNR_CATEGORIES_TIERS
    ...  libelle=Test catégories tiers et collectivités
    Ajouter le tiers consulte depuis le listing  ${args_tiers}
    
    # Vérification de l'absence d'une catégorie non référente au dossier en cours (ALLAUCH)
    Depuis l'onglet consultation du dossier  ${di}
    Wait Until Keyword Succeeds  ${TIMEOUT}  ${RETRY_INTERVAL}  Click Element  action-soustab-consultation-corner-ajouter_consultation_tiers
    Wait Until Page Contains Element  css=select#categorie_tiers_consulte
    ${value_unexpected} =  Set Variable  ALLAUCH
    @{list_value_unexpected} =  Create List  Catégorie ${value_unexpected}
    ${demande_omc_select} =  Set Variable  css=div#form-content select#categorie_tiers_consulte

    Select List Should Not Contain List  ${demande_omc_select}  ${list_value_unexpected}