*** Settings ***
Documentation  Test les dépôts de demandes

# On inclut les mots-clefs
Resource  resources/resources.robot
# On ouvre/ferme le navigateur au début/à la fin du Test Suite.
Suite Setup  For Suite Setup
Suite Teardown  For Suite Teardown


*** Keywords ***
Activer la saisie du numéro de dossier
    [Documentation]  Permet d'activer la saisie du numéro de dossier par sections sur le formulaire
    ...  d'ajout d'une nouvelle demande
    Click Element  css=#num_doss_manuel  
    Wait Until Keyword Succeeds  ${TIMEOUT}  ${RETRY_INTERVAL}  Element Should Be Visible  css=#num_doss_sequence
    Wait Until Keyword Succeeds  ${TIMEOUT}  ${RETRY_INTERVAL}  Element Should Not Be Visible  css=#num_doss_sequence[disabled="disabled"]


*** Test Cases ***
Vérification du bon fonctionnement de la date de dépôt en mairie
    Depuis la page d'accueil  admin  admin

    # On active l'option option_date_depot_mairie
    &{param_values} =  Create Dictionary
    ...  libelle=option_date_depot_mairie
    ...  valeur=true
    ...  om_collectivite=agglo
    Ajouter le paramètre depuis le menu (surcharge)  ${param_values}

    # Ajout d'un dossier avec la date de dépôt en mairie à la date du jour
    &{args_demande} =  Create Dictionary
    ...  dossier_autorisation_type_detaille=Permis de construire pour une maison individuelle et / ou ses annexes
    ...  demande_type=Dépôt Initial
    ...  om_collectivite=MARSEILLE
    ...  date_depot_mairie=${date_ddmmyyyy}
    &{args_petitionnaire} =  Create Dictionary
    ...  particulier_nom=TEST030NOM
    ...  particulier_prenom=TEST030PRENOM
    ...  om_collectivite=MARSEILLE
    ${di_date_depot_mairie} =  Ajouter la demande par WS  ${args_demande}  ${args_petitionnaire}

    # On vérifie que la date de dépot en mairie est modifiable à la main dans le dossier d'instruction
    Depuis le contexte du dossier d'instruction  ${di_date_depot_mairie}
    Wait Until Form Value Should Be  css=#date_depot_mairie  ${date_ddmmyyyy}

    # On vérifie que l'année ne peut pas être modifiée
    Click On Form Portlet Action  dossier_instruction  modifier
    Input Text  date_depot_mairie  16/02/2015
    Click On Submit Button

    Error Message Should Contain  L'année de la date de dépôt en mairie n'est pas modifiable.
    Error Message Should Contain  SAISIE NON ENREGISTRÉE
    Click On Back Button

    ${date_annee_yyyy} =  Get Time  year
    ${date_depot_mairie} =  Create Dictionary
    ...  date_depot_mairie=16/02/${date_annee_yyyy}

    Modifier le dossier d'instruction  ${di_date_depot_mairie}  ${date_depot_mairie}

    Depuis le contexte du dossier d'instruction  ${di_date_depot_mairie}
    Wait Until Form Value Should Be  css=#date_depot_mairie  ${date_depot_mairie.date_depot_mairie}

    ${date_depot_mairie} =  Create Dictionary
    ...  date_depot_mairie=${date_ddmmyyyy}

    Modifier le dossier d'instruction  ${di_date_depot_mairie}  ${date_depot_mairie}

    ${date_depot_mairie_for_calc} =  Get Value  date_depot_mairie

    # On ajoute une instruction qui majore le délai d'instruction
    &{args_action} =  Create Dictionary
    ...  action=majore_delai_instruction
    ...  libelle=Majorer le délai d'instruction
    ...  regle_delai=archive_delai+delai
    ...  regle_accord_tacite=accord_tacite
    ...  regle_date_limite=date_depot_mairie+delai+archive_delai
    Ajouter l'action depuis le menu  ${args_action}
    @{etat_source} =  Create List  delai de notification envoye
    @{type_di} =  Create List  PCI - P - Initial
    &{args_evenement} =  Create Dictionary
    ...  libelle=Majorer le délai d'instruction
    ...  etats_depuis_lequel_l_evenement_est_disponible=${etat_source}
    ...  dossier_instruction_type=${type_di}
    ...  delai=3 Mois
    ...  action=Majorer le délai d'instruction
    Ajouter l'événement depuis le menu  ${args_evenement}

    Ajouter une instruction au DI  ${di_date_depot_mairie}  Majorer le délai d'instruction

    # La date limite doit être à 5 mois de plus de celle calculé par défaut
    # calcul du jour identique 5 mois après (+5 mois)
    ${date_depot_mairie_for_calc_calculated} =  Ajouter ou supprimer des mois à une date  5  ${date_depot_mairie_for_calc}

    Depuis le contexte du dossier d'instruction  ${di_date_depot_mairie}
    Wait Until Keyword Succeeds  ${TIMEOUT}  ${RETRY_INTERVAL}  Element Should Contain  date_limite  ${date_depot_mairie_for_calc_calculated}


    # On ajoute une instruction qui modifie le délai d'instruction
    &{args_action} =  Create Dictionary
    ...  action=modif_delai_instruction
    ...  libelle=Modifier le délai d'instruction
    ...  regle_delai=delai
    ...  regle_accord_tacite=accord_tacite
    ...  regle_date_limite=date_depot_mairie+delai
    Ajouter l'action depuis le menu  ${args_action}
    @{etat_source} =  Create List  delai de notification envoye
    @{type_di} =  Create List  PCI - P - Initial
    &{args_evenement} =  Create Dictionary
    ...  libelle=Modifier le délai d'instruction
    ...  etats_depuis_lequel_l_evenement_est_disponible=${etat_source}
    ...  dossier_instruction_type=${type_di}
    ...  delai=1 Mois
    ...  action=Modifier le délai d'instruction
    Ajouter l'événement depuis le menu  ${args_evenement}

    Ajouter une instruction au DI  ${di_date_depot_mairie}  Modifier le délai d'instruction

    # La date limite doit être à 1 mois de moins de celle calculé par défaut
    # On utilise la date de dépôt en mairie afin de calculer la nouvelle date limite d'instruction
    ${date_depot_mairie_for_calc_calculated} =  Ajouter ou supprimer des mois à une date  1  ${date_depot_mairie_for_calc}

    Depuis le contexte du dossier d'instruction  ${di_date_depot_mairie}
    Wait Until Keyword Succeeds  ${TIMEOUT}  ${RETRY_INTERVAL}  Element Should Contain  date_limite  ${date_depot_mairie_for_calc_calculated}

    &{param_args} =  Create Dictionary
    ...  selection_col=libellé
    ...  search_value=option_date_depot_mairie
    ...  click_value=agglo
    Supprimer le paramètre (surcharge)  ${param_args}

