*** Settings ***
Documentation    Menu Administration
# On inclut les mots-clefs
Resource    resources/resources.robot
# On ouvre et on ferme le navigateur respectivement au début et à la fin
# du Test Suite.
Suite Setup    For Suite Setup
Suite Teardown    For Suite Teardown

*** Test Cases ***
NOM DE MON TEST Cases
    [Documentation]  'Paramétrage Dossier > Demandes > Type'
    ...  Test sur la rédaction de la documentation
    ...  test sur la rédaction de la documentation

    # On accède à la page concernée en saisissant l'identifiant et le mot de passe que l'on passe en paramètres
    # au keyword "depuis la page d'accueil"
    Depuis la page d'accueil  admin  admin

    # Ajout d'un nouveau type de demande
    # On crée un dictionnaire avec le mot clé "Create Dictionnary" pour stocké des valeurs indéxés en utilisant & au lieu de $ et {} pour entourer le nom de
    # de la variable
    # Trois petit point suivit de deux espaces est la syntaxe à avoir
    &{args_demande_type} =  Create Dictionary
    ...    code=TESTDOCAFF_AUTO
    ...    libelle=TESTDOCAFF_AUTO
    ...    groupe=Autorisation ADS
    ...    dossier_autorisation_type_detaille=CU (Certificat d'urbanisme)
    ...    demande_nature=Nouveau dossier
    ...    dossier_instruction_type=CU - Initial
    ...    evenement=Notification de delai

    # On envoi la variable crée ci dessus en paramètre au keyword "ajouter un nouveau type de demande depuis le menu", 
    # et on utilise le ${nomDeLaVariable} pour appeler la variable crée
    Ajouter un nouveau type de demande depuis le menu  ${args_demande_type}

    # Activation du paramètre permettant d'accéder au champ commune 
    &{param_division} =  Create Dictionary
    ...  libelle=option_dossier_commune
    ...  valeur=true
    ...  om_collectivite=agglo
    Ajouter ou modifier le paramètre depuis le menu  ${param_division}

    
    # Ajout d'une commune
    &{dico_commune} =  Create Dictionary
    ...  com=13055
    ...  reg=13
    ...  dep=055
    ...  om_validite_debut=${date_ddmmyyyy}
    ...  libelle=Marseille
    Ajouter commune avec dates validité  ${dico_commune}


    # L'affectation doit fonctionner
    &{aff_auto_CU} =  Create Dictionary
    ...  om_collectivite=MARSEILLE
    ...  dossier_autorisation_type_detaille=Certificat d'urbanisme
    ...  instructeur=Louis Laurent (H)
    ...  affectation_manuelle=toto
    Ajouter l'affectation depuis le menu  ${aff_auto_CU}

    # On se met dans un contexte particulier grâce au keuword ci dessous
    Depuis le contexte de nouvelle demande via le menu
    # On sélectionne le type de dossier d'autorisation détaillé
    # Le keyword 'select from list by labet' permet de choisir une valeur dans un select, ce select sera recherché via le
    # css et l'identifiant ou la class qui sera nommé, suivi de deux espaces, et ensuite de la valeur que l'on voudra sélectionner 
    Select From List By Label  css=#om_collectivite  MARSEILLE
    Select From List By Label  css=#dossier_autorisation_type_detaille  Certificat d'urbanisme
    Select From List By Label  css=#demande_type  Dépôt Initial
    # Ce keyword permet de vérifié si un input est visible, içi en l'occurence avec pour identifiant "date_demande"
    Element Should Not Be Visible  css=#date_demande

    # Ici nous créons une liste, et nous utilisons @ et non plus &, avec le mot clé "Create List"
    @{list_select_AA} =    Create List
    ...    choisir affectation
    ...    affectation automatique
    ...    toto
    # Nous temporisons le temps de voir un input visible, et dès que c'est le cas, nous passons à la suite
    Wait Until Keyword Succeeds  ${TIMEOUT}  ${RETRY_INTERVAL}  Element Should Be Visible  css=select#affectation_automatique

    # Ici nous récuperons une liste d'un select et nous la stockons dans la variable ${aff_auto_list}
    ${aff_auto_list} =  Get List Items  css=select#affectation_automatique
    # Nous vérifions ensuite si les deux liste on égal ou non
    Lists Should Be Equal  ${aff_auto_list}  ${list_select_AA}

    # Nous selectionnons de nouveau une valeur dans un select, ici toto
    Select From List By Label  css=#affectation_automatique  toto
    # Nous temporisons de nouveau pour laisser le temps à l'input date_demande de s'afficher
    Wait Until Keyword Succeeds  ${TIMEOUT}  ${RETRY_INTERVAL}  Element Should Be Visible  css=#date_demande