*** Settings ***
Documentation  Teste les demandes de nouveaux dossiers et plus spécifiquement,
...  la saisie automatique des champs d'adresses.  

# On inclut les mots-clefs
Resource  resources/resources.robot
# On ouvre/ferme le navigateur au début/à la fin du Test Suite.
Suite Setup  For Suite Setup
Suite Teardown  For Suite Teardown


*** Test Cases ***
TNR de l'affichage des infos des demandeurs dans le formulaire du di
    [Documentation]  Vérifie les informations affichés dans le fieldset demandeur en
    ...  consultation du di.

    Depuis la page d'accueil  instr  instr
    # Affichage de toutes les infos pour un particulier
    &{args_petitionnaire_principal} =  Create Dictionary
    ...  particulier_nom=D'Aubigné
    ...  particulier_prenom=Charline
    ...  particulier_civilite=Madame
    ...  om_collectivite=MARSEILLE
    ...  particulier_date_naissance=20/01/1976
    ...  particulier_commune_naissance=MULHOUSE
    ...  particulier_departement_naissance=HAUT-RHIN
    ...  particulier_pays_naissance=FRANCE
    ...  numero=89
    ...  voie=rue des Coudriers
    ...  complement=cplmt
    ...  lieu_dit=Vauvert
    ...  localite=MULHOUSE
    ...  code_postal=68100
    ...  bp=1
    ...  cedex=2
    ...  pays=FRANCE
    ...  division_territoriale=division
    ...  telephone_fixe=0447129800
    ...  telephone_mobile=0336018799
    ...  indicatif=+33
    ...  fax=fax
    ...  courriel=cdaubigne@test.test
    ...  notification=t

    # Affichage de toutes les infos pour une personne morale
    &{args_demandeur_autre_1}=  Create Dictionary
    ...  qualite=personne morale
    ...  personne_morale_denomination=denomination
    ...  personne_morale_raison_sociale=raisonSociale
    ...  personne_morale_siret=11111111111111
    ...  personne_morale_categorie_juridique=cat jur
    ...  personne_morale_civilite=Monsieur
    ...  personne_morale_nom=Bisson
    ...  personne_morale_prenom=Sacripant
    ...  om_collectivite=MARSEILLE
    ...  numero=14
    ...  voie=rue La Boétie
    ...  complement=cplmt 2
    ...  lieu_dit=Lieu_dit 2
    ...  localite=PARIS
    ...  code_postal=75016
    ...  bp=3
    ...  cedex=4
    ...  pays=FRANCE
    ...  division_territoriale=division 2
    ...  telephone_fixe=01.64.94.65.52
    ...  telephone_mobile=04.60.90.60.50
    ...  indicatif=+34
    ...  fax=fax 2
    ...  courriel=sbisson@test.test
    ...  notification=f

    # Affichage sans le lieu de naissance pour un particulier
    &{args_demandeur_autre_2} =  Create Dictionary
    ...  particulier_nom=Collin
    ...  particulier_prenom=Orson
    ...  particulier_civilite=Monsieur
    ...  om_collectivite=MARSEILLE
    ...  particulier_date_naissance=10/11/1970
    ...  numero=89
    ...  voie=cours Jean Jaures
    ...  complement=cplmt 3
    ...  lieu_dit=Lieu_dit 3
    ...  localite=BORDEAUX
    ...  code_postal=33800
    ...  bp=5
    ...  cedex=6
    ...  pays=FRANCE
    ...  division_territoriale=div 3
    ...  telephone_fixe=06.00.31.40.40
    ...  telephone_mobile=05.99.20.39.39
    ...  indicatif=+35
    ...  fax=fax 3
    ...  courriel=ocollin@test.test

    # Affichage sans la date de naissance pour un particulier
    # Le lieu_dit n'est également pas renseigné pour s'assurer qu'il n'y a pas de ligne vide
    # lorsque les infos d'une ligne ne sont pas affichées
    &{args_demandeur_autre_3} =  Create Dictionary
    ...  particulier_nom=Brisebois
    ...  particulier_prenom=Joséphine
    ...  particulier_civilite=Monsieur Madame
    ...  om_collectivite=MARSEILLE
    ...  particulier_commune_naissance=VESOUL
    ...  particulier_departement_naissance=HAUTE-SAÔNE
    ...  particulier_pays_naissance=FRANCE
    ...  numero=46
    ...  voie=Rue Frédéric Chopin
    ...  complement=cplmt 4
    ...  localite=VESOUL
    ...  code_postal=70000
    ...  bp=7
    ...  cedex=8
    ...  telephone_fixe=03.26.74.27.87
    ...  telephone_mobile=06.26.74.27.87
    ...  indicatif=+36
    ...  courriel=jbrisebois@test.test

    &{args_autre_demandeurs} =  Create Dictionary
    ...  petitionnaire=${args_demandeur_autre_1}
    ...  delegataire=${args_demandeur_autre_2}
    ...  proprietaire=${args_demandeur_autre_3}
    &{args_di} =  Create Dictionary
    ...  dossier_autorisation_type_detaille=Permis de construire pour une maison individuelle et / ou ses annexes
    ...  demande_type=Dépôt Initial
    ...  om_collectivite=MARSEILLE
    ${di} =  Ajouter la demande par WS
    ...  ${args_di}
    ...  ${args_petitionnaire_principal}
    ...  ${args_autre_demandeurs}

    # Récupération du texte à valider pour chaque demandeur :
    # Seules les informations du pétitionnaire principal sont affichées
    ${content_info_petitionnaire_princ} =  Set Variable  Demandeur principal\nMadame D'Aubigné Charline\n89 rue des Coudriers cplmt\nVauvert\n68100 MULHOUSE 1 2\ndivision FRANCE\nLe demandeur accepte d’être notifié à l'adresse électronique communiquée\ncdaubigne@test.test\n0447129800 - 0336018799\nÉDITER\nSUPPRIMER
    ${content_info_petitionnaire} =  Set Variable  Demandeur\nraisonSociale denomination\n11111111111111 cat jur\nMonsieur Bisson Sacripant\nLe demandeur refuse d’être notifié à l'adresse électronique communiquée\nÉDITER\nSUPPRIMER
    ${content_info_delegataire} =  Set Variable  Autre correspondant\nMonsieur Collin Orson\nLe demandeur refuse d’être notifié à l'adresse électronique communiquée\nÉDITER\nSUPPRIMER
    ${content_info_proprietaire} =  Set Variable  Propriétaire\nMonsieur Madame Brisebois Joséphine\nLe demandeur refuse d’être notifié à l'adresse électronique communiquée\nÉDITER\nSUPPRIMER

    # Vérification des infos affichées dans le fieldset demandeur
    Depuis le contexte du dossier d'instruction  ${di}
    Click On Portlet Action  dossier_instruction  modifier

    Open Fieldset  dossier_instruction  demandeur
    Element Text Should Be
    ...  css=#petitionnaire_principal_delegataire
    ...  ${content_info_petitionnaire_princ}
    Element Text Should Be
    ...  css=#listePetitionnaires .petitionnaire
    ...  ${content_info_petitionnaire}
    Element Text Should Be
    ...  css=#autres-demandeurs .delegataire
    ...  ${content_info_delegataire}
    Element Text Should Be
    ...  css=#autres-demandeurs .proprietaire
    ...  ${content_info_proprietaire}

    # Vérification que le pétitionnaire principal peut être supprimé
    Element Should Be Visible  css=#petitionnaire_principal_delegataire .demande__demandeur--actions button.button-edit
    Element Should Be Visible  css=#petitionnaire_principal_delegataire .demande__demandeur--actions button.button-remove