Vérification de la prise en compte de l'année de la date de dépôt en mairie lors de la numérotation manuelle

    Depuis la page d'accueil  admin  admin

    # Active l'option de numérotation forcée
    &{param_values} =  Create Dictionary
    ...  libelle=option_dossier_saisie_numero
    ...  valeur=true
    ...  om_collectivite=agglo
    Ajouter le paramètre depuis le menu (surcharge)  ${param_values}

    # On active l'option option_date_depot_mairie
    &{param_values} =  Create Dictionary
    ...  libelle=option_date_depot_mairie
    ...  valeur=true
    ...  om_collectivite=agglo
    Ajouter le paramètre depuis le menu (surcharge)  ${param_values}

    # On vérifie que lorsque les deux options sont activées elles fonctionnent correctement entre elles
    Go To Submenu In Menu  guichet_unique  nouveau-dossier

    Select From List By Label  om_collectivite  MARSEILLE
    Select From Chosen List Should Contain  dossier_autorisation_type_detaille  DECLARATION PREALABLE SIMPLE
    Select From Chosen List  dossier_autorisation_type_detaille  DECLARATION PREALABLE SIMPLE

    Wait Until Keyword Succeeds  ${TIMEOUT}  ${RETRY_INTERVAL}  Element Should Be Visible  date_depot_mairie

    ${date_annee_yyyy} =  Get Time  year
    ${date_annee_yy} =  Get Substring  ${date_annee_yyyy}  -2
    Wait Until Form Value Should Be  css=#num_doss_annee  ${date_annee_yy}

    Input Text  date_depot_mairie  16/02/2015
    Input Text  date_demande  ${date_ddmmyyyy}

    Wait Until Form Value Should Be  css=#num_doss_annee  15

    &{args_petitionnaire} =  Create Dictionary
    ...  om_collectivite=MARSEILLE
    ...  particulier_civilite=Monsieur
    ...  particulier_nom=DURAND
    Ajouter le demandeur  petitionnaire_principal  ${args_petitionnaire}

    Activer la saisie du numéro de dossier
    Input Text  num_doss_division  A
    Click On Submit Button
    Valid Message Should Contain  DP 013055 15 A0001

    Click Element  link_demande_dossier_instruction
    Element Should Contain  dossier_libelle  DP 013055 15 A0001P0

    &{param_args} =  Create Dictionary
    ...  selection_col=libellé
    ...  search_value=option_date_depot_mairie
    ...  click_value=agglo
    Supprimer le paramètre (surcharge)  ${param_args}

    &{param_args} =  Create Dictionary
    ...  selection_col=libellé
    ...  search_value=option_dossier_saisie_numero
    ...  click_value=agglo
    Supprimer le paramètre (surcharge)  ${param_args}

