*** Settings ***
Documentation     TestSuite "Documentation" : cette suite permet d'extraire
...    automatiquement les captures à destination de la documentation.
# On inclut les mots-clefs
Resource    resources/resources.robot
# On ouvre et on ferme le navigateur respectivement au début et à la fin
# du Test Suite.
Suite Setup    For Suite Setup
Suite Teardown    For Suite Teardown
# A chaque début de Test Case on positionne la taille de la fenêtre
# pour obtenir des captures homogènes
Test Setup    Set Window Size  ${1280}  ${1024}

*** Test Cases ***
Constitution d'un jeu de données

    [Documentation]  L'objet de ce 'Test Case' est de constituer un jeu de de
    ...    données cohérent pour les scénarios fonctionnels qui suivent.

    [Tags]  doc

    Depuis la page d'accueil  admin  admin

    # SCREEN : a_instruction_dossier_instruction_message_champs_requis_platau
    &{args_type_DA_detaille_modification} =  Create Dictionary
    ...  dossier_platau=true
    Modifier type de dossier d'autorisation détaillé  PCI  ${args_type_DA_detaille_modification}
    Modifier type de dossier d'autorisation détaillé  DP  ${args_type_DA_detaille_modification}
    # isole le contexte du test (création d'une collectivité)
    &{librecom_multi_1_values} =  Create Dictionary
    ...  om_collectivite_libelle=LIBRECOM_WS_CONTROLE_DONNEE_MULTI_1
    ...  departement=019
    ...  commune=100
    ...  insee=19100
    ...  direction_code=BCD
    ...  direction_libelle=Direction de LIBRECOM_WS_CONTROLE_DONNEE_MULTI_1
    ...  direction_chef=Chef
    ...  division_code=BCD
    ...  division_libelle=Division BCD
    ...  division_chef=Chef
    ...  guichet_om_utilisateur_nom=Pacquenett Lerrault
    ...  guichet_om_utilisateur_email=plerrault@openads-test.fr
    ...  guichet_om_utilisateur_login=plerrault
    ...  guichet_om_utilisateur_pwd=plerrault
    ...  instr_om_utilisateur_nom=Molaine Trimard
    ...  instr_om_utilisateur_email=mtrimard@openads-test.fr
    ...  instr_om_utilisateur_login=mtrimard
    ...  instr_om_utilisateur_pwd=mtrimard
    ...  code_entite=LBCOM_24
    ...  acteur=LIBRECOM-ACT-024
    Isolation d'un contexte  ${librecom_multi_1_values}
    ${code_service1} =  Set Variable  300
    ${libelle_service1} =  Set Variable  TEST300SERVIC01
    &{args_service} =  Create Dictionary
    ...  abrege=${code_service1}
    ...  libelle=${libelle_service1}
    ...  edition=Consultation - Demande d'avis
    ...  om_collectivite=LIBRECOM_WS_CONTROLE_DONNEE_MULTI_1
    ...  service_type=Plat'AU
    ...  generate_edition=true
    Ajouter le service depuis le listing  ${args_service}
    &{args_dossier} =  Create Dictionary
    ...  om_collectivite=LIBRECOM_WS_CONTROLE_DONNEE_MULTI_1
    ...  dossier_autorisation_type_detaille=Permis de construire pour une maison individuelle et / ou ses annexes
    ...  demande_type=Dépôt Initial
    &{args_petitionnaire1} =  Create Dictionary
    ...  qualite=particulier
    ...  particulier_nom=TEST300TASKNOM01
    ...  particulier_prenom=TEST300TASKPRENOM01
    ...  om_collectivite=LIBRECOM_WS_CONTROLE_DONNEE_MULTI_1
    ${di_a_instruction_dossier_instruction_message_champs_requis_platau} =  Ajouter la demande par WS  ${args_dossier}  ${args_petitionnaire1}
    &{document_numerise_values} =  Create Dictionary
    ...  uid_upload=testImportManuel.pdf
    ...  date_creation=10/09/2016
    ...  document_numerise_type=Test type document numerise de catégorie PLATAU
    Ajouter une pièce depuis le dossier d'instruction  ${di_a_instruction_dossier_instruction_message_champs_requis_platau}  ${document_numerise_values}
    Click On Back Button In Subform
    Click Link  Test type document numerise de catégorie PLATAU
    Set Suite Variable  ${di_a_instruction_dossier_instruction_message_champs_requis_platau}


    # SCREEN : a_instruction_dossier_instruction_form_petitionnaires_fieldset
    Depuis la page d'accueil  guichet  guichet
    &{args_petitionnaire} =  Create Dictionary
    ...  particulier_nom=Moquin
    ...  particulier_prenom=Laurent
    ...  om_collectivite=MARSEILLE
    &{args_demande} =  Create Dictionary
    ...  dossier_autorisation_type_detaille=Permis de construire pour une maison individuelle et / ou ses annexes
    ...  demande_type=Dépôt Initial
    ...  om_collectivite=MARSEILLE
    ${di} =  Ajouter la demande par WS  ${args_demande}  ${args_petitionnaire}
    Depuis la page d'accueil  admin  admin
    Modifier le paramètre  option_portail_acces_citoyen  true  agglo
    Depuis la page d'accueil  guichet  guichet
    &{args_demande} =  Create Dictionary
    ...  demande_type=Demande de modification
    ...  dossier_instruction=${di}
    ${di_modif} =  Ajouter la demande par WS  ${args_demande}
    Set Suite Variable  ${di_modif}


    # SCREEN : a_instruction_dossier_geolocalisation
    Depuis la page d'accueil  admin  admin
    Ajouter la collectivité depuis le menu  Plan de Cuques  mono
    Ajouter une bible depuis l'onglet de l'événement  Notification du delai legal maison individuelle  Exemple1  Exemple1  complément 1  Oui  Permis de construire  Plan de Cuques
    Ajouter une bible depuis l'onglet de l'événement  Notification du delai legal maison individuelle  Exemple2  Exemple2  complément 1  Oui  Permis de construire  Plan de Cuques
    Ajouter une bible depuis l'onglet de l'événement  Notification du delai legal maison individuelle  Exemple3  Exemple3  complément 1  Oui  Permis de construire  Plan de Cuques
    Ajouter l'utilisateur  Huard Franck  support@atreal.fr  instrcuq  instrcuq  INSTRUCTEUR  Plan de Cuques
    Ajouter la direction depuis le menu  PDC  Direction PDC  null  Chef PDC  null  null  Plan de Cuques
    Ajouter la division depuis le menu  PDC  subdivision PDC  null  Chef PDC  null  null  Direction PDC
    Ajouter l'instructeur depuis le menu  Huard Franck  subdivision PDC  instructeur  Huard Franck
    &{args_affectation} =  Create Dictionary
    ...  instructeur=Huard Franck (PDC)
    ...  om_collectivite=Plan de Cuques
    Ajouter l'affectation depuis le menu  ${args_affectation}
    &{args_type_da} =  Create Dictionary
    ...  code=PCI
    Modifier le type de dossier d'autorisation  PC  ${args_type_da}
    &{args_petitionnaire} =  Create Dictionary
    ...  particulier_nom=Pellerin
    ...  particulier_prenom=Olivier
    ...  om_collectivite=Plan de Cuques
    &{args_demande} =  Create Dictionary
    ...  dossier_autorisation_type_detaille=Permis de construire pour une maison individuelle et / ou ses annexes
    ...  demande_type=Dépôt Initial
    ...  om_collectivite=Plan de Cuques
    ${di_libelle} =  Ajouter la demande par WS  ${args_demande}  ${args_petitionnaire}
    Set Suite Variable  ${di_libelle}
    Depuis l'onglet instruction du dossier d'instruction  ${di_libelle}
    Click On Link  Notification du delai legal maison individuelle
    Click On SubForm Portlet Action  instruction  definaliser
    Click On Back Button In Subform
    Click On Link  Notification du delai legal maison individuelle
    Click On SubForm Portlet Action  instruction  modifier
    Ajout automatique de complément(s) d'instruction

    Depuis la page d'accueil  admin  admin

