*** Settings ***
Documentation    Test le fonctionnement des écrans du menu Paramétrage Dossiers > Workflows > Événement
# On inclut les mots-clefs
Resource    resources/resources.robot
# On ouvre et on ferme le navigateur respectivement au début et à la fin
# du Test Suite.
Suite Setup    For Suite Setup
Suite Teardown    For Suite Teardown


*** Test Cases ***
Chemin d'accès au formulaire de l'événément
    [Documentation]  Test du chemins d'accés a l'ajout des événements.

    Depuis la page d'accueil  admin  admin
    # On ouvre le tableau
    Depuis le listing  evenement
    # On clique sur l'icone ajouter
    Click On Add Button

    # Vérification qu'il n'y a aucune erreur
    La page ne doit pas contenir d'erreur

    # Test d'affichage
    Le titre de la page doit être  Paramétrage Dossiers > Workflows > Événement
    Element Should Be Visible  css=.formControls-top .om-button.btn.btn-primary
    ${btn_ajouter} =    Get Element Attribute    css=.formControls-top .om-button.btn.btn-primary  value
    Should Be Equal  Ajouter  ${btn_ajouter}

Affichage dynamique des champs sur le formulaire d'ajout d'un événement
    [Documentation]  Avec un profil administrateur, depuis le menu Administration > Paramétrage, j'ajoute un
    ...  nouvel élement. Dans le formulaire d'ajout je lui donne le libellé "option_module_acteur", la valeur
    ...  "true", la collectivité "agglo" et je valide le formulaire.
    ...
    ...  Depuis le menu Paramétrage Dossiers > Workflows > Événement, je clique sur l'action d'ajout.
    ...  A l'ouverture du formulaire, le champs "type(s) d'habilitation des tiers à notifier" n'est pas visible.
    ...
    ...  Lorsque je sélectionne la valeur "notification automatique" dans le champs "Notification des tiers", le
    ...  champs "type(s) d'habilitation des tiers à notifier" s'affiche.
    ...
    ...  En cliquant sur le bouton valider, sans remplir le libellé de l'événement, le formulaire se recharge
    ...  et "type(s) d'habilitation des tiers à notifier" reste visible.
    ...
    ...  Lorsque je sélectionne une autre valeur dans le champs "Notification des tiers", le champs
    ...  "type(s) d'habilitation des tiers à notifier" est masqué.

    &{param_values} =  Create Dictionary
    ...  libelle=option_module_acteur
    ...  valeur=true
    ...  om_collectivite=agglo
    Gerer le paramètre par WS  ${param_values}

    Depuis la page d'accueil  admin  admin
    Depuis le formulaire d'ajout de l'événement
    Wait Until Page Contains Element  css=#notification_tiers
    Wait Until Element Is Not Visible  css=#type_habilitation_tiers_consulte

    Select From List By Label  css=#notification_tiers  Notification automatique
    Wait Until Element Is Visible  css=#type_habilitation_tiers_consulte

    Click On Submit Button
    La page ne doit pas contenir d'erreur
    Wait Until Element Is Visible  css=#type_habilitation_tiers_consulte

    Select From List By Label  css=#notification_tiers  Notification manuelle
    Wait Until Element Is Not Visible  css=#type_habilitation_tiers_consulte


