*** Settings ***
Documentation  Tests relatif aux imports et aux exports du paramétrage de bible.

# On inclut les mots-clefs
Resource  resources/resources.robot
# On ouvre/ferme le navigateur au début/à la fin du Test Suite.
Suite Setup  For Suite Setup
Suite Teardown  For Suite Teardown


*** Test Cases ***
Création du jeu de données
    [Documentation]  Isole un contexte puis récupère et set les identifiants de l'évenement,
    ...  la demande et la collectivité qui seront utilisés par la suite.

    Depuis la page d'accueil    admin    admin
    # isole le contexte du test (création d'une collectivité)
    &{isolation_values} =  Create Dictionary
    ...  om_collectivite_libelle=LIBREBIBLES1
    ...  departement=013
    ...  commune=099
    ...  insee=13099
    ...  direction_code=Z25
    ...  direction_libelle=Direction de LIBREBIBLES1
    ...  direction_chef=Chef
    ...  division_code=Z25
    ...  division_libelle=Division Z25
    ...  division_chef=Chef
    ...  guichet_om_utilisateur_nom=Alice Ecila
    ...  guichet_om_utilisateur_email=alicelecila@openads-test.fr
    ...  guichet_om_utilisateur_login=aecila
    ...  guichet_om_utilisateur_pwd=aecila
    ...  instr_om_utilisateur_nom=Eliot Toile
    ...  instr_om_utilisateur_email=eliottoile@openads-test.fr
    ...  instr_om_utilisateur_login=etoile
    ...  instr_om_utilisateur_pwd=etoile
    Isolation d'un contexte  ${isolation_values}

    # récupération des informations
    Depuis le contexte de la collectivité  LIBREBIBLES1
    ${collectivite_id} =  Get Text  css=span#om_collectivite
    Depuis le tableau des types de demandes
    Use Simple Search  type de dossier d'instruction  PCI - Initial
    Click on Link  PCI - Initial
    ${demande_type_id} =  Get Text  css=span#demande_type
    Depuis le contexte de l'événement  accepter un dossier sans réserve
    ${evenement_id} =  Get Text  css=span#evenement
    ${current_date} =  Get Current Date   exclude_millis=True
    ${current_date} =  Replace String  ${current_date}  ${SPACE}  _
    ${current_date} =  Replace String  ${current_date}  :  -

    # Préparations des variables
    Set Suite Variable  ${om_collectivite_libelle}  ${isolation_values.om_collectivite_libelle}
    Set Suite Variable  ${evenement_id}
    Set Suite Variable  ${demande_type_id}
    Set Suite Variable  ${collectivite_id}
    Set Suite Variable  ${current_date}

Ouvre le formulaire de l'import spécifique bible depuis le menu

    [Documentation]  Ce test case permet de vérifier que le formulaire d'import
    ...  spécifique de bibles, est accessible depuis le menu

    Depuis la page d'accueil    admin    admin
    Go To Submenu In Menu  administration  import_specific
    Click Element  id=action-import-bible-importer
    La page ne doit pas contenir d'erreur
    Page Should Not Contain  objet est invalide