CE des instruction

    [Documentation]  L'objet de ce 'Test Case' est de constituer les screen en lien avec les guichet

    [Tags]  doc

    &{param_values} =  Create Dictionary
    ...  libelle=option_sig
    ...  valeur=sig_externe
    ...  om_collectivite=agglo
    Ajouter ou modifier le paramètre depuis le menu  ${param_values}
    &{om_param} =  Create Dictionary
    ...  libelle=option_streetview
    ...  valeur=true
    ...  om_collectivite=MARSEILLE
    Ajouter ou modifier le paramètre depuis le menu  ${om_param}
    Depuis le contexte du dossier d'instruction  PC 013055 12 00001P0
    CCSS  screenshots/instruction/a_instruction_dossier_geolocalisation.png
    ...  css=#fieldset-form-dossier_instruction-localisation

    Depuis le contexte du dossier d'instruction  ${di_modif}
    Click Element  css=.ui-corner-all.ui-widget-content.ui-state-active.collapsible
    CCSS  screenshots/instruction/a_instruction_dossier_instruction_form_petitionnaires_fieldset.png
    ...  css=#fieldset-form-dossier_instruction-demandeur

    Depuis le contexte du dossier d'instruction  ${di_a_instruction_dossier_instruction_message_champs_requis_platau}
    CCSS  screenshots/instruction/a_instruction_dossier_instruction_message_champs_requis_platau.png
    ...  css=.panel_information.ui-widget.ui-corner-all.ui-state-highlight.ui-state-demat-color.demat-color-text