Affichage dynamique des champs sur le formulaire de modification d'un événement
    [Documentation]  Depuis le menu Paramétrage Dossiers > Workflows > Événement, j'accède à un événement,
    ...  pour lequel "Notification des tiers " a pour valeur "Notification automatique".
    ...  A l'ouverture du formulaire je constate que le champs "type(s) d'habilitation des tiers à notifier"
    ...  est visible.
    ...
    ...  Lorsque je sélectionne une autre valeur dans le champs "Notification des tiers", le champs
    ...  "type(s) d'habilitation des tiers à notifier" est masqué.
    ...
    ...  Lorsque je sélectionne la valeur "notification automatique" dans le champs "Notification des tiers",
    ...  le champs "type(s) d'habilitation des tiers à notifier" s'affiche.
    ...
    ...  En cliquant sur le bouton valider, sans remplir le libellé de l'événement, le formulaire se recharge
    ...  et "type(s) d'habilitation des tiers à notifier" reste visible.
    ...
    ...  J'accède à un événement pour lequel "Notification des tiers " n'a pas pour valeur "Notification automatique".
    ...  A l'ouverture du formulaire le champs "type(s) d'habilitation des tiers à notifier" n'est pas visible.

    Depuis la page d'accueil  admin  admin
    &{args_evenement} =  Create Dictionary
    ...  libelle=023 PARAM MODIF - NA
    ...  notification_tiers=Notification automatique
    Ajouter l'événement depuis le menu  ${args_evenement}
    Set Suite Variable  ${evenement_NA_libelle}  ${args_evenement.libelle}
    &{args_evenement} =  Create Dictionary
    ...  libelle=023 PARAM MODIF - NM
    ...  notification_tiers=Notification manuelle
    Ajouter l'événement depuis le menu  ${args_evenement}
    Set Suite Variable  ${evenement_NM_libelle}  ${args_evenement.libelle}

    Depuis le formulaire de modification de l'événement  ${evenement_NA_libelle}
    Wait Until Page Contains Element  css=#notification_tiers
    Wait Until Element Is Visible  css=#type_habilitation_tiers_consulte

    Select From List By Label  css=#notification_tiers  Notification manuelle
    Wait Until Element Is Not Visible  css=#type_habilitation_tiers_consulte

    Select From List By Label  css=#notification_tiers  Notification automatique
    Wait Until Element Is Visible  css=#type_habilitation_tiers_consulte

    Input Text  css=#libelle  ${EMPTY}
    Click On Submit Button
    La page ne doit pas contenir d'erreur
    Wait Until Element Is Visible  css=#type_habilitation_tiers_consulte

    Depuis le formulaire de modification de l'événement  ${evenement_NM_libelle}
    Wait Until Page Contains Element  css=#notification_tiers
    Wait Until Element Is Not Visible  css=#type_habilitation_tiers_consulte


Affichage des champs sur le formulaire de consultation d'un événement
    [Documentation]  Depuis le menu Paramétrage Dossiers > Workflows > Événement, j'accède à un événement
    ...  pour lequel "Notification des tiers " a pour valeur "Notification automatique".
    ...  A l'ouverture du formulaire je constate que le champs "type(s) d'habilitation des tiers à notifier"
    ...  est visible.
    ...
    ...  J'accède à un événement pour lequel "Notification des tiers " n'a pas pour valeur "Notification automatique".
    ...  A l'ouverture du formulaire le champs "type(s) d'habilitation des tiers à notifier" n'est pas visible.

    Depuis la page d'accueil  admin  admin

    Depuis le contexte de l'événement  ${evenement_NA_libelle}
    Wait Until Page Contains Element  css=#notification_tiers
    Wait Until Element Is Visible  css=#lib-type_habilitation_tiers_consulte

    Depuis le contexte de l'événement  ${evenement_NM_libelle}
    Wait Until Page Contains Element  css=#notification_tiers
    Wait Until Element Is Not Visible  css=#lib-type_habilitation_tiers_consulte


