*** Settings ***
Documentation     Test relatif à la gestion des enjeux sur les dossiers.
# On inclut les mots-clefs
Resource    resources/resources.robot
# On ouvre et on ferme le navigateur respectivement au début et à la fin
# du Test Suite.
Suite Setup    For Suite Setup
Suite Teardown    For Suite Teardown

*** Test Cases ***
Setup
    [Documentation]  Depuis le menu Paramétrage Dossiers > Enjeu, ajout de trois enjeux
    ...   - 1er enjeu  : "Site archéologique", associé au type PC, à la collectivité de niveau 2 et ayant la couleur rouge (#e80000).
    ...   - 2ème enjeu : "Date courte", associé au type PC, à la collectivité ALLAUCH et ayant la couleur violette (#ff00ff).
    ...   - 3ème enjeu : "Zone à risque", associé au type DP, à la collectivité MARSEILLE et ayant la couleur bleu (#3800ff).
    ...   Ajout via le WS de 2 dossiers :
    ...   - Un PC et une DP concernant la collectivité MARSEILLE
    ...   - Un PC concernant la collectivité ALLAUCH

    Depuis la page d'accueil  admin  admin

    Set Suite Variable  ${lib_enjeu_pc_agglo}  site archéologique
    Set Suite Variable  ${lib_enjeu_pc_allauch}  date courte
    Set Suite Variable  ${lib_enjeu_dp_marseille}  zone à risque
    Set Suite Variable  ${color_enjeu_pc_agglo}  E80000
    Set Suite Variable  ${color_enjeu_pc_allauch}  FF00FF
    Set Suite Variable  ${color_enjeu_dp_marseille}  3800FF
    # 1er Enjeu
    @{om_collectivite} =  Create List  agglo
    @{dossier_instruction_type} =  Create List  PCI - P - Initial
    &{values} =  Create Dictionary
    ...  libelle=${lib_enjeu_pc_agglo}
    ...  couleur=${color_enjeu_pc_agglo}
    ...  om_collectivite=${om_collectivite}
    ...  dossier_instruction_type=${dossier_instruction_type}
    ...  priorite=6
    ${id_enjeu_pc_agglo} =  Ajouter un enjeu et récupérer son identifiant  ${values}
    # 2ème Enjeu
    @{om_collectivite} =  Create List  ALLAUCH
    @{dossier_instruction_type} =  Create List  PCI - P - Initial
    &{values} =  Create Dictionary
    ...  libelle=${lib_enjeu_pc_allauch}
    ...  couleur=${color_enjeu_pc_allauch}
    ...  om_collectivite=${om_collectivite}
    ...  dossier_instruction_type=${dossier_instruction_type}
    ...  priorite=3
    ${id_enjeu_pc_allauch} =  Ajouter un enjeu et récupérer son identifiant  ${values}
    # 3ème Enjeu
    @{om_collectivite} =  Create List  MARSEILLE
    @{dossier_instruction_type} =  Create List  DP - P - Initiale
    &{values} =  Create Dictionary
    ...  libelle=${lib_enjeu_dp_marseille}
    ...  couleur=${color_enjeu_dp_marseille}
    ...  om_collectivite=${om_collectivite}
    ...  dossier_instruction_type=${dossier_instruction_type}
    ${id_enjeu_dp_marseille} =  Ajouter un enjeu et récupérer son identifiant  ${values}

    Set Suite Variable  ${id_enjeu_pc_agglo}
    Set Suite Variable  ${id_enjeu_pc_allauch}
    Set Suite Variable  ${id_enjeu_dp_marseille}

    # Création des dossiers
    &{args_dossier} =  Create Dictionary
    ...  om_collectivite=MARSEILLE
    ...  dossier_autorisation_type_detaille=Permis de construire pour une maison individuelle et / ou ses annexes
    ...  demande_type=Dépôt Initial
    &{args_petitionnaire1} =  Create Dictionary
    ...  qualite=particulier
    ...  particulier_nom=TEST037
    ...  particulier_prenom=GESTION DES ENJEUX - 1
    ...  om_collectivite=MARSEILLE
    ${di_pc_marseille} =  Ajouter la demande par WS  ${args_dossier}  ${args_petitionnaire1}

    &{args_dossier} =  Create Dictionary
    ...  om_collectivite=ALLAUCH
    ...  dossier_autorisation_type_detaille=Permis de construire pour une maison individuelle et / ou ses annexes
    ...  demande_type=Dépôt Initial
    &{args_petitionnaire1} =  Create Dictionary
    ...  qualite=particulier
    ...  particulier_nom=TEST037
    ...  particulier_prenom=GESTION DES ENJEUX - 2
    ...  om_collectivite=ALLAUCH
    ${di_pc_allauch} =  Ajouter la demande par WS  ${args_dossier}  ${args_petitionnaire1}

    &{args_dossier} =  Create Dictionary
    ...  om_collectivite=MARSEILLE
    ...  dossier_autorisation_type_detaille=Déclaration préalable
    ...  demande_type=Dépôt Initial
    &{args_petitionnaire1} =  Create Dictionary
    ...  qualite=particulier
    ...  particulier_nom=TEST037
    ...  particulier_prenom=GESTION DES ENJEUX - 3
    ...  om_collectivite=MARSEILLE
    ${di_dp_marseille} =  Ajouter la demande par WS  ${args_dossier}  ${args_petitionnaire1}

    Set Suite Variable  ${di_pc_marseille}
    Set Suite Variable  ${di_dp_marseille}
    Set Suite Variable  ${di_pc_allauch}
    # On supprime les éventuels espaces du libellé
    ${di_pc_marseille_se} =  Sans espace  ${di_pc_marseille}
    ${di_dp_marseille_se} =  Sans espace  ${di_dp_marseille}
    ${di_pc_allauch_se} =  Sans espace  ${di_pc_allauch}
    Set Suite Variable  ${di_pc_marseille_se}
    Set Suite Variable  ${di_dp_marseille_se}
    Set Suite Variable  ${di_pc_allauch_se}

    # Ajout d'une consultation avec un retour d'avis sur chacun des dossiers
    &{service} =  Create Dictionary
    ...  abrege=01.37
    ...  libelle=TEST037_ALL
    ...  edition=Consultation - Demande d'avis
    ...  om_collectivite=ALLAUCH
    ...  service_type=openADS
    ...  generate_edition=true
    Ajouter le service depuis le listing  ${service}
    ${service_allauch} =  Set Variable  ${service.abrege} - ${service.libelle}

    Ajouter l'utilisateur  consu_allauch consu_allauch  nospam@openmairie.org  consu_allauch  consu_allauch  SERVICE CONSULTÉ  ALLAUCH
    &{lien_service_om_utilisateur} =  Create Dictionary
    ...  om_utilisateur=consu_allauch consu_allauch
    ...  service=${service.libelle}
    Ajouter lien service/utilisateur  ${lien_service_om_utilisateur}

    &{service} =  Create Dictionary
    ...  abrege=02.37
    ...  libelle=TEST037_MAR
    ...  edition=Consultation - Demande d'avis
    ...  om_collectivite=MARSEILLE
    ...  service_type=openADS
    ...  generate_edition=true
    Ajouter le service depuis le listing  ${service}
    ${service_marseille} =  Set Variable  ${service.abrege} - ${service.libelle}
    &{lien_service_om_utilisateur} =  Create Dictionary
    ...  om_utilisateur=Service consulté
    ...  service=${service.libelle}
    Ajouter lien service/utilisateur  ${lien_service_om_utilisateur}

    Set Suite Variable  ${service_mar}  02.37 - TEST037_MAR
    Set Suite Variable  ${service_all}  01.37 - TEST037_ALL

    # Ajout d'une demande et d'un retour de consultation sur chacun des dossiers
    &{args_avis_consultation} =  Create Dictionary
    ...  avis_consultation=Favorable

    Depuis la page d'accueil  instr  instr
    Ajouter une consultation depuis un dossier  ${di_pc_marseille}  ${service_marseille}
    Depuis la page d'accueil  admin  admin
    Ajouter une consultation depuis un dossier  ${di_dp_marseille}  ${service_marseille}
    Depuis la page d'accueil  consu  consu
    Rendre l'avis sur la consultation du dossier  ${di_pc_marseille}  ${args_avis_consultation}
    Rendre l'avis sur la consultation du dossier  ${di_dp_marseille}  ${args_avis_consultation}

    Depuis la page d'accueil  instrpolycomm3  instrpolycomm3
    Ajouter une consultation depuis un dossier  ${di_pc_allauch}  ${service_allauch}
    Depuis la page d'accueil  consu_allauch  consu_allauch
    Rendre l'avis sur la consultation du dossier  ${di_pc_allauch}  ${args_avis_consultation}

    # Ajout de message non lu sur chacun des dossiers
    Depuis la page d'accueil  admin  admin
    ${message} =  Set Variable  TEST037
    Ajouter un message dans le dossier d'instruction  ${di_pc_marseille}  ${message}
    Ajouter un message dans le dossier d'instruction  ${di_dp_marseille}  ${message}
    Ajouter un message dans le dossier d'instruction  ${di_pc_allauch}  ${message}

    # Création d'une demande de commission et préparation du suivi pour le retour
    &{type_de_commission_01} =  Create Dictionary
    ...  code=37M
    ...  libelle=TEST37_MARSEILLE
    ...  lieu_salle=37TST
    ...  listes_de_diffusion=test37@test.com
    ...  participants=Atreal
    ...  corps_du_courriel=Test 37 (Affichage des enjeux)
    ...  om_collectivite=MARSEILLE
    Ajouter type de commission  ${type_de_commission_01}
    &{demande_commission} =  Create Dictionary
    ...  commission_type=${type_de_commission_01.libelle}
    Ajouter la demande de passage en commission  ${di_pc_marseille}  ${demande_commission}

    &{args_commission_A} =  Create Dictionary
    ...  libelle=COM37_MARSEILLE
    ...  lieu_adresse_ligne1=tst37
    ...  om_collectivite=MARSEILLE
    ...  commission_type=${type_de_commission_01.libelle}
    Ajouter un suivi de commission  ${args_commission_A}

    &{type_de_commission_02} =  Create Dictionary
    ...  code=37A
    ...  libelle=TEST37_ALLAUCH
    ...  lieu_salle=37TST
    ...  listes_de_diffusion=test37@test.com
    ...  participants=Atreal
    ...  corps_du_courriel=Test 37 (Affichage des enjeux)
    ...  om_collectivite=ALLAUCH
    Ajouter type de commission  ${type_de_commission_02}
    &{demande_commission} =  Create Dictionary
    ...  commission_type=${type_de_commission_02.libelle}
    Ajouter la demande de passage en commission  ${di_pc_allauch}  ${demande_commission}

    &{args_commission_B} =  Create Dictionary
    ...  libelle=COM37_ALLAUCH
    ...  lieu_adresse_ligne1=tst37
    ...  om_collectivite=ALLAUCH
    ...  commission_type=${type_de_commission_02.libelle}
    Ajouter un suivi de commission  ${args_commission_B}

    Set Suite Variable  ${code_commission_marseille}  ${type_de_commission_01.code}
    Set Suite Variable  ${code_commission_allauch}  ${type_de_commission_02.code}

CRUD des enjeux sur les dossiers
    [Documentation]  Cas 1 : Avec un instructeur de la collectivité MARSEILLE, depuis le contexte d'un PC,
    ...  depuis le formulaire de modification, uniquement les enjeux lié aux PC et aux collectivités
    ...  MARSEILLE ou agglo peuvent être ajoutés.
    ...  Ajoute les enjeux disponiblse et vérifie qu'ils sont visible sur la synthèse du DI avec la couleur
    ...  voulue.
    ...  Retourne sur le formulaire de modification, supprime l'enjeu et valide le formulaire. Le fieldset
    ...  Enjeu n'est plus visible en consultation.
    ...  Remet l'enjeu pour la suite des tests.
    ...  Cas 2 : Avec un instructeur de la collectivité ALLAUCH, depuis le contexte d'un PC, depuis le
    ...  formulaire de modification, uniquement les enjeux lié aux PC et aux collectivités ALLAUCH ou
    ...  agglo peuvent être ajoutés.
    ...  Ajoute les enjeux disponibles et vérifie qu'ils sont visible sur la synthèse du DI avec la couleur
    ...  voulue.

    # Cas 1
    Depuis la page d'accueil  instr  instr
    Depuis le contexte du dossier d'instruction  ${di_pc_marseille}
    Click On Portlet Action  dossier_instruction  modifier
    La page ne doit pas contenir d'erreur
    @{enjeux_ok} =  Create List  ${lib_enjeu_pc_agglo}
    @{enjeux_ko} =  Create List  ${lib_enjeu_pc_allauch}  ${lib_enjeu_dp_marseille}
    Select Multiple From Chosen List Should Contain List  enjeux  ${enjeux_ok}
    Select Multiple From Chosen List Should Not Contain List  enjeux  ${enjeux_ko}
    # Ajout de l'enjeu
    Select From Multiple Chosen List  enjeux  ${enjeux_ok}
    Click On Submit Button
    La page ne doit pas contenir d'erreur
    # Vérification de la couleur et du libellé de l'enjeu
    Wait Until Keyword Succeeds
    ...  ${TIMEOUT}  ${RETRY_INTERVAL}
    ...  Element Should Contain  css=.enjeux--item--${id_enjeu_pc_agglo} .enjeux-dossier[style*="${color_enjeu_pc_agglo}"]  ${lib_enjeu_pc_agglo}
    # Suppression de l'enjeu
    Click On Portlet Action  dossier_instruction  modifier
    Unselect From Multiple Chosen List  enjeux  ${enjeux_ok}
    Click On Submit Button
    La page ne doit pas contenir d'erreur
    # Vérification du non affichage de l'enjeu
    Page Should Not Contain Element  css=#fieldset-form-dossier_instruction-enjeu
    # Remise de l'enjeu pour la suite des tests
    Click On Portlet Action  dossier_instruction  modifier
    Select From Multiple Chosen List  enjeux  ${enjeux_ok}
    Click On Submit Button
    La page ne doit pas contenir d'erreur

    # Ajout de l'enjeu sur le dossier DP
    Depuis la page d'accueil  admin  admin
    @{enjeux} =  Create List  ${lib_enjeu_dp_marseille}
    ${values} =  Create Dictionary
    ...  enjeux=${enjeux}
    Modifier le dossier d'instruction  ${di_dp_marseille}  ${values}

    # Cas 2
    Depuis la page d'accueil  instrpolycomm3  instrpolycomm3
    Depuis le contexte du dossier d'instruction  ${di_pc_allauch}
    Click On Portlet Action  dossier_instruction  modifier
    La page ne doit pas contenir d'erreur
    @{enjeux_ok} =  Create List  ${lib_enjeu_pc_agglo}  ${lib_enjeu_pc_allauch}
    @{enjeux_ko} =  Create List  ${lib_enjeu_dp_marseille}
    Select Multiple From Chosen List Should Contain List  enjeux  ${enjeux_ok}
    Select Multiple From Chosen List Should Not Contain List  enjeux  ${enjeux_ko}
    # Ajout des enjeux
    Select From Multiple Chosen List  enjeux  ${enjeux_ok}
    Click On Submit Button
    La page ne doit pas contenir d'erreur
    # Vérification de la couleur et du libellé des enjeux
    Wait Until Keyword Succeeds
    ...  ${TIMEOUT}  ${RETRY_INTERVAL}
    ...  Element Should Contain  css=.enjeux--item--${id_enjeu_pc_agglo} .enjeux-dossier[style*="${color_enjeu_pc_agglo}"]  ${lib_enjeu_pc_agglo}
    Wait Until Keyword Succeeds
    ...  ${TIMEOUT}  ${RETRY_INTERVAL} 
    ...  Element Should Contain  css=.enjeux--item--${id_enjeu_pc_allauch} .enjeux-dossier[style*="${color_enjeu_pc_allauch}"]  ${lib_enjeu_pc_allauch}


Export CSV des Listings présence des enjeux
    [Documentation]  En se basant sur les éléments crée par le test CRUD des enjeux
    ...    on test la présence dans le CSV des recherches des enjeux

    Depuis la page d'accueil  admin  admin
    Go To Submenu In Menu  instruction  dossier_instruction_recherche

    ${link_export_listing}=  Get Element Attribute  css=.tab-export a  href
    ${output_dir}  ${output_name} =  Télécharger un fichier  ${SESSION_COOKIE}  ${link_export_listing}  ${EXECDIR}${/}binary_files${/}
    La page ne doit pas contenir d'erreur

    # Récupération du contenu du fichier pour vérifier le contenu des champs affiché.
    # Vérifie que la colonne 'enjeu' contien bien les mots "site archéologique"
    ${full_path_to_file} =  Catenate  SEPARATOR=  ${output_dir}  ${output_name}
    ${content_file} =  Get File  ${full_path_to_file}
    ${csv_file} =  Set Variable  "site archéologique"
    Should Contain  ${content_file}  ${csv_file}
    ${csv_file} =  Set Variable  "<i priorite="
    Should Not Contain  ${content_file}  ${csv_file}


Affichage des enjeux sur le listing : dossiers d'instruction
    [Documentation]

    # Cas 1 : affichage d'un dossier sans enjeu
    Depuis la page d'accueil  instr  instr
    Depuis le listing  dossier_instruction
    La page ne doit pas contenir d'erreur
    &{values} =  Create Dictionary
    ...  dossier=AT0130551300001P0
    Filtrer les dossier  ${values}
    # Vérification qu'un dossier sans enjeu n'a rien d'affiché
    Page Should Not Contain Element  css=a[href*="idx=AT0130551300001P0"] i.ri-alert-line
    Page Should Not Contain Element  css=a[href*="idx=AT0130551300001P0"] i.omi-alert-multiple-line

    # Cas 2 : affichage d'un dossier avec un seul enjeu
    Depuis le listing  dossier_instruction
    La page ne doit pas contenir d'erreur
    &{values} =  Create Dictionary
    ...  dossier=${di_pc_marseille_se}
    Filtrer les dossier  ${values}
    La page ne doit pas contenir d'erreur
    # Vérification de l'affichage de l'icone, la couleur et le titre de l'enjeu
    Wait Until Page Contains Element  css=a[href*="idx=${di_pc_marseille_se}"] i.ri-alert-line[style*="color:#${color_enjeu_pc_agglo}"]
    Wait Until Page Contains Element  css=a[href*="idx=${di_pc_marseille_se}"] i.ri-alert-line[title="${lib_enjeu_pc_agglo}"]

    # Cas 3 : affichage d'un dossier avec un plusieurs enjeu
    Depuis la page d'accueil  instrpolycomm3  instrpolycomm3
    Depuis le listing  dossier_instruction
    La page ne doit pas contenir d'erreur
    &{values} =  Create Dictionary
    ...  dossier=${di_pc_allauch_se}
    Filtrer les dossier  ${values}
    La page ne doit pas contenir d'erreur
    # Vérification de l'affichage de l'icone du titre des enjeux
    Wait Until Page Contains Element  css=a[href*="idx=${di_pc_allauch_se}"] i.omi-alert-multiple-line

Affichage des enjeux sur le listing : dossiers à qualifier
    [Documentation]

    # Cas 1 : affichage d'un dossier avec un seul enjeu
    Depuis la page d'accueil  instr  instr
    Depuis le listing  dossier_qualifier
    La page ne doit pas contenir d'erreur
    Use Simple Search  Tous  ${di_pc_marseille_se}
    La page ne doit pas contenir d'erreur
    # Vérification de l'affichage de l'icone, la couleur et le titre de l'enjeu
    Wait Until Page Contains Element  css=a[href*="idx=${di_pc_marseille_se}"] i.ri-alert-line[style*="color:#${color_enjeu_pc_agglo}"]
    Wait Until Page Contains Element  css=a[href*="idx=${di_pc_marseille_se}"] i.ri-alert-line[title="${lib_enjeu_pc_agglo}"]

    # Cas 2 : affichage d'un dossier avec un plusieurs enjeu
    Depuis la page d'accueil  instrpolycomm3  instrpolycomm3
    Depuis le listing  dossier_qualifier
    La page ne doit pas contenir d'erreur
    Use Simple Search  Tous  ${di_pc_allauch_se}
    La page ne doit pas contenir d'erreur
    # Vérification de l'affichage de l'icone du titre des enjeux
    Wait Until Page Contains Element  css=a[href*="idx=${di_pc_allauch_se}"] i.omi-alert-multiple-line

Affichage des enjeux sur les listings : encours
    [Documentation]

    # Cas 1 : affichage d'un dossier avec un seul enjeu
    Depuis la page d'accueil  instr  instr

    # Listing mes encours
    Depuis le listing  dossier_instruction_mes_encours
    Use Simple Search  Tous  ${di_pc_marseille_se}
    La page ne doit pas contenir d'erreur
    # Vérification de l'affichage de l'icone, la couleur et le titre de l'enjeu
    Wait Until Page Contains Element  css=a[href*="idx=${di_pc_marseille_se}"] i.ri-alert-line[style*="color:#${color_enjeu_pc_agglo}"]
    Wait Until Page Contains Element  css=a[href*="idx=${di_pc_marseille_se}"] i.ri-alert-line[title="${lib_enjeu_pc_agglo}"]

    # Listing tous les encours
    Depuis le listing  dossier_instruction_tous_encours
    Use Simple Search  Tous  ${di_pc_marseille_se}
    La page ne doit pas contenir d'erreur
    # Vérification de l'affichage de l'icone, la couleur et le titre de l'enjeu
    Wait Until Page Contains Element  css=a[href*="idx=${di_pc_marseille_se}"] i.ri-alert-line[style*="color:#${color_enjeu_pc_agglo}"]
    Wait Until Page Contains Element  css=a[href*="idx=${di_pc_marseille_se}"] i.ri-alert-line[title="${lib_enjeu_pc_agglo}"]


    # Cas 2 : affichage d'un dossier avec plusieurs enjeu
    Depuis la page d'accueil  instrpolycomm3  instrpolycomm3

    # Listing mes encours
    Depuis le listing  dossier_instruction_mes_encours
    Use Simple Search  Tous  ${di_pc_allauch_se}
    La page ne doit pas contenir d'erreur
    # Vérification de l'affichage de l'icone du titre des enjeux
    Wait Until Page Contains Element  css=a[href*="idx=${di_pc_allauch_se}"] i.omi-alert-multiple-line

    # Listing tous les encours
    Depuis le listing  dossier_instruction_tous_encours
    Use Simple Search  Tous  ${di_pc_allauch_se}
    La page ne doit pas contenir d'erreur
    # Vérification de l'affichage de l'icone du titre des enjeux
    Wait Until Page Contains Element  css=a[href*="idx=${di_pc_allauch_se}"] i.omi-alert-multiple-line

Affichage des enjeux sur les listings : consultations
    [Documentation]  Affichage des icônes liées aux enjeux :
    ...  Avec un profil instructeur de la collectivité Marseille, depuis le menu
    ...  "Instruction > consultations > mes retours" vérifie l'affichage de l'icône de présence
    ...  d'un enjeu. Idem pour "Instruction > consultations > retours de ma division" et
    ...  "Instruction > consultations > tous les retours".
    ...  Avec un profil instructeur de la collectivité Allauch, effectue les mêmes tests mais
    ...  en vérifiant l'affichage de l'icône de présence d'enjeu multiple.
    ...
    ...  Tri par enjeux :
    ...  Avec un profil ayant accès aux retour de consultation de toutes les collectivités,
    ...  depuis "Instruction > consultations > tous les retours" vérifie que les enjeux sont
    ...  bien triés par ordre de priorité. Vérifie qu'en cas d'enjeu multiple la priorité la
    ...  plus elevée est celle qui sert de reférence. Vérifie qu'un enjeu sans priorité est
    ...  considéré comme ayant la priorité la plus basse.
    ...  
    ...  Recherche avancée :
    ...  Avec le même profil tape le nom d'un enjeu précédé de '*' et vérifie qu'il n'y a que
    ...  cet enjeu qui est affiché.
    ...  Clique ensuite sur la colonne enjeu pour vérifier le tri par ordre de priorité
    ...  décroissante. Clique une nouvelle fois pour tester le tri par ordre croissant.
    
    # Cas 1 : affichage d'un dossier avec un seul enjeu
    Depuis la page d'accueil  instr  instr

    # Listing mes retours
    Depuis le listing  consultation_mes_retours
    Input Text  css=div#adv-search-classic-fields input.champFormulaire  ${di_pc_marseille_se}
    La page ne doit pas contenir d'erreur
    # Vérification de l'affichage de l'icone, la couleur et le titre de l'enjeu
    Wait Until Page Contains Element  css=i.ri-alert-line[style*="color:#${color_enjeu_pc_agglo}"]
    Wait Until Page Contains Element  css=i.ri-alert-line[title="${lib_enjeu_pc_agglo}"]

    # Listing retours de ma division
    Depuis le listing  consultation_retours_ma_division
    Input Text  css=div#adv-search-classic-fields input.champFormulaire  ${di_pc_marseille_se}
    La page ne doit pas contenir d'erreur
    # Vérification de l'affichage de l'icone, la couleur et le titre de l'enjeu
    Wait Until Page Contains Element  css=i.ri-alert-line[style*="color:#${color_enjeu_pc_agglo}"]
    Wait Until Page Contains Element  css=i.ri-alert-line[title="${lib_enjeu_pc_agglo}"]

    # Listing tous les retours
    Depuis le listing  consultation_tous_retours
    Input Text  css=div#adv-search-classic-fields input.champFormulaire  ${di_pc_marseille_se}
    La page ne doit pas contenir d'erreur
    # Vérification de l'affichage de l'icone, la couleur et le titre de l'enjeu
    Wait Until Page Contains Element  css=i.ri-alert-line[style*="color:#${color_enjeu_pc_agglo}"]
    Wait Until Page Contains Element  css=i.ri-alert-line[title="${lib_enjeu_pc_agglo}"]


    # Cas 2 : affichage d'un dossier avec plusieurs enjeu
    Depuis la page d'accueil  instrpolycomm3  instrpolycomm3
    # Ajout d'une demande et d'un retour de consultation

    # Listing mes retours
    Depuis le listing  consultation_mes_retours
    Input Text  css=div#adv-search-classic-fields input.champFormulaire  ${di_pc_allauch_se}
    La page ne doit pas contenir d'erreur
    # Vérification de l'affichage de l'icone du titre des enjeux
    Wait Until Page Contains Element  css=i.omi-alert-multiple-line

    # Listing retours de ma division
    Depuis le listing  consultation_retours_ma_division
    Input Text  css=div#adv-search-classic-fields input.champFormulaire  ${di_pc_allauch_se}
    La page ne doit pas contenir d'erreur
    # Vérification de l'affichage de l'icone du titre des enjeux
    Wait Until Page Contains Element  css=i.omi-alert-multiple-line

    # Listing tous les retours
    Depuis le listing  consultation_tous_retours
    Input Text  css=div#adv-search-classic-fields input.champFormulaire  ${di_pc_allauch_se}
    La page ne doit pas contenir d'erreur
    # Vérification de l'affichage de l'icone du titre des enjeux
    Wait Until Page Contains Element  css=i.omi-alert-multiple-line

    # Vérification du tri des enjeux sur le listing consultation_tous_retours
    Depuis la page d'accueil  admin  admin
    Depuis le listing  consultation_tous_retours
    # Garde uniquement les 3 dossiers ayant des enjeux associés
    Input Text  css=div#adv-search-classic-fields input.champFormulaire  ${di_pc_allauch_se},${di_pc_marseille_se},${di_dp_marseille_se}
    # Tri à l'ouverture du listing
    Wait Until Element Contains  css=tbody tr:nth-child(1)  ${di_pc_allauch}
    Element Should Contain  css=tbody tr:nth-child(2)  ${di_pc_marseille}
    Element Should Contain  css=tbody tr:nth-child(3)  ${di_dp_marseille}
    # Tri par ordre décroissant en cliquant sur la colonne enjeu
    Click Link  css=th.col-12 a
    Wait Until Element Contains  css=tbody tr:nth-child(1)  ${di_pc_allauch}
    Element Should Contain  css=tbody tr:nth-child(2)  ${di_pc_marseille}
    Element Should Contain  css=tbody tr:nth-child(3)  ${di_dp_marseille}
    # Tri par ordre décroissant en cliquant une 2eme fois sur la colonne enjeu
    Click Link  css=th.col-12 a
    Wait Until Element Contains  css=tbody tr:nth-child(1)  ${di_dp_marseille}
    Element Should Contain  css=tbody tr:nth-child(2)  ${di_pc_marseille}
    Element Should Contain  css=tbody tr:nth-child(3)  ${di_pc_allauch}

    # Marque les consultations comme lu pour qu'elles ne soient plus visible dans le listing
    Depuis le contexte de la consultation  ${di_dp_marseille}  ${service_mar}
    Click On SubForm Portlet Action  consultation  marquer_comme_lu
    Depuis le contexte de la consultation  ${di_pc_marseille}  ${service_mar}
    Click On SubForm Portlet Action  consultation  marquer_comme_lu
    Depuis le contexte de la consultation  ${di_pc_allauch}  ${service_all}
    Click On SubForm Portlet Action  consultation  marquer_comme_lu

Affichage des enjeux sur les listings : messages
    [Documentation]  Affichage des icônes liées aux enjeux :
    ...  Avec un profil instructeur de la collectivité Marseille, accède au menu
    ...  "Instruction > messages > mes messages" et vérifie l'affichage de l'icône de présence
    ...  d'un enjeu. Idem pour les menus "Instruction > messages > messages de ma division" et
    ...  "Instruction > messages > tous les messages".
    ...  Avec un profil instructeur de la collectivité Allauch, effectue les mêmes tests mais
    ...  en vérifiant l'affichage de l'icône de présence d'enjeu multiple.
    ...
    ...  Tri par enjeux :
    ...  Avec un profil ayant accès aux messages de toutes les collectivités accès au menu
    ...  "Instruction > messages > tous les messages" et vérifie que les enjeux sont bien
    ...  trié par ordre de priorité. Vérifie qu'en cas d'enjeu multiple la priorité la plus
    ...  elevée est celle qui sert de reférence. Vérifie qu'un enjeu sans priorité est
    ...  considéré comme ayant la priorité la plus basse.
    ...  
    ...  Recherche avancée :
    ...  Avec le même profil tape le nom d'un enjeu précédé de '*' et vérifie qu'il n'y a que
    ...  cet enjeu qui est affiché.
    ...  Clique ensuite sur la colonne enjeu pour vérifier le tri par ordre de priorité
    ...  décroissante. Clique une nouvelle fois pour tester le tri par ordre croissant.
    
    # Cas 1 : affichage d'un dossier avec un seul enjeu
    Depuis la page d'accueil  instr  instr
    # Ajout d'un message non lu

    # Listing mes messages
    Depuis le listing  messages_mes_retours
    Input Text  css=div#adv-search-classic-fields input.champFormulaire  ${di_pc_marseille_se}
    La page ne doit pas contenir d'erreur
    # Vérification de l'affichage de l'icone, la couleur et le titre de l'enjeu
    Wait Until Page Contains Element  css=i.ri-alert-line[style*="color:#${color_enjeu_pc_agglo}"]
    Wait Until Page Contains Element  css=i.ri-alert-line[title="${lib_enjeu_pc_agglo}"]

    # Listing messages de ma division
    Depuis le listing  messages_retours_ma_division
    Input Text  css=div#adv-search-classic-fields input.champFormulaire  ${di_pc_marseille_se}
    La page ne doit pas contenir d'erreur
    # Vérification de l'affichage de l'icone, la couleur et le titre de l'enjeu
    Wait Until Page Contains Element  css=i.ri-alert-line[style*="color:#${color_enjeu_pc_agglo}"]
    Wait Until Page Contains Element  css=i.ri-alert-line[title="${lib_enjeu_pc_agglo}"]

    # Listing tous les messages
    Depuis le listing  messages_tous_retours
    Input Text  css=div#adv-search-classic-fields input.champFormulaire  ${di_pc_marseille_se}
    La page ne doit pas contenir d'erreur
    # Vérification de l'affichage de l'icone, la couleur et le titre de l'enjeu
    Wait Until Page Contains Element  css=i.ri-alert-line[style*="color:#${color_enjeu_pc_agglo}"]
    Wait Until Page Contains Element  css=i.ri-alert-line[title="${lib_enjeu_pc_agglo}"]


    # Cas 2 : affichage d'un dossier avec plusieurs enjeu
    Depuis la page d'accueil  instrpolycomm3  instrpolycomm3
    # Ajout d'une demande et d'un retour de messages

    # Listing mes messages
    Depuis le listing  messages_mes_retours
    Input Text  css=div#adv-search-classic-fields input.champFormulaire  ${di_pc_allauch_se}
    La page ne doit pas contenir d'erreur
    # Vérification de l'affichage de l'icone du titre des enjeux
    Wait Until Page Contains Element  css=i.omi-alert-multiple-line

    # Listing messages de ma division
    Depuis le listing  messages_retours_ma_division
    Input Text  css=div#adv-search-classic-fields input.champFormulaire  ${di_pc_allauch_se}
    La page ne doit pas contenir d'erreur
    # Vérification de l'affichage de l'icone du titre des enjeux
    Wait Until Page Contains Element  css=i.omi-alert-multiple-line

    # Listing tous les messages
    Depuis le listing  messages_tous_retours
    Input Text  css=div#adv-search-classic-fields input.champFormulaire  ${di_pc_allauch_se}
    La page ne doit pas contenir d'erreur
    # Vérification de l'affichage de l'icone du titre des enjeux
    Wait Until Page Contains Element  css=i.omi-alert-multiple-line

    # Vérification du tri des enjeux sur le listing messages_tous_retours
    Depuis la page d'accueil  admin  admin
    Depuis le listing  messages_tous_retours
    # Garde uniquement les 3 dossiers ayant des enjeux associés
    Input Text  css=div#adv-search-classic-fields input.champFormulaire  ${di_pc_allauch_se},${di_pc_marseille_se},${di_dp_marseille_se}
    Wait Until Element Contains  css=tbody tr:nth-child(1)  ${di_pc_allauch}
    Element Should Contain  css=tbody tr:nth-child(2)  ${di_pc_marseille}
    Element Should Contain  css=tbody tr:nth-child(3)  ${di_dp_marseille}
    # Tri par ordre décroissant en cliquant sur la colonne enjeu
    Click Link  css=th.col-11 a
    Wait Until Element Contains  css=tbody tr:nth-child(1)  ${di_pc_allauch}
    Element Should Contain  css=tbody tr:nth-child(2)  ${di_pc_marseille}
    Element Should Contain  css=tbody tr:nth-child(3)  ${di_dp_marseille}
    # Tri par ordre décroissant en cliquant une 2eme fois sur la colonne enjeu
    Click Link  css=th.col-11 a
    Wait Until Element Contains  css=tbody tr:nth-child(1)  ${di_dp_marseille}
    Element Should Contain  css=tbody tr:nth-child(2)  ${di_pc_marseille}
    Element Should Contain  css=tbody tr:nth-child(3)  ${di_pc_allauch}

    # Test de la recherche avancée des enjeux.
    # Filtre pour n'afficher que l'enjeu spécifique au dossier d'allauch,
    # le dossier associé à Marseille ne dois plus être visible.
    &{search_value} =  Create Dictionary
    ...  enjeu=*${lib_enjeu_pc_allauch}
    Effectuer une recherche avancée sur les messages  ${search_value}
    Wait Until Keyword Succeeds  ${TIMEOUT}  ${RETRY_INTERVAL}  Page Should Not Contain  ${di_pc_marseille}
    Wait Until Keyword Succeeds  ${TIMEOUT}  ${RETRY_INTERVAL}  Page Should Not Contain  ${di_dp_marseille}

Affichage des enjeux sur les listings : commissions
    [Documentation]


    Depuis la page d'accueil  admin  admin
    Go To Submenu In Menu  suivi  commissions-demande-passage
    # Listing Demande commission
    # Cas 1 : affichage d'un dossier avec un seul enjeu
    Wait Until Page Contains Element  css=i.ri-alert-line[style*="color:#${color_enjeu_pc_agglo}"]
    # Cas 2 : affichage d'un dossier avec plusieurs enjeu
    Wait Until Page Contains Element  css=i.omi-alert-multiple-line

    # Passage en commission
    Planifier un dossier pour une commission  ${di_pc_marseille}  ${code_commission_marseille}${DATE_FORMAT_YYYYMMDD}
    Rendre un avis sur dossier passé en commission  avis rendu TST37  ${di_pc_marseille}  ${code_commission_marseille}${DATE_FORMAT_YYYYMMDD}
    Planifier un dossier pour une commission  ${di_pc_allauch}  ${code_commission_allauch}${DATE_FORMAT_YYYYMMDD}
    Rendre un avis sur dossier passé en commission  avis rendu TST37  ${di_pc_allauch}  ${code_commission_allauch}${DATE_FORMAT_YYYYMMDD}

    # Cas 1 : affichage d'un dossier avec un seul enjeu
    Depuis la page d'accueil  instr  instr

    # Listing mes retours
    Depuis le listing  commission_mes_retours
    Use Simple Search  Tous  ${di_pc_marseille_se}
    La page ne doit pas contenir d'erreur
    # Vérification de l'affichage de l'icone, la couleur et le titre de l'enjeu
    Wait Until Page Contains Element  css=i.ri-alert-line[style*="color:#${color_enjeu_pc_agglo}"]
    Wait Until Page Contains Element  css=i.ri-alert-line[title="${lib_enjeu_pc_agglo}"]

    # Listing retours de ma division
    Depuis le listing  commission_retours_ma_division
    Use Simple Search  Tous  ${di_pc_marseille_se}
    La page ne doit pas contenir d'erreur
    # Vérification de l'affichage de l'icone, la couleur et le titre de l'enjeu
    Wait Until Page Contains Element  css=i.ri-alert-line[style*="color:#${color_enjeu_pc_agglo}"]
    Wait Until Page Contains Element  css=i.ri-alert-line[title="${lib_enjeu_pc_agglo}"]

    # Listing tous les retours
    Depuis le listing  commission_tous_retours
    Use Simple Search  Tous  ${di_pc_marseille_se}
    La page ne doit pas contenir d'erreur
    # Vérification de l'affichage de l'icone, la couleur et le titre de l'enjeu
    Wait Until Page Contains Element  css=i.ri-alert-line[style*="color:#${color_enjeu_pc_agglo}"]
    Wait Until Page Contains Element  css=i.ri-alert-line[title="${lib_enjeu_pc_agglo}"]

    # Marque la commissions comme lu
    Click Link   ${di_pc_marseille}
    Click On SubForm Portlet Action  dossier_commission  marquer_comme_lu

    # Cas 2 : affichage d'un dossier avec plusieurs enjeu
    Depuis la page d'accueil  instrpolycomm3  instrpolycomm3
    # Ajout d'une demande et d'un retour de commission

    # Listing mes retours
    Depuis le listing  commission_mes_retours
    Use Simple Search  Tous  ${di_pc_allauch_se}
    La page ne doit pas contenir d'erreur
    # Vérification de l'affichage de l'icone du titre des enjeux
    Wait Until Page Contains Element  css=i.omi-alert-multiple-line

    # Listing retours de ma division
    Depuis le listing  commission_retours_ma_division
    Use Simple Search  Tous  ${di_pc_allauch_se}
    La page ne doit pas contenir d'erreur
    # Vérification de l'affichage de l'icone du titre des enjeux
    Wait Until Page Contains Element  css=i.omi-alert-multiple-line

    # Listing tous les retours
    Depuis le listing  commission_tous_retours
    Use Simple Search  Tous  ${di_pc_allauch_se}
    La page ne doit pas contenir d'erreur
    # Vérification de l'affichage de l'icone du titre des enjeux
    Wait Until Page Contains Element  css=i.omi-alert-multiple-line

    # Marque la commissions comme lu
    Click Link   ${di_pc_allauch}
    Click On SubForm Portlet Action  dossier_commission  marquer_comme_lu

Affichage des enjeux sur les listings : dossiers liés
    [Documentation]

    # Cas 1 : affichage d'un dossier avec un seul enjeu
    Depuis la page d'accueil  instr  instr

    Depuis le listing  dossier_lies
    Use Simple Search  dossier  ${di_pc_marseille_se}
    La page ne doit pas contenir d'erreur
    # Vérification de l'affichage de l'icone, la couleur et le titre de l'enjeu
    Wait Until Page Contains Element  css=i.ri-alert-line[style*="color:#${color_enjeu_pc_agglo}"]
    Wait Until Page Contains Element  css=i.ri-alert-line[title="${lib_enjeu_pc_agglo}"]

    Depuis le listing  dossier_lies_geographiquement
    ${da_marseille} =  Replace String Using Regexp  ${di_pc_marseille_se}  [A-Z][0-9]+$  ${EMPTY}
    Use Simple Search  dossier d'autorisation  ${da_marseille}
    La page ne doit pas contenir d'erreur
    # Vérification de l'affichage de l'icone, la couleur et le titre de l'enjeu
    Wait Until Page Contains Element  css=i.ri-alert-line[style*="color:#${color_enjeu_pc_agglo}"]
    Wait Until Page Contains Element  css=i.ri-alert-line[title="${lib_enjeu_pc_agglo}"]

    Depuis le listing  dossier_lies_retour
    Use Simple Search  dossier  ${di_pc_marseille_se}
    La page ne doit pas contenir d'erreur
    # Vérification de l'affichage de l'icone, la couleur et le titre de l'enjeu
    Wait Until Page Contains Element  css=i.ri-alert-line[style*="color:#${color_enjeu_pc_agglo}"]
    Wait Until Page Contains Element  css=i.ri-alert-line[title="${lib_enjeu_pc_agglo}"]

    # Cas 2 : affichage d'un dossier avec plusieurs enjeu
    Depuis la page d'accueil  instrpolycomm3  instrpolycomm3

    Depuis le listing  dossier_lies
    Use Simple Search  dossier  ${di_pc_allauch_se}
    La page ne doit pas contenir d'erreur
    Wait Until Page Contains Element  css=i.omi-alert-multiple-line

    Depuis le listing  dossier_lies_geographiquement
    ${da_allauch} =  Replace String Using Regexp  ${di_pc_allauch_se}  [A-Z][0-9]+$  ${EMPTY}
    Use Simple Search  dossier d'autorisation  ${da_allauch}
    La page ne doit pas contenir d'erreur
    Wait Until Page Contains Element  css=i.omi-alert-multiple-line

    Depuis le listing  dossier_lies_retour
    Use Simple Search  dossier  ${di_pc_allauch_se}
    La page ne doit pas contenir d'erreur
    Wait Until Page Contains Element  css=i.omi-alert-multiple-line


# Affichage des enjeux sur le widget : dossier limite -> Voir test 045_widgets::Widget "Dossiers Limites"


Affichage des enjeux sur les listings : clôturés
    [Documentation]

    # Cas 1 : affichage d'un dossier avec un seul enjeu
    Depuis la page d'accueil  instr  instr
    # Cloture du dossier
    Ajouter une instruction au DI et la finaliser  ${di_pc_marseille}  accepter un dossier avec reserve

    Depuis le listing  dossier_instruction_mes_clotures
    Use Simple Search  Tous  ${di_pc_marseille_se}
    La page ne doit pas contenir d'erreur
    # Vérification de l'affichage de l'icone, la couleur et le titre de l'enjeu
    Wait Until Page Contains Element  css=i.ri-alert-line[style*="color:#${color_enjeu_pc_agglo}"]
    Wait Until Page Contains Element  css=i.ri-alert-line[title="${lib_enjeu_pc_agglo}"]

    Depuis le listing  dossier_instruction_tous_clotures
    Use Simple Search  Tous  ${di_pc_marseille_se}
    La page ne doit pas contenir d'erreur
    # Vérification de l'affichage de l'icone, la couleur et le titre de l'enjeu
    Wait Until Page Contains Element  css=i.ri-alert-line[style*="color:#${color_enjeu_pc_agglo}"]
    Wait Until Page Contains Element  css=i.ri-alert-line[title="${lib_enjeu_pc_agglo}"]

    # Cas 2 : affichage d'un dossier avec plusieurs enjeu
    Depuis la page d'accueil  instrpolycomm3  instrpolycomm3
    # Cloture du dossier
    Ajouter une instruction au DI et la finaliser  ${di_pc_allauch}  accepter un dossier avec reserve

    Depuis le listing  dossier_instruction_mes_clotures
    Use Simple Search  Tous  ${di_pc_allauch_se}
    La page ne doit pas contenir d'erreur
    Wait Until Page Contains Element  css=i.omi-alert-multiple-line

    Depuis le listing  dossier_instruction_tous_clotures
    Use Simple Search  Tous  ${di_pc_allauch_se}
    La page ne doit pas contenir d'erreur
    Wait Until Page Contains Element  css=i.omi-alert-multiple-line