TNR Vérification du numéro de siret

     # On se connecte à l'application
    Depuis la page d'accueil  admin  admin

    Go To Submenu In Menu  guichet_unique  nouveau-dossier

    # Informations à saisir
    &{args_demande} =  Create Dictionary
    ...  dossier_autorisation_type_detaille=Permis de construire pour une maison individuelle et / ou ses annexes
    ...  om_collectivite=MARSEILLE
    &{args_petitionnaire} =  Create Dictionary
    ...  qualite=personne morale
    ...  personne_morale_denomination=Notaire&Co
    ...  personne_morale_raison_sociale=Société
    ...  personne_morale_civilite=Monsieur
    ...  personne_morale_nom=Martin
    ...  personne_morale_prenom=Nicolas
    ...  personne_morale_siret=12345678912345
    ...  om_collectivite=MARSEILLE
    # On remplit les champs de la demande
    Saisir la demande  ${args_demande}
    # On ajoute le pétitionnaire
    Click Element Until New Element  add_petitionnaire_principal  css=.ui-widget-overlay

    # Contrôle du numéro siret
    Select From List By Label  css=#qualite  personne morale
    # On saisi un numéro siret qui n'a pas 14 caractères
    Input Text  css=#personne_morale_siret  123456789

    Click Element  css=#sousform-petitionnaire input[value="Ajouter le demandeur"]

    # Vérification du message d'erreur
    Error Message Should Contain  Le champ siret doit contenir 14 caractères.

    # On ferme l'overlay
    Click Element Until No More Element  css=.ui-icon-closethick

    Ajouter le demandeur  petitionnaire_principal  ${args_petitionnaire}

    Click On Submit Button


TNR la date de dépôt ne doit pas être supérieur à la date du jour
    [Documentation]  Ce test vérifie que si dans le formualire de nouvelle demande
    ...  l'utilisateur à saisi une date de demande dans le futur un message d'erreur
    ...  s'affiche et ses modifications ne sont pas enregistrées

    Depuis la page d'accueil  guichet  guichet

    ${demain} =  Add Time To Date  ${date_ddmmyyyy}  1 days  %d/%m/%Y  True  %d/%m/%Y
    &{args_demande} =  Create Dictionary
    ...  dossier_autorisation_type_detaille=Permis de construire pour une maison individuelle et / ou ses annexes
    ...  date_demande=${demain}
    &{args_petitionnaire} =  Create Dictionary
    ...  qualite=personne morale
    ...  personne_morale_denomination=Notaire&Co
    ...  personne_morale_raison_sociale=Société
    ...  personne_morale_civilite=Monsieur
    ...  personne_morale_nom=Martin
    ...  personne_morale_prenom=Nicolas
    ...  personne_morale_siret=12345678912345
    # On remplit les champs de la demande
    Go To Submenu In Menu  guichet_unique  nouveau-dossier
    Saisir la demande  ${args_demande}
    Ajouter le demandeur  petitionnaire_principal  ${args_petitionnaire}
    Click On Submit Button
    Error Message Should Contain  La date de demande ne peut pas être superieure à la date du jour.

