*** Settings ***
Documentation    Gestion des modules
...    @author  epritchard
...    @package openADS
...    @version 03/07/2024

*** Keywords ***
Parametrer un Module sur un Evenement
    [Documentation]  Fonction pour associé un module a un événement
    ...    en incluant les déclencheur, ordre et paramétrage si nécéssaire

    [Arguments]  ${libelle_evenement}  ${nom_module}  ${declencheur}=None  ${order}=None  ${parametres}=None

    Depuis le formulaire d'ajout de module sur l'evenement  ${libelle_evenement}
    Wait until Page Contains  Type d'objet

    Select From List By Value  css=#module  ${nom_module}
    
    Run Keyword If  "${declencheur}" != "None"
    ...    Wait Until Keyword Succeeds  ${TIMEOUT}  ${RETRY_INTERVAL}
    ...    Select From List By Value  css=#declencheur  ${declencheur}

    Run Keyword If  "${order}" != "None"
    ...    Input Text  css=#ordre  ${order}
    Run Keyword If  "${order}" == "None"
    ...    Input Text  css=#ordre  0

    Run Keyword If  "${parametres}" != "None"
    ...    Input Text  css=#parametres  ${parametres}

    Click On Submit Button
    Page Should Contain  Vos modifications ont bien été enregistrées

    ${id_module} =  Get Text  css=div.form-content span#lien_module
    [return]  ${id_module}

Depuis le listing des modules de l'evenement
    [Documentation]  Se place dans le contexte de l'évenement voulu puis clique
    ...  sur le sous-onglet module.
    [Arguments]  ${libelle_evenement}

    # Accède à l'evenement
    Depuis le contexte de l'événement  ${libelle_evenement}
    # Clique sur l'onglet Module et vérifie que la page s'est bien chargé
    Click Element Until New Element  css=#lien_module  css=.add-16
    Page Should Contain  lien_module
    # Vérifie qu'il n'y a pas d'erreur
    La page ne doit pas contenir d'erreur

Depuis le formulaire d'ajout de module sur l'evenement
    [Documentation]  Se place dans le contexte de l'évenement voulu puis clique
    ...  sur le sous-onglet module. Puis clique sur le bouton d'ajout pour
    ...  accèder au formulaire.
    [Arguments]  ${libelle_evenement}

    # Accède à l'evenement puis à l'onglet module
    Depuis le listing des modules de l'evenement  ${libelle_evenement}
    # Clique sur le bouton d'ajout
    Click On Add Button
    # Vérifie qu'il n'y a pas d'erreur
    La page ne doit pas contenir d'erreur

Supprimer le module de l'evenement
    [Documentation]  Se place dans le contexte de l'évenement voulu puis clique
    ...  sur le sous-onglet module. Accède au module et clique sur l'action
    ...  de suppression. [WIP]
    [Arguments]  ${libelle_evenement}  ${txt_recherche}  ${id_module}

    # Accède à l'evenement puis à l'onglet module
    Depuis le listing des modules de l'evenement  ${libelle_evenement}
    # Filtre selon le nom du module
    Input Text  css=#recherchedyn  ${txt_recherche}
    # Clique sur le lien
    Wait Until Keyword Succeeds  ${TIMEOUT}  ${RETRY_INTERVAL}  Click Link  css=a[id$="consulter-${id_module}"]
    # Utilise l'action de suppression
    Click On SubForm Portlet Action  lien_module  supprimer
    # Vérifie qu'il n'y a pas d'erreur sur le formulaire de suppression
    La page ne doit pas contenir d'erreur
    # Click sur le bouton de suppression
    Click On Submit Button In Subform
    # Vérifie qu'il n'y a pas d'erreur à la suppression
    La page ne doit pas contenir d'erreur