Import spécifique de bibles
    [Documentation]  On vérifie que l'import spécifique de bibles fonctionne


    Depuis la page d'accueil    admin    admin

    # Verification de la possiblite d'importer sans le l'option precharge || BEGIN

    # produit le fichier d'import à partir du template
    ${import_bible_content} =  Get File  binary_files/import_specific_bible_no_precharge.csv.tpl
    ${import_bible_content} =  Replace String  ${import_bible_content}  evt  ${evenement_id}
    ${import_bible_content} =  Replace String  ${import_bible_content}  demande  ${demande_type_id}
    ${import_bible_content} =  Replace String  ${import_bible_content}  collectivite  ${collectivite_id}
    ${import_bible_file} =  Set Variable  import_bible_ok.${current_date}.csv
    Create File  binary_files/${import_bible_file}  ${import_bible_content}

    # va sur la page d'import spécifique de bibles
    Depuis l'import spécifique   bible

    # téléverse le fichier CSV des bibles à importer
    Add File  fic1  ${import_bible_file}
    Click On Submit Button In Import CSV

    # vérifie que l'opération est un succès
    Résultat de l'import doit contenir  4 ligne(s) dans le fichier dont :
    Résultat de l'import doit contenir  - 1 ligne(s) d'entête
    Résultat de l'import doit contenir  - 2 ligne(s) correcte(s)
    Résultat de l'import doit contenir  - 0 ligne(s) rejetée(s)
    Résultat de l'import doit contenir  - 1 ligne(s) vide(s)

    # vérifie que l'opération est un succès
    Résultat de l'import doit contenir  4 ligne(s) dans le fichier dont :
    Résultat de l'import doit contenir  - 1 ligne(s) d'entête
    Résultat de l'import doit contenir  - 2 ligne(s) correcte(s)
    Résultat de l'import doit contenir  - 0 ligne(s) rejetée(s)
    Résultat de l'import doit contenir  - 1 ligne(s) vide(s)

    # Verification de la possiblite d'importer sans le l'option precharge || END

    # produit le fichier d'import à partir du template
    ${import_bible_content} =  Get File  binary_files/import_specific_bible.csv.tpl
    ${import_bible_content} =  Replace String  ${import_bible_content}  evt  ${evenement_id}
    ${import_bible_content} =  Replace String  ${import_bible_content}  demande  ${demande_type_id}
    ${import_bible_content} =  Replace String  ${import_bible_content}  collectivite  ${collectivite_id}
    ${import_bible_file} =  Set Variable  import_bible_ok.${current_date}.csv
    Create File  binary_files/${import_bible_file}  ${import_bible_content}

    # va sur la page d'import spécifique de bibles
    Depuis l'import spécifique   bible

    # téléverse le fichier CSV des bibles à importer
    Add File  fic1  ${import_bible_file}
    Click On Submit Button In Import CSV

    # vérifie que l'opération est un succès
    Résultat de l'import doit contenir  4 ligne(s) dans le fichier dont :
    Résultat de l'import doit contenir  - 1 ligne(s) d'entête
    Résultat de l'import doit contenir  - 2 ligne(s) correcte(s)
    Résultat de l'import doit contenir  - 0 ligne(s) rejetée(s)
    Résultat de l'import doit contenir  - 1 ligne(s) vide(s)

    # ajoute un nouveau dossier (PC)
    &{args_demande_auto} =  Create Dictionary
    ...  dossier_autorisation_type_detaille=Permis de construire pour une maison individuelle et / ou ses annexes
    ...  demande_type=Dépôt Initial
    ...  om_collectivite=${om_collectivite_libelle}
    &{args_petitionnaire_auto} =  Create Dictionary
    ...  particulier_nom=Garnier
    ...  particulier_prenom=Arlette
    ...  om_collectivite=${om_collectivite_libelle}
    ${di} =  Ajouter la demande par WS  ${args_demande_auto}  ${args_petitionnaire_auto}

    # ajoute une nouvelle instruction (81 accepter un dossier sans réserve)
    Ajouter une instruction au DI  ${di}  accepter un dossier sans réserve

    # se rend sur la page de l'instruction
    Depuis l'instruction du dossier d'instruction  ${di}  accepter un dossier sans réserve

    # clique sur modifier
    Click On SubForm Portlet Action  instruction  modifier

    # clique sur le bouton "bible" dans un complément
    Ouvrir la bible du complément d'instruction n°  1

    # vérifie que les bibles proposées sont les bonnes
    Wait Until Keyword Succeeds  ${TIMEOUT}  ${RETRY_INTERVAL}  Element Text Should Be  content0  test1

    # en sélectionne une et valide son application
    Select Checkbox  xpath=//*[text()[contains(.,"test1")]]/ancestor::tr/*/input
    Click Element  css=div.ui-dialog>div#upload-container>div>form>div.formControls input[type="submit"]

    # vérifie que ce contenu correspond à celui de la bible sélectionnée
    HTML Should Contain  complement_om_html  Ceci est le test 1

    # Clique sur la bible automatique du second complément
    Ajout automatique de complément(s) d'instruction

    # Vérifie que la bible automatique fonctionne
    HTML Should Contain  complement2_om_html  Ceci est le test 2

Export des bibles
    [Documentation]  Test l'export des bibles

    # On s'identifie en tant qu'admin
    Depuis la page d'accueil  admin  admin
    # On accède au menu Export/Import > Requête mémorisée > Bible via son url
    Go To  ${PROJECT_URL}${OM_ROUTE_MODULE_REQMO}&obj=bible

    # Remplissage du formulaire de la reqmo, par défaut les valeurs sont
    #  - Tri : libellé ASC
    #  - Format de sortie : Tableau - Affichage à l'écran
    #  - Séparateur : ; (point virgule)
    #  - Nombre limite d'enregistrement : 100
    # Les valeurs par défaut suffisent pour ce test, le test se contente dons
    # de cliquer sur le bouton de validation
    Click On Submit Button In Reqmo

    # Vérification des résultats
    Element Should Contain  css=.tab-tab  test1 Ceci est le test 1 {{${evenement_id},1,Non,Oui,${demande_type_id},${collectivite_id}}}
    Element Should Contain  css=.tab-tab  test2 Ceci est le test 2 {{${evenement_id},2,Oui,Non,${demande_type_id},${collectivite_id}}}