TNR vérification utilisation de département Corse (2A)
    [Documentation]  Permet la vérification de l'utilisation du département Corse (2A) et de son bon fonctionnement

    Depuis la page d'accueil  admin  admin

    # Activation du paramètre option dossier commune
    &{param_division} =  Create Dictionary
    ...  libelle=option_dossier_commune
    ...  valeur=true
    ...  om_collectivite=agglo
    Ajouter ou modifier le paramètre depuis le menu  ${param_division}

    # Activation de l'option dossier saisie numero
    &{param_values} =  Create Dictionary
    ...  libelle=option_dossier_saisie_numero
    ...  valeur=true
    ...  om_collectivite=agglo
    Ajouter ou modifier le paramètre depuis le menu  ${param_values}

    # Ajouter commune Corse 2A
    &{corse_commune} =  Create Dictionary
    ...  typecom=COM
    ...  com=2A390
    ...  reg=12
    ...  dep=2A
    ...  arr=645
    ...  libelle=Corse
    Ajouter commune avec dates validité  ${corse_commune}

    # Ajouter une demande
    &{args_demande} =  Create Dictionary
    ...  dossier_autorisation_type_detaille=Permis de construire pour une maison individuelle et / ou ses annexes
    ...  commune=2A390 - Corse
    ...  terrain_adresse_code_postal=2A390
    ...  om_collectivite=MARSEILLE
    &{args_petitionnaire} =  Create Dictionary
    ...  particulier_nom=Dada
    ...  particulier_prenom=Idi Amin
    ...  om_collectivite=MARSEILLE
    ${new_dossier} =  Ajouter la nouvelle demande  ${args_demande}  ${args_petitionnaire}
    
    Depuis le listing  dossier_instruction

    Input Text  css=div#adv-search-adv-fields input#dossier  ${new_dossier}
    Click On Search Button

    # Vérification que le dossier à bien été enregistrer et que les numero de dossier et la localisation
    # correspondent bien aux données saisis précédemment
    Element Should Contain  css=#tab-dossier_instruction table.tab-tab tbody td.col-3  ${new_dossier}
    Click Element  css=#tab-dossier_instruction table.tab-tab tbody td.col-3

    ${get_num_dossier} =  Get Text  dossier_libelle

    Should Be Equal  ${new_dossier}  ${get_num_dossier}
    Wait Until Element Contains  css=.localisation-terrain-adresse  ${args_demande.terrain_adresse_code_postal}     

    # Désactivation du paramètre option dossier commune
    &{param_division} =  Create Dictionary
    ...  libelle=option_dossier_commune
    ...  valeur=false
    ...  om_collectivite=agglo
    Ajouter ou modifier le paramètre depuis le menu  ${param_division}

    # Désactivation de l'option dossier saisie numero
    &{param_values} =  Create Dictionary
    ...  libelle=option_dossier_saisie_numero
    ...  valeur=false
    ...  om_collectivite=agglo
    Ajouter ou modifier le paramètre depuis le menu  ${param_values}