Affichage des champs sur le formulaire de suppression d'un événement
    [Documentation]  Depuis le menu Paramétrage Dossiers > Workflows > Événement, j'accède à un événement,
    ...  correspondant à un sous-dossier en suppression.
    ...  A l'ouverture du formulaire, je constate que les champs "sous-dossier" et "sous-dossier pour les DI"
    ...  sont visible alors que le champs "type de dossier d'autorisation détaillé" n'est pas affiché.
    ...
    ...  J'accède à un événement n'étant pas un sous-dossier.
    ...  A l'ouverture du formulaire, je constate que les champs "sous-dossier" et "type de dossier d'autorisation détaillé"
    ...  sont visible alors que le champs "sous-dossier pour les DI" n'est pas affiché.

    Depuis la page d'accueil  admin  admin

    Depuis le formulaire de suppression de l'événement  ${evenement_NA_libelle}
    Wait Until Page Contains Element  css=#notification_tiers
    Wait Until Element Is Visible  css=#lib-type_habilitation_tiers_consulte

    Depuis le formulaire de suppression de l'événement  ${evenement_NM_libelle}
    Wait Until Page Contains Element  css=#notification_tiers
    Wait Until Element Is Not Visible  css=#lib-type_habilitation_tiers_consulte


Vérification de la validation des numériques et dates dans les regles
    [Documentation]  Test que les regles de type Dates dans les Actions et les Evenements...
    ...    ne contiennent que des valeurs XX mois, XX jour, ou XX jours.
    ...    On test aussi les cas  XX mois + 1 ou [champ_fusion] + XX mois

    # On se connecte à l'application
    Depuis la page d'accueil  admin  admin

    # On ajoute une action avec 
    &{args_action} =  Create Dictionary
    ...  action=validation_num_date_texte
    ...  libelle=Action Test Date
    ...  regle_delai=archive_delai+delai+1mois
    ...  regle_accord_tacite=accord_tacite
    ...  regle_date_limite=date_depot_mairie+archive_delai+delai+1mois
    Ajouter l'action depuis le menu  ${args_action}
    # On test l'ajout valide
    Valid Message Should Contain  Vos modifications ont bien été enregistrées.

    # On ajout un evenement sur l'action validation_num_date_texte avec une date
    @{etat_source} =  Create List  delai de notification envoye
    @{type_di} =  Create List  PCI - P - Initial
    &{args_evenement} =  Create Dictionary
    ...  libelle=TEST Majorer le délai d'instruction 1 Success
    ...  etats_depuis_lequel_l_evenement_est_disponible=${etat_source}
    ...  dossier_instruction_type=${type_di}
    ...  delai=1Mois+1mois
    ...  action=Action Test Date
    Ajouter l'événement depuis le menu  ${args_evenement}
    # On test l'ajout valide
    Valid Message Should Contain  Vos modifications ont bien été enregistrées.
    
    # On ajout un evenement sur l'action validation_num_date_texte avec NULL
    @{etat_source} =  Create List  delai de notification envoye
    @{type_di} =  Create List  PCI - P - Initial
    &{args_evenement} =  Create Dictionary
    ...  libelle=TEST Majorer le délai d'instruction 2 Success
    ...  etats_depuis_lequel_l_evenement_est_disponible=${etat_source}
    ...  dossier_instruction_type=${type_di}
    ...  delai=NULL
    ...  action=Action Test Date
    Ajouter l'événement depuis le menu  ${args_evenement}
    # On test l'ajout valide
    Valid Message Should Contain  Vos modifications ont bien été enregistrées.

    # On ajout un evenement sur l'action validation_num_date_texte avec delai_notification NULL+truc
    @{etat_source} =  Create List  delai de notification envoye
    @{type_di} =  Create List  PCI - P - Initial
    &{args_evenement} =  Create Dictionary
    ...  libelle=TEST Majorer le délai d'instruction 3 FAIL
    ...  etats_depuis_lequel_l_evenement_est_disponible=${etat_source}
    ...  dossier_instruction_type=${type_di}
    ...  delai=NULL
    ...  delai_notification=NULL+truc
    ...  action=Action Test Date
    Ajouter l'événement depuis le menu sans vérification  ${args_evenement}
    # On test l'ajout
    Error Message Should Contain  'NULL' losque est utilisé doit être la seule valeur du champ.
    Error Message Should Contain  La valeur null + truc du champ délai notification est invalide

    # On ajoute un evenement a la regle delai fausse
    @{etat_source} =  Create List  delai de notification envoye
    @{type_di} =  Create List  PCI - P - Initial
    &{args_evenement} =  Create Dictionary
    ...  libelle=TEST Majorer le délai d'instruction 4 FAIL
    ...  etats_depuis_lequel_l_evenement_est_disponible=${etat_source}
    ...  dossier_instruction_type=${type_di}
    ...  delai=1Mois1
    ...  action=Action Test Date
    Ajouter l'événement depuis le menu sans vérification  ${args_evenement}

    # On vérifie la présence du message d'erreur
    Error Message Should Contain  1mois1

    # On ajoute un evenement a la regle delai fausse
    @{etat_source} =  Create List  delai de notification envoye
    @{type_di} =  Create List  PCI - P - Initial
    &{args_evenement} =  Create Dictionary
    ...  libelle=TEST Majorer le délai d'instruction 5 FAIL
    ...  etats_depuis_lequel_l_evenement_est_disponible=${etat_source}
    ...  dossier_instruction_type=${type_di}
    ...  delai_notification=1+1Mois
    ...  action=Action Test Date
    Ajouter l'événement depuis le menu sans vérification  ${args_evenement}

    # On vérifie la présence du message d'erreur
    Error Message Should Contain  1

    # On ajoute un evenement a la regle delai fausse
    @{etat_source} =  Create List  delai de notification envoye
    @{type_di} =  Create List  PCI - P - Initial
    &{args_evenement} =  Create Dictionary
    ...  libelle=Majorer le délai d'instruction Text FAIL
    ...  etats_depuis_lequel_l_evenement_est_disponible=${etat_source}
    ...  dossier_instruction_type=${type_di}
    ...  delai_notification=delai
    ...  action=Action Test Date
    Ajouter l'événement depuis le menu sans vérification  ${args_evenement}

    # On vérifie la présence du message d'erreur
    Error Message Should Contain  delai


