*** Settings ***
Documentation     TestSuite "Documentation" : cette suite permet d'extraire
...    automatiquement les captures à destination de la documentation.
# On inclut les mots-clefs
Resource    resources/resources.robot
# On ouvre et on ferme le navigateur respectivement au début et à la fin
# du Test Suite.
Suite Setup    For Suite Setup
Suite Teardown    For Suite Teardown
# A chaque début de Test Case on positionne la taille de la fenêtre
# pour obtenir des captures homogènes
Test Setup    Set Window Size  ${1280}  ${1024}

*** Test Cases ***
Constitution d'un jeu de données

    [Documentation]  L'objet de ce 'Test Case' est de constituer un jeu de de
    ...    données cohérent pour les scénarios fonctionnels qui suivent.

    [Tags]  doc

    Depuis la page d'accueil  guichet  guichet

    # SCREEN : a_guichet_unique_affichage_reglementaire_attestation_message_lien_attestation
    Depuis la page d'accueil  guichet  guichet
    Go To Submenu In Menu  guichet_unique  affichage_reglementaire_registre
    Click Element  id=registre-form-submit
    Cliquer sur le bouton de la fenêtre modale  Confirmer

CE des guichet
    [Documentation]  L'objet de ce 'Test Case' est de constituer les screen en lien avec les guichet

    [Tags]  doc

    Go To    ${PROJECT_URL}${OM_ROUTE_FORM}&obj=demande_affichage_reglementaire_attestation&action=120&idx=0
    CCSS  screenshots/guichet/a_guichet_unique_affichage_reglementaire_attestation_formulaire.png
    ...    css=#formulaire

    Input Text  dossier  dossierKO
    Click On Submit Button
    CCSS  screenshots/guichet/a_guichet_unique_affichage_reglementaire_attestation_message_dossier_inexistant.png
    ...    css=.message.ui-widget.ui-corner-all.ui-state-highlight.ui-state-error

    Input Text  dossier  AT 013055 12 00001P0
    Click On Submit Button
    CCSS  screenshots/guichet/a_guichet_unique_affichage_reglementaire_attestation_message_dossier_jamais_affiche.png
    ...    css=.message.ui-widget.ui-corner-all.ui-state-highlight.ui-state-error

    Input Text  css=#dossier  PC0130551200002P0
    Click On Submit Button Until Message  Cliquez sur le lien ci-dessous pour télécharger votre attestation d'affichage
    CCSS  screenshots/guichet/a_guichet_unique_affichage_reglementaire_attestation_message_lien_attestation.png
    ...    css=.message.ui-widget.ui-corner-all.ui-state-highlight.ui-state-valid

    Depuis la page d'accueil  admin  admin
    &{param_values} =  Create Dictionary
    ...  libelle=id_affichage_obligatoire
    ...  valeur=false
    ...  om_collectivite=agglo
    Ajouter ou modifier le paramètre depuis le menu  ${param_values}
    Go To    ${PROJECT_URL}${OM_ROUTE_FORM}&obj=demande_affichage_reglementaire_attestation&action=120&idx=0
    CCSS  screenshots/guichet/a_guichet_unique_affichage_reglementaire_message_erreur_parametrage.png
    ...    css=.message.ui-widget.ui-corner-all.ui-state-highlight.ui-state-error
    &{param_values} =  Create Dictionary
    ...  libelle=id_affichage_obligatoire
    ...  valeur=true
    ...  om_collectivite=agglo
    Ajouter ou modifier le paramètre depuis le menu  ${param_values}
    Depuis la page d'accueil  guichet  guichet

    Click Element  css=.rubrik.guichet_unique.ui-accordion-li-fix
    CCSS  screenshots/guichet/a_guichet_unique_menu.png
    ...    css=.rubrik.guichet_unique.ui-accordion-li-fix