Les dossiers liés géograhiquement sont filtrés par commune
    [Documentation]  Ce test case a pour but de vérifier que les dossiers liés géographiquement
    ...  sont bien filtrés par commune, ainsi que par collectivité/service

    Depuis la page d'accueil  admin  admin
    # Activation du paramètre permettant d'accéder au champ commune
    &{param_values} =  Create Dictionary
    ...  libelle=option_dossier_commune
    ...  valeur=true
    ...  om_collectivite=agglo
    Ajouter ou modifier le paramètre depuis le menu  ${param_values}

    # communes
    &{com_mars_1_values} =  Create Dictionary
    ...  typecom=COM
    ...  com=13001
    ...  reg=13
    ...  dep=13
    ...  arr=001
    ...  tncc=0
    ...  ncc=Mars1
    ...  nccenr=Mars1
    ...  libelle=Marseille 1er
    ...  can=1
    ...  comparent=
    Ajouter commune avec dates validité  ${com_mars_1_values}
    &{com_mars_2_values} =  Create Dictionary
    ...  typecom=COM
    ...  com=13002
    ...  reg=13
    ...  dep=13
    ...  arr=002
    ...  tncc=0
    ...  ncc=Mars2
    ...  nccenr=Mars2
    ...  libelle=Marseille 2ème
    ...  can=1
    ...  comparent=
    Ajouter commune avec dates validité  ${com_mars_2_values}
    &{com_allauch_values} =  Create Dictionary
    ...  typecom=COM
    ...  com=13190
    ...  reg=13
    ...  dep=13
    ...  arr=000
    ...  tncc=0
    ...  ncc=Allauch
    ...  nccenr=Allauch
    ...  libelle=Allauch
    ...  can=1
    ...  comparent=
    Ajouter commune avec dates validité  ${com_allauch_values}

    &{args_petitionnaire} =  Create Dictionary
    ...  particulier_nom=Rick
    ...  particulier_prenom=Pat
    ...  om_collectivite=MARSEILLE
    @{ref_cad} =  Create List  000  0A  0001
    &{args_demande_1} =  Create Dictionary
    ...  dossier_autorisation_type_detaille=Permis de construire pour une maison individuelle et / ou ses annexes
    ...  terrain_references_cadastrales=${ref_cad}
    ...  om_collectivite=MARSEILLE
    ...  commune=13001 - Marseille 1er
    ${libelle_di_1} =  Ajouter la nouvelle demande  ${args_demande_1}  ${args_petitionnaire}
    &{args_demande_2} =  Create Dictionary
    ...  dossier_autorisation_type_detaille=Permis de construire pour une maison individuelle et / ou ses annexes
    ...  terrain_references_cadastrales=${ref_cad}
    ...  om_collectivite=MARSEILLE
    ...  commune=13001 - Marseille 1er
    ${libelle_di_2} =  Ajouter la nouvelle demande  ${args_demande_2}  ${args_petitionnaire}
    &{args_demande_3} =  Create Dictionary
    ...  dossier_autorisation_type_detaille=Permis de construire pour une maison individuelle et / ou ses annexes
    ...  terrain_references_cadastrales=${ref_cad}
    ...  om_collectivite=MARSEILLE
    ...  commune=13002 - Marseille 2ème
    ${libelle_di_3} =  Ajouter la nouvelle demande  ${args_demande_3}  ${args_petitionnaire}
    &{args_demande_4} =  Create Dictionary
    ...  dossier_autorisation_type_detaille=Permis de construire pour une maison individuelle et / ou ses annexes
    ...  terrain_references_cadastrales=${ref_cad}
    ...  om_collectivite=ALLAUCH
    ...  commune=13001 - Marseille 1er
    ${libelle_di_4} =  Ajouter la nouvelle demande  ${args_demande_4}  ${args_petitionnaire}
    &{args_demande_5} =  Create Dictionary
    ...  dossier_autorisation_type_detaille=Permis de construire pour une maison individuelle et / ou ses annexes
    ...  terrain_references_cadastrales=${ref_cad}
    ...  om_collectivite=ALLAUCH
    ...  commune=13190 - Allauch
    ${libelle_di_5} =  Ajouter la nouvelle demande  ${args_demande_5}  ${args_petitionnaire}

    ${libelle_di_1_noP0} =  Replace String Using Regexp  ${libelle_di_1}  P0$  ${EMPTY}
    ${libelle_di_2_noP0} =  Replace String Using Regexp  ${libelle_di_2}  P0$  ${EMPTY}
    ${libelle_di_3_noP0} =  Replace String Using Regexp  ${libelle_di_3}  P0$  ${EMPTY}
    ${libelle_di_4_noP0} =  Replace String Using Regexp  ${libelle_di_4}  P0$  ${EMPTY}
    ${libelle_di_5_noP0} =  Replace String Using Regexp  ${libelle_di_5}  P0$  ${EMPTY}

    Depuis l'onglet Dossiers Liés du dossier d'instruction  ${libelle_di_1}
    Element Should Contain  sousform-dossier_lies_geographiquement  ${libelle_di_2_noP0}
    Element Should Not Contain  sousform-dossier_lies_geographiquement  ${libelle_di_3_noP0}
    Element Should Not Contain  sousform-dossier_lies_geographiquement  ${libelle_di_4_noP0}
    Element Should Not Contain  sousform-dossier_lies_geographiquement  ${libelle_di_5_noP0}

    Depuis l'onglet Dossiers Liés du dossier d'instruction  ${libelle_di_2}
    Element Should Contain  sousform-dossier_lies_geographiquement  ${libelle_di_1_noP0}
    Element Should Not Contain  sousform-dossier_lies_geographiquement  ${libelle_di_3_noP0}
    Element Should Not Contain  sousform-dossier_lies_geographiquement  ${libelle_di_4_noP0}
    Element Should Not Contain  sousform-dossier_lies_geographiquement  ${libelle_di_5_noP0}

    Depuis l'onglet Dossiers Liés du dossier d'instruction  ${libelle_di_3}
    Element Should Not Contain  sousform-dossier_lies_geographiquement  ${libelle_di_1_noP0}
    Element Should Not Contain  sousform-dossier_lies_geographiquement  ${libelle_di_2_noP0}
    Element Should Not Contain  sousform-dossier_lies_geographiquement  ${libelle_di_4_noP0}
    Element Should Not Contain  sousform-dossier_lies_geographiquement  ${libelle_di_5_noP0}

    Depuis l'onglet Dossiers Liés du dossier d'instruction  ${libelle_di_4}
    Element Should Not Contain  sousform-dossier_lies_geographiquement  ${libelle_di_1_noP0}
    Element Should Not Contain  sousform-dossier_lies_geographiquement  ${libelle_di_2_noP0}
    Element Should Not Contain  sousform-dossier_lies_geographiquement  ${libelle_di_3_noP0}
    Element Should Not Contain  sousform-dossier_lies_geographiquement  ${libelle_di_5_noP0}

    Depuis l'onglet Dossiers Liés du dossier d'instruction  ${libelle_di_5}
    Element Should Not Contain  sousform-dossier_lies_geographiquement  ${libelle_di_1_noP0}
    Element Should Not Contain  sousform-dossier_lies_geographiquement  ${libelle_di_2_noP0}
    Element Should Not Contain  sousform-dossier_lies_geographiquement  ${libelle_di_3_noP0}
    Element Should Not Contain  sousform-dossier_lies_geographiquement  ${libelle_di_4_noP0}

    # Vérification de la prise en compte de la ref cadastrale sur 8 caractères
    @{ref_cad} =  Create List  000  A  0001
    ${ref_cadastrale} =  Create Dictionary
    ...  terrain_references_cadastrales=${ref_cad}

    Modifier le dossier d'instruction  ${libelle_di_2}  ${ref_cadastrale}

    Depuis l'onglet Dossiers Liés du dossier d'instruction  ${libelle_di_1}
    Element Should Contain  sousform-dossier_lies_geographiquement  ${libelle_di_2_noP0}
    Element Should Not Contain  sousform-dossier_lies_geographiquement  ${libelle_di_3_noP0}
    Element Should Not Contain  sousform-dossier_lies_geographiquement  ${libelle_di_4_noP0}
    Element Should Not Contain  sousform-dossier_lies_geographiquement  ${libelle_di_5_noP0}

    Depuis l'onglet Dossiers Liés du dossier d'instruction  ${libelle_di_2}
    Element Should Contain  sousform-dossier_lies_geographiquement  ${libelle_di_1_noP0}
    Element Should Not Contain  sousform-dossier_lies_geographiquement  ${libelle_di_3_noP0}
    Element Should Not Contain  sousform-dossier_lies_geographiquement  ${libelle_di_4_noP0}
    Element Should Not Contain  sousform-dossier_lies_geographiquement  ${libelle_di_5_noP0}

    Depuis l'onglet Dossiers Liés du dossier d'instruction  ${libelle_di_3}
    Element Should Not Contain  sousform-dossier_lies_geographiquement  ${libelle_di_1_noP0}
    Element Should Not Contain  sousform-dossier_lies_geographiquement  ${libelle_di_2_noP0}
    Element Should Not Contain  sousform-dossier_lies_geographiquement  ${libelle_di_4_noP0}
    Element Should Not Contain  sousform-dossier_lies_geographiquement  ${libelle_di_5_noP0}

    Depuis l'onglet Dossiers Liés du dossier d'instruction  ${libelle_di_4}
    Element Should Not Contain  sousform-dossier_lies_geographiquement  ${libelle_di_1_noP0}
    Element Should Not Contain  sousform-dossier_lies_geographiquement  ${libelle_di_2_noP0}
    Element Should Not Contain  sousform-dossier_lies_geographiquement  ${libelle_di_3_noP0}
    Element Should Not Contain  sousform-dossier_lies_geographiquement  ${libelle_di_5_noP0}

    Depuis l'onglet Dossiers Liés du dossier d'instruction  ${libelle_di_5}
    Element Should Not Contain  sousform-dossier_lies_geographiquement  ${libelle_di_1_noP0}
    Element Should Not Contain  sousform-dossier_lies_geographiquement  ${libelle_di_2_noP0}
    Element Should Not Contain  sousform-dossier_lies_geographiquement  ${libelle_di_3_noP0}
    Element Should Not Contain  sousform-dossier_lies_geographiquement  ${libelle_di_4_noP0}

    &{param_values} =  Create Dictionary
    ...  libelle=option_dossier_commune
    ...  valeur=false
    ...  om_collectivite=agglo
    Ajouter ou modifier le paramètre depuis le menu  ${param_values}

    # On remet le 0
    @{ref_cad} =  Create List  000  0A  0001
    ${ref_cadastrale} =  Create Dictionary
    ...  terrain_references_cadastrales=${ref_cad}

    Modifier le dossier d'instruction  ${libelle_di_2}  ${ref_cadastrale}

    Depuis l'onglet Dossiers Liés du dossier d'instruction  ${libelle_di_1}
    Element Should Contain  sousform-dossier_lies_geographiquement  ${libelle_di_2_noP0}
    Element Should Contain  sousform-dossier_lies_geographiquement  ${libelle_di_3_noP0}
    Element Should Not Contain  sousform-dossier_lies_geographiquement  ${libelle_di_4_noP0}
    Element Should Not Contain  sousform-dossier_lies_geographiquement  ${libelle_di_5_noP0}

    Depuis l'onglet Dossiers Liés du dossier d'instruction  ${libelle_di_2}
    Element Should Contain  sousform-dossier_lies_geographiquement  ${libelle_di_1_noP0}
    Element Should Contain  sousform-dossier_lies_geographiquement  ${libelle_di_3_noP0}
    Element Should Not Contain  sousform-dossier_lies_geographiquement  ${libelle_di_4_noP0}
    Element Should Not Contain  sousform-dossier_lies_geographiquement  ${libelle_di_5_noP0}

    Depuis l'onglet Dossiers Liés du dossier d'instruction  ${libelle_di_3}
    Element Should Contain  sousform-dossier_lies_geographiquement  ${libelle_di_1_noP0}
    Element Should Contain  sousform-dossier_lies_geographiquement  ${libelle_di_2_noP0}
    Element Should Not Contain  sousform-dossier_lies_geographiquement  ${libelle_di_4_noP0}
    Element Should Not Contain  sousform-dossier_lies_geographiquement  ${libelle_di_5_noP0}

    Depuis l'onglet Dossiers Liés du dossier d'instruction  ${libelle_di_4}
    Element Should Not Contain  sousform-dossier_lies_geographiquement  ${libelle_di_1_noP0}
    Element Should Not Contain  sousform-dossier_lies_geographiquement  ${libelle_di_2_noP0}
    Element Should Not Contain  sousform-dossier_lies_geographiquement  ${libelle_di_3_noP0}
    Element Should Contain  sousform-dossier_lies_geographiquement  ${libelle_di_5_noP0}

    Depuis l'onglet Dossiers Liés du dossier d'instruction  ${libelle_di_5}
    Element Should Not Contain  sousform-dossier_lies_geographiquement  ${libelle_di_1_noP0}
    Element Should Not Contain  sousform-dossier_lies_geographiquement  ${libelle_di_2_noP0}
    Element Should Not Contain  sousform-dossier_lies_geographiquement  ${libelle_di_3_noP0}
    Element Should Contain  sousform-dossier_lies_geographiquement  ${libelle_di_4_noP0}

    # Vérification de la prise en compte de la ref cadastrale sur 8 caractères
    @{ref_cad} =  Create List  000  A  0001
    ${ref_cadastrale} =  Create Dictionary
    ...  terrain_references_cadastrales=${ref_cad}

    Modifier le dossier d'instruction  ${libelle_di_2}  ${ref_cadastrale}

    Depuis l'onglet Dossiers Liés du dossier d'instruction  ${libelle_di_1}
    Element Should Contain  sousform-dossier_lies_geographiquement  ${libelle_di_2_noP0}
    Element Should Contain  sousform-dossier_lies_geographiquement  ${libelle_di_3_noP0}
    Element Should Not Contain  sousform-dossier_lies_geographiquement  ${libelle_di_4_noP0}
    Element Should Not Contain  sousform-dossier_lies_geographiquement  ${libelle_di_5_noP0}

    Depuis l'onglet Dossiers Liés du dossier d'instruction  ${libelle_di_2}
    Element Should Contain  sousform-dossier_lies_geographiquement  ${libelle_di_1_noP0}
    Element Should Contain  sousform-dossier_lies_geographiquement  ${libelle_di_3_noP0}
    Element Should Not Contain  sousform-dossier_lies_geographiquement  ${libelle_di_4_noP0}
    Element Should Not Contain  sousform-dossier_lies_geographiquement  ${libelle_di_5_noP0}

    Depuis l'onglet Dossiers Liés du dossier d'instruction  ${libelle_di_3}
    Element Should Contain  sousform-dossier_lies_geographiquement  ${libelle_di_1_noP0}
    Element Should Contain  sousform-dossier_lies_geographiquement  ${libelle_di_2_noP0}
    Element Should Not Contain  sousform-dossier_lies_geographiquement  ${libelle_di_4_noP0}
    Element Should Not Contain  sousform-dossier_lies_geographiquement  ${libelle_di_5_noP0}

    Depuis l'onglet Dossiers Liés du dossier d'instruction  ${libelle_di_4}
    Element Should Not Contain  sousform-dossier_lies_geographiquement  ${libelle_di_1_noP0}
    Element Should Not Contain  sousform-dossier_lies_geographiquement  ${libelle_di_2_noP0}
    Element Should Not Contain  sousform-dossier_lies_geographiquement  ${libelle_di_3_noP0}
    Element Should Contain  sousform-dossier_lies_geographiquement  ${libelle_di_5_noP0}

    Depuis l'onglet Dossiers Liés du dossier d'instruction  ${libelle_di_5}
    Element Should Not Contain  sousform-dossier_lies_geographiquement  ${libelle_di_1_noP0}
    Element Should Not Contain  sousform-dossier_lies_geographiquement  ${libelle_di_2_noP0}
    Element Should Not Contain  sousform-dossier_lies_geographiquement  ${libelle_di_3_noP0}
    Element Should Contain  sousform-dossier_lies_geographiquement  ${libelle_di_4_noP0}


Suppression des paramètres
    &{param_args} =  Create Dictionary
    ...  selection_col=libellé
    ...  search_value=option_dossier_saisie_numero
    ...  click_value=agglo
    Supprimer le paramètre (surcharge)  ${param_args}

    &{param_args} =  Create Dictionary
    ...  selection_col=libellé
    ...  search_value=option_dossier_commune
    ...  click_value=agglo
    Supprimer le paramètre (surcharge)  ${param_args}