Vérification des champs et gestion d'un évènement (document_type)
    [Documentation]  On vérifie que le champs document_type existe bien et est fonctionnelle dans "paramétrage dossiers > workflow >
    ...  évenement".
    ...  Lors de l'ajout d'un évènement depuis l'onglet "instruction" d'un DI, on vérifie également que depuis le profil admin,
    ...  on à bien le champ document_type présent, et on vérifie qu'il est bien renseigné avec les informations en lien avec l'évènement.
    ...  Un évènement peut avoir un type de document qui lui est associé. S'il est renseigné, alors l'info sera
    ...  présente lors de l'ajout d'un évènement depuis l'onglet "instruction" d'un DI, sinon le champ est visible
    ...  mais n'est pas renseigné.
    Depuis la page d'accueil  admin  admin

    # Ajout du premier DI
    &{args_petitionnaire} =  Create Dictionary
    ...  particulier_civilite=Monsieur
    ...  particulier_nom=Codo
    ...  particulier_prenom=Cecho
    ...  om_collectivite=MARSEILLE
    &{args_demande} =  Create Dictionary
    ...  dossier_autorisation_type_detaille=PCI - Permis de construire pour une maison individuelle et / ou ses annexes
    ...  om_collectivite=MARSEILLE
    ${di}=  Ajouter la nouvelle demande depuis le menu  ${args_demande}  ${args_petitionnaire}

    # Ajout du 2eme DI
    &{args_petitionnaire} =  Create Dictionary
    ...  particulier_civilite=Monsieur
    ...  particulier_nom=doco
    ...  particulier_prenom=choce
    ...  om_collectivite=MARSEILLE
    &{args_demande} =  Create Dictionary
    ...  dossier_autorisation_type_detaille=PCI - Permis de construire pour une maison individuelle et / ou ses annexes
    ...  om_collectivite=MARSEILLE
    ${di_2}=  Ajouter la nouvelle demande depuis le menu  ${args_demande}  ${args_petitionnaire}

    # On vérifie que dans le paramétrage d'un évènement, dans la section "Édition", on a bien le champ,
    # que le champ est bien nommé et que le select est bien renseigné
    Depuis le formulaire de modification de l'événement  demande de pièces complémentaires sans majoration
    Element Should Be Visible  css=#lib-document_type
    Element Should Contain  css=#fieldset-form-evenement-edition  Type de document
    @{listeType} =  Create List  Accusé de réception (contrôle de légalité)  Arrêté
    Select List Should Contain List  css=select#document_type  ${listeType}

    # On modifie l'évènement pour lui ajouter un type de document
    ${lib_document_instruction_type} =  Set Variable  Contestation de DAACT
    Select From List By Label  css=#document_type  ${lib_document_instruction_type}
    Click On Submit Button

    # Depuis le formulaire d'ajout de l'événement depuis l'onglet "instruction" d'un DI, le champ document type doit être visible
    # et bien renseigné
    Ajouter une instruction au DI  ${di}  demande de pièces complémentaires sans majoration
    Element Should Be Visible  css=#lib-document_type_instruction
    Element Should Contain  css=#fieldset-sousform-instruction-evenement  Type de document
    Element Should Contain  css=#fieldset-sousform-instruction-evenement  ${lib_document_instruction_type}
    Click On Back Button In SubForm

    # En mode modification
    Click On SubForm Portlet Action  instruction  modifier
    Element Should Be Visible  css=#lib-document_type_instruction
    Element Should Contain  css=#fieldset-sousform-instruction-evenement  ${lib_document_instruction_type}
    Click On Back Button In SubForm
    # Et en mode suppression également
    Click On SubForm Portlet Action  instruction  supprimer
    Element Should Be Visible  css=#lib-document_type_instruction
    Element Should Contain  css=#fieldset-sousform-instruction-evenement  ${lib_document_instruction_type}

    # Mais pas en mode ajout (le champ ne doit pas être visible)
    Depuis le formulaire d'ajout d'une instruction du DI  ${di}  NULL
    Element Should Not Be Visible  css=#lib-document_type_instruction
    Click On Back Button In SubForm

    # Et si on regarde une autre évènement d'instruction, le champ document_type n'est pas renseigné car on a pas
    # associé de type de document à l'évènement "Notification du delai legal maison individuelle"
    Click On Link  Notification du delai legal maison individuelle
    Element Should Be Visible  css=#lib-document_type_instruction
    Form Value Should Be  css=#document_type_instruction  ${EMPTY}

    # On vérifie que si on modifie le type de document d'un évènement dans le paramétrage, le type de document d'un évènement d'instruction 
    # dans l'onglet instruction d'un DI n'a pas changé, car il doit resté identique à celui mis en place lors de l'ajout
    Depuis le formulaire de modification de l'événement  demande de pièces complémentaires sans majoration
    ${lib_document_instruction_type_2} =  Set Variable  Arrêté
    Select From List By Label  css=#document_type  ${lib_document_instruction_type_2}
    Click On Submit Button
    Depuis l'instruction du dossier d'instruction  ${di}  demande de pièces complémentaires sans majoration
    Element Should Contain  css=#fieldset-sousform-instruction-evenement  ${lib_document_instruction_type}

    # Mais si on ajoute le même évènement d'instruction sur un autre DI, il prend en compte la modification 
    # fait dans le paramétrage des évènements et prend en compte le nouveau type de document associé à l'évènement
    Ajouter une instruction au DI  ${di_2}  demande de pièces complémentaires sans majoration
    Element Should Contain  css=#fieldset-sousform-instruction-evenement  ${lib_document_instruction_type_2}

    # Vérification qu'en mode Modification on conserve bien la valeur du type de document
    Click On Submit Button In Subform
    Element Should Be Visible  css=#lib-document_type_instruction
    Element Should Contain  css=#fieldset-sousform-instruction-evenement  ${lib_document_instruction_type_2}