*** Settings ***
Documentation     Notification des demandeurs

# On inclut les mots-clefs
Resource    resources/resources.robot
# On ouvre et on ferme le navigateur respectivement au début et à la fin
# du Test Suite.
Suite Setup    For Suite Setup
Suite Teardown    For Suite Teardown


*** Test Cases ***
Constitution du jeu de données
    [Documentation]  constitution d'un jeu de données servant à tester le bon fonctionnement
    ...  de la notification des demandeurs

    Depuis la page d'accueil  admin  admin
    # Isolation du contexte
    &{librecom_values} =  Create Dictionary
    ...  om_collectivite_libelle=LIBRECOM_NOTIFDEM
    ...  departement=020
    ...  commune=001
    ...  insee=20001
    ...  direction_code=Notif
    ...  direction_libelle=Direction de LIBRECOM_NOTIFDEM
    ...  direction_chef=Chef
    ...  division_code=Notif
    ...  division_libelle=Division Notif
    ...  division_chef=Chef
    ...  guichet_om_utilisateur_nom=Durandana Paquet
    ...  guichet_om_utilisateur_email=dpaquet@openads-test.fr
    ...  guichet_om_utilisateur_login=dpaquet
    ...  guichet_om_utilisateur_pwd=dpaquet
    ...  instr_om_utilisateur_nom=Mandel Paulet
    ...  instr_om_utilisateur_email=mpaulet@openads-test.fr
    ...  instr_om_utilisateur_login=mpaulet
    ...  instr_om_utilisateur_pwd=mpaulet
    Isolation d'un contexte  ${librecom_values}

    # paramètrage du titre et du message de notificatio
    &{om_param} =  Create Dictionary
    ...  libelle=parametre_courriel_type_titre
    ...  valeur=[openADS] Notification concernant votre dossier
    ...  om_collectivite=LIBRECOM_NOTIFDEM
    Ajouter ou modifier le paramètre depuis le menu  ${om_param}

    &{om_param} =  Create Dictionary
    ...  libelle=parametre_courriel_type_message
    ...  valeur=Bonjour, une nouvelle instruction a été ajouté a votre dossier.
    ...  om_collectivite=LIBRECOM_NOTIFDEM
    Ajouter ou modifier le paramètre depuis le menu  ${om_param}
    

    # lettretype
    &{args_lettretype} =  Create Dictionary
    ...  id=test_NOTIF
    ...  libelle=Test
    ...  sql=Aucune REQUÊTE
    ...  titre=&idx, &destinataire, aujourdhui&aujourdhui, datecourrier&datecourrier, &departement
    ...  corps=<p><br pagebreak="true" /></p>&idx, &destinataire, aujourdhui&aujourdhui, datecourrier&datecourrier, &departement
    ...  actif=true
    ...  collectivite=agglo
    Ajouter la lettre-type depuis le menu  &{args_lettretype}

    # Ajout de 8 événements pour tester tous les cas de notification
    # 4 événements avec des lettretypes
    @{etat_source} =  Create List  delai de notification envoye
    @{type_di} =  Create List  PCI - P - Initial
    &{args_evenement1} =  Create Dictionary
    ...  libelle=TEST_NOTIF_AUTO_LETTRETYPE
    ...  etats_depuis_lequel_l_evenement_est_disponible=${etat_source}
    ...  dossier_instruction_type=${type_di}
    ...  lettretype=test_NOTIF Test
    ...  notification=Notification automatique
    Ajouter l'événement depuis le menu  ${args_evenement1}

    &{args_evenement2} =  Create Dictionary
    ...  libelle=TEST_NOTIF_AUTO_SIGN_LETTRETYPE
    ...  etats_depuis_lequel_l_evenement_est_disponible=${etat_source}
    ...  dossier_instruction_type=${type_di}
    ...  lettretype=test_NOTIF Test
    ...  notification=Notification automatique avec signature requise
    Ajouter l'événement depuis le menu  ${args_evenement2}

    &{args_evenement3} =  Create Dictionary
    ...  libelle=TEST_NOTIF_MAN_LETTRETYPE
    ...  etats_depuis_lequel_l_evenement_est_disponible=${etat_source}
    ...  dossier_instruction_type=${type_di}
    ...  lettretype=test_NOTIF Test
    ...  notification=Notification manuelle
    Ajouter l'événement depuis le menu  ${args_evenement3}

    &{args_evenement4} =  Create Dictionary
    ...  libelle=TEST_NOTIF_MAN_SIGN_LETTRETYPE
    ...  etats_depuis_lequel_l_evenement_est_disponible=${etat_source}
    ...  dossier_instruction_type=${type_di}
    ...  lettretype=test_NOTIF Test
    ...  notification=Notification manuelle avec signature requise
    Ajouter l'événement depuis le menu  ${args_evenement4}

    # 4 événements sans lettretypes
    &{args_evenement5} =  Create Dictionary
    ...  libelle=TEST_NOTIF_AUTO
    ...  etats_depuis_lequel_l_evenement_est_disponible=${etat_source}
    ...  dossier_instruction_type=${type_di}
    ...  notification=Notification automatique
    Ajouter l'événement depuis le menu  ${args_evenement5}

    &{args_evenement6} =  Create Dictionary
    ...  libelle=TEST_NOTIF_MAN
    ...  etats_depuis_lequel_l_evenement_est_disponible=${etat_source}
    ...  dossier_instruction_type=${type_di}
    ...  notification=Notification manuelle
    Ajouter l'événement depuis le menu  ${args_evenement6}


Activation de la notification par mail
    [Documentation]  Active la notification par mail des demandeurs

    Depuis la page d'accueil  admin  admin

    &{om_param} =  Create Dictionary
    ...  libelle=option_notification
    ...  valeur=mail
    ...  om_collectivite=LIBRECOM_NOTIFDEM
    Ajouter ou modifier le paramètre depuis le menu  ${om_param}

    Démarrer maildump

Notification automatique par mail d'une instruction sans lettretype
    [Documentation]  Vérifie le bon fonctionnement de la notification automatique
    ...  par mail des demandeurs

    Depuis la page d'accueil  admin  admin

    # Ajout d'un dossier et d'une instruction de notification auto
    # Seul le petitionnaire principal a un courriel et accepte les notification
    # c'est donc le seul pétitionnaire qui devra être notifié
    &{args_petitionnaire_principal} =  Create Dictionary
    ...  particulier_nom=Cressac
    ...  particulier_prenom=Véronique
    ...  om_collectivite=LIBRECOM_NOTIFDEM
    ...  courriel=vcressac@notif.fr
    ...  notification=t

    &{args_petitionnaire1} =  Create Dictionary
    ...  particulier_nom=Charpie
    ...  particulier_prenom=Aimé
    ...  om_collectivite=LIBRECOM_NOTIFDEM
    ...  courriel=caime@notnotif.fr

    &{args_autres_demandeurs} =  Create Dictionary
    ...  petitionnaire=${args_petitionnaire1}

    &{args_demande} =  Create Dictionary
    ...  dossier_autorisation_type_detaille=Permis de construire pour une maison individuelle et / ou ses annexes
    ...  demande_type=Dépôt Initial
    ...  om_collectivite=LIBRECOM_NOTIFDEM
    ...  depot_electronique=true
    ${di_notif_auto1} =  Ajouter la demande par WS  ${args_demande}  ${args_petitionnaire_principal}  ${args_autres_demandeurs}

    # Ajout de l'instruction de notification automatique sans lettretype
    # La notification doit se faire à l'ajout de l'instruction
    Depuis la page d'accueil  mpaulet  mpaulet
    Ajouter une instruction au DI  ${di_notif_auto1}  TEST_NOTIF_AUTO
    Verifier que le mail a bien été envoyé au destinataire  vcressac@notif.fr
    Page Should Not Contain  caime@notnotif.fr
    Depuis l'instruction du dossier d'instruction  ${di_notif_auto1}  TEST_NOTIF_AUTO
    Element Should Contain  css=div#suivi_notification_jsontotab  vcressac@notif.fr
    Element Should Contain  css=div#suivi_notification_jsontotab  Le mail de notification a été envoyé
    Element Should Not Contain  css=div#suivi_notification_jsontotab  caime@notnotif.fr
    
Notification automatique par mail d'une instruction avec lettretype sans signature requise
    [Documentation]  Vérifie le bon fonctionnement de la notification automatique
    ...  par mail des demandeurs

    Depuis la page d'accueil  admin  admin

    # Ajout d'un dossier et d'une instruction de notification auto
    # Seul le petitionnaire principal a un courriel et accepte les notification
    # c'est donc le seul pétitionnaire qui devra être notifié
    &{args_petitionnaire_principal} =  Create Dictionary
    ...  particulier_nom=Patience
    ...  particulier_prenom=Boncoeur
    ...  om_collectivite=LIBRECOM_NOTIFDEM
    ...  courriel=pboncoeur@notif.fr
    ...  notification=t

    &{args_petitionnaire1} =  Create Dictionary
    ...  particulier_nom=Veronneau
    ...  particulier_prenom=Vail
    ...  om_collectivite=LIBRECOM_NOTIFDEM
    ...  notification=t

    &{args_autres_demandeurs} =  Create Dictionary
    ...  petitionnaire=${args_petitionnaire1}

    &{args_demande} =  Create Dictionary
    ...  dossier_autorisation_type_detaille=Permis de construire pour une maison individuelle et / ou ses annexes
    ...  demande_type=Dépôt Initial
    ...  om_collectivite=LIBRECOM_NOTIFDEM
    ...  depot_electronique=true
    ${di_notif_auto1} =  Ajouter la demande par WS  ${args_demande}  ${args_petitionnaire_principal}  ${args_autres_demandeurs}

    # Ajout de l'instruction de notification automatique avec lettretype sans signature
    # La notification doit se faire à la finalisation de la lettretype
    Depuis la page d'accueil  mpaulet  mpaulet
    Ajouter une instruction au DI et la finaliser  ${di_notif_auto1}  TEST_NOTIF_AUTO_LETTRETYPE
    Verifier que le mail a bien été envoyé au destinataire  pboncoeur@notif.fr
    Page Should Not Contain  vail
    Depuis l'instruction du dossier d'instruction  ${di_notif_auto1}  TEST_NOTIF_AUTO_LETTRETYPE
    Element Should Contain  css=div#suivi_notification_jsontotab  pboncoeur@notif.fr
    Element Should Contain  css=div#suivi_notification_jsontotab  Le mail de notification a été envoyé
    Element Should Not Contain  css=div#suivi_notification_jsontotab  vail

Notification automatique par mail d'une instruction avec lettretype et avec retour signature
    [Documentation]  Vérifie le bon fonctionnement de la notification automatique
    ...  par mail des demandeurs

    Depuis la page d'accueil  admin  admin

    # Ajout d'un dossier et d'une instruction de notification auto
    # Seul le petitionnaire principal a un courriel et accepte les notification
    # c'est donc le seul pétitionnaire qui devra être notifié
    &{args_petitionnaire_principal} =  Create Dictionary
    ...  qualite=personne morale
    ...  personne_morale_denomination=Denomination
    ...  personne_morale_nom=Monjeau
    ...  personne_morale_prenom=Eglantine
    ...  om_collectivite=LIBRECOM_NOTIFDEM
    ...  courriel=meglantine@notif.fr
    ...  notification=t

    &{args_petitionnaire1} =  Create Dictionary
    ...  qualite=personne morale
    ...  personne_morale_raison_sociale=raison sociale
    ...  personne_morale_nom=Bonenfant
    ...  personne_morale_prenom=Anne
    ...  om_collectivite=LIBRECOM_NOTIFDEM
    ...  courriel=abonenfant@notnotif.fr
    ...  notification=t

    &{args_autres_demandeurs} =  Create Dictionary
    ...  petitionnaire=${args_petitionnaire1}

    &{args_demande} =  Create Dictionary
    ...  dossier_autorisation_type_detaille=Permis de construire pour une maison individuelle et / ou ses annexes
    ...  demande_type=Dépôt Initial
    ...  om_collectivite=LIBRECOM_NOTIFDEM
    ...  depot_electronique=true
    ${di_notif_auto1} =  Ajouter la demande par WS  ${args_demande}  ${args_petitionnaire_principal}  ${args_autres_demandeurs}

    # Ajout de l'instruction de notification automatique avec lettretype avec signature
    # La notification doit se faire à l'ajout de la date de retour
    Depuis la page d'accueil  admin  admin
    Ajouter une instruction au DI et la finaliser  ${di_notif_auto1}  TEST_NOTIF_AUTO_SIGN_LETTRETYPE
    Depuis l'instruction du dossier d'instruction  ${di_notif_auto1}  TEST_NOTIF_AUTO_SIGN_LETTRETYPE
    Page Should Not Contain Element  css=fieldset#fieldset-sousform-instruction-suivi
    # Remplissage de la date de retour de signature
    ${date_retour_sign} =  Convert Date  ${DATE_FORMAT_YYYY-MM-DD}  result_format=%d/%m/%Y
    Click On SubForm Portlet Action  instruction  modifier_suivi
    Input Datepicker  date_retour_signature  ${date_retour_sign}
    Click On Submit Button In Subform
    # Vérification des infos
    Verifier que le mail a bien été envoyé au destinataire  meglantine@notif.fr
    Verifier que le mail a bien été envoyé au destinataire  abonenfant@notnotif.fr
    Depuis l'instruction du dossier d'instruction  ${di_notif_auto1}  TEST_NOTIF_AUTO_SIGN_LETTRETYPE
    Element Should Contain  css=div#suivi_notification_jsontotab  meglantine@notif.fr
    Element Should Contain  css=div#suivi_notification_jsontotab  Le mail de notification a été envoyé
    Element Should Contain  css=div#suivi_notification_jsontotab  abonenfant@notnotif.fr

Notification manuelle par mail d'une instruction sans lettretype
    [Documentation]  Vérifie le bon fonctionnement de la notification manuelle
    ...  par mail des demandeurs

    Depuis la page d'accueil  admin  admin

    # Ajout d'un dossier et d'une instruction de notification auto
    # Seul le petitionnaire principal a un courriel et accepte les notification
    # c'est donc le seul pétitionnaire qui devra être notifié
    &{args_petitionnaire_principal} =  Create Dictionary
    ...  particulier_nom=Loiselle
    ...  particulier_prenom=Roland
    ...  om_collectivite=LIBRECOM_NOTIFDEM
    ...  courriel=rloiselle@notif.fr
    ...  notification=t

    &{args_petitionnaire1} =  Create Dictionary
    ...  particulier_nom=Dandonneau
    ...  particulier_prenom=Parfait
    ...  om_collectivite=LIBRECOM_NOTIFDEM
    ...  courriel=dparfait@notnotif.fr

    &{args_autres_demandeurs} =  Create Dictionary
    ...  petitionnaire=${args_petitionnaire1}

    &{args_demande} =  Create Dictionary
    ...  dossier_autorisation_type_detaille=Permis de construire pour une maison individuelle et / ou ses annexes
    ...  demande_type=Dépôt Initial
    ...  om_collectivite=LIBRECOM_NOTIFDEM
    ...  depot_electronique=true
    ${di_notif_auto1} =  Ajouter la demande par WS  ${args_demande}  ${args_petitionnaire_principal}  ${args_autres_demandeurs}

    # Ajout de l'instruction de notification automatique sans lettretype
    Depuis la page d'accueil  mpaulet  mpaulet
    Ajouter une instruction au DI  ${di_notif_auto1}  TEST_NOTIF_MAN
    # L'action ne doit être dans le portlet
    Portlet Action Should Be In SubForm  instruction  overlay_notification_manuelle

    # Utilisation de l'action
    Click On SubForm Portlet Action  instruction  overlay_notification_manuelle  modale
    Wait until element contains  css=div#sousform-instruction_notification_manuelle  petitionnaire Loiselle Roland rloiselle@notif.fr
    Element Should Not Contain  css=div#sousform-instruction_notification_manuelle  dparfait@notnotif.fr
    # Sélection du demandeur et validation
    Select Checkbox  css=div#sousform-instruction_notification_manuelle input[type="checkbox"]
    Click Element  css=div#sousform-instruction_notification_manuelle input[type="submit"]
    Wait Until Page Contains  La notification a été générée.

    # Vérifie que la page s'est bien mis à jour lors de la validation
    Wait until element contains  css=#fieldset-sousform-instruction-suivi  Suivi
    Element Should Contain  css=div#suivi_notification_jsontotab  rloiselle@notif.fr
    Element Should Contain  css=div#suivi_notification_jsontotab  Le mail de notification a été envoyé
    Element Should Not Contain  css=div#suivi_notification_jsontotab  dparfait@notnotif.fr
    # Vérifie que le mail a bien été envoyé
    Verifier que le mail a bien été envoyé au destinataire  rloiselle@notif.fr
    Page Should Not Contain  dparfait@notnotif.fr

Notification manuelle par mail d'une instruction avec lettretype sans signature requise
    [Documentation]  Vérifie le bon fonctionnement de la notification manuelle
    ...  par mail des demandeurs

    Depuis la page d'accueil  admin  admin

    # Ajout d'un dossier et d'une instruction de notification auto
    # Seul le petitionnaire principal a un courriel et accepte les notification
    # c'est donc le seul pétitionnaire qui devra être notifié
    &{args_petitionnaire_principal} =  Create Dictionary
    ...  qualite=personne morale
    ...  personne_morale_denomination=denom1
    ...  personne_morale_nom=Leclerc
    ...  personne_morale_prenom=Maurelle
    ...  om_collectivite=LIBRECOM_NOTIFDEM
    ...  notification=t

    &{args_petitionnaire1} =  Create Dictionary
    ...  qualite=personne morale
    ...  personne_morale_denomination=denom2
    ...  personne_morale_nom=Jalbert
    ...  personne_morale_prenom=Matthieu
    ...  om_collectivite=LIBRECOM_NOTIFDEM
    ...  courriel=mjalbert@notif.fr
    ...  notification=t

    &{args_autres_demandeurs} =  Create Dictionary
    ...  petitionnaire=${args_petitionnaire1}

    &{args_demande} =  Create Dictionary
    ...  dossier_autorisation_type_detaille=Permis de construire pour une maison individuelle et / ou ses annexes
    ...  demande_type=Dépôt Initial
    ...  om_collectivite=LIBRECOM_NOTIFDEM
    ...  depot_electronique=true
    ${di_notif_auto1} =  Ajouter la demande par WS  ${args_demande}  ${args_petitionnaire_principal}  ${args_autres_demandeurs}

    # Ajout de l'instruction de notification manuelle avec lettretype sans signature
    Depuis la page d'accueil  mpaulet  mpaulet
    Ajouter une instruction au DI et la finaliser  ${di_notif_auto1}  TEST_NOTIF_MAN_LETTRETYPE
    # L'action doit être dans le portlet
    Depuis l'instruction du dossier d'instruction  ${di_notif_auto1}  TEST_NOTIF_MAN_LETTRETYPE
    Portlet Action Should Be In SubForm  instruction  overlay_notification_manuelle

    # Utilisation de l'action
    Click On SubForm Portlet Action  instruction  overlay_notification_manuelle  modale
    Wait until element contains  css=div#sousform-instruction_notification_manuelle  petitionnaire Jalbert Matthieu mjalbert@notif.fr
    Element Should Not Contain  css=div#sousform-instruction_notification_manuelle  Leclerc
    # Sélection du demandeur et validation
    Select Checkbox  css=div#sousform-instruction_notification_manuelle input[type="checkbox"]
    Click Element  css=div#sousform-instruction_notification_manuelle input[type="submit"]
    Wait Until Page Contains  La notification a été générée.

    # Vérifie que la page s'est bien mis à jour lors de la validation
    Wait until element contains  css=#fieldset-sousform-instruction-suivi  Suivi
    Element Should Contain  css=div#suivi_notification_jsontotab  mjalbert@notif.fr
    Element Should Contain  css=div#suivi_notification_jsontotab  Le mail de notification a été envoyé
    Element Should Not Contain  css=div#suivi_notification_jsontotab  Leclerc
    # Vérifie que le mail a bien été envoyé
    Verifier que le mail a bien été envoyé au destinataire  mjalbert@notif.fr
    Page Should Not Contain  leclerc

Notification manuelle par mail d'une instruction avec lettretype et signature requise
    [Documentation]  Vérifie le bon fonctionnement de la notification manuelle
    ...  par mail des demandeurs

    Depuis la page d'accueil  admin  admin

    # Ajout d'un dossier et d'une instruction de notification auto
    # Seul le petitionnaire principal a un courriel et accepte les notification
    # c'est donc le seul pétitionnaire qui devra être notifié
    &{args_petitionnaire_principal} =  Create Dictionary
    ...  particulier_nom=Babin
    ...  particulier_prenom=Pauline
    ...  om_collectivite=LIBRECOM_NOTIFDEM
    ...  courriel=pbabin@notif.fr
    ...  notification=t

    &{args_petitionnaire1} =  Create Dictionary
    ...  particulier_nom=Chenard
    ...  particulier_prenom=Lance
    ...  om_collectivite=LIBRECOM_NOTIFDEM
    ...  courriel=lchenard@notif.fr
    ...  notification=t

    &{args_autres_demandeurs} =  Create Dictionary
    ...  petitionnaire=${args_petitionnaire1}

    &{args_demande} =  Create Dictionary
    ...  dossier_autorisation_type_detaille=Permis de construire pour une maison individuelle et / ou ses annexes
    ...  demande_type=Dépôt Initial
    ...  om_collectivite=LIBRECOM_NOTIFDEM
    ...  depot_electronique=true
    ${di_notif_auto1} =  Ajouter la demande par WS  ${args_demande}  ${args_petitionnaire_principal}  ${args_autres_demandeurs}

    # Ajout de l'instruction de notification automatique avec lettretype avec signature
    Depuis la page d'accueil  admin  admin
    Ajouter une instruction au DI et la finaliser  ${di_notif_auto1}  TEST_NOTIF_MAN_SIGN_LETTRETYPE
    # L'action ne doit être dans le portlet
    Depuis l'instruction du dossier d'instruction  ${di_notif_auto1}  TEST_NOTIF_MAN_SIGN_LETTRETYPE
    Portlet Action Should Not Be In SubForm  instruction  overlay_notification_manuelle
    # Ajout d'une date de signature
    # Remplissage de la date de retour de signature
    ${date_retour_sign} =  Convert Date  ${DATE_FORMAT_YYYY-MM-DD}  result_format=%d/%m/%Y
    Click On SubForm Portlet Action  instruction  modifier_suivi
    Input Datepicker  date_retour_signature  ${date_retour_sign}
    Click On Submit Button In Subform
    Portlet Action Should Be In SubForm  instruction  overlay_notification_manuelle

    # Utilisation de l'action
    Click On SubForm Portlet Action  instruction  overlay_notification_manuelle  modale
    Wait until element contains  css=div#sousform-instruction_notification_manuelle  petitionnaire Chenard Lance lchenard@notif.fr
    Element Should Contain  css=div#sousform-instruction_notification_manuelle  petitionnaire Babin Pauline pbabin@notif.fr
    # Sélection du demandeur et validation
    Select Checkbox  css=div#sousform-instruction_notification_manuelle div.field-type-checkbox:nth-child(1) input[type="checkbox"]
    Select Checkbox  css=div#sousform-instruction_notification_manuelle div.field-type-checkbox:nth-child(2) input[type="checkbox"]
    Click Element  css=div#sousform-instruction_notification_manuelle input[type="submit"]
    Wait Until Page Contains  La notification a été générée.

    # Vérifie que la page s'est bien mis à jour lors de la validation
    Wait until element contains  css=#fieldset-sousform-instruction-suivi  Suivi
    Element Should Contain  css=div#suivi_notification_jsontotab  lchenard@notif.fr
    Element Should Contain  css=div#suivi_notification_jsontotab  pbabin@notif.fr
    Element Should Contain  css=div#suivi_notification_jsontotab  Le mail de notification a été envoyé
    # Vérifie que le mail a bien été envoyé
    Verifier que le mail a bien été envoyé au destinataire  lchenard@notif.fr
    Verifier que le mail a bien été envoyé au destinataire  pbabin@notif.fr

Desactivation de la notification par mail
    [Documentation]  Desactive la notification par mail des demandeurs

    Depuis la page d'accueil  admin  admin

    &{param_args} =  Create Dictionary
    ...  selection_col=libellé
    ...  search_value=option_notification
    ...  click_value=LIBRECOM_NOTIFDEM
    Supprimer le paramètre (surcharge)  ${param_args}
    
    Arrêter maildump

Notification automatique via le portail citoyen d'une instruction sans lettretype
    [Documentation]  Vérifie le bon fonctionnement de la notification automatique
    ...  via le portail citoyen des demandeurs

    Depuis la page d'accueil  admin  admin

    # Ajout d'un dossier et d'une instruction de notification auto
    # Seul le petitionnaire principal a un courriel et accepte les notification
    # c'est donc le seul pétitionnaire qui devra être notifié
    &{args_petitionnaire_principal} =  Create Dictionary
    ...  particulier_nom=L'Heureux
    ...  particulier_prenom=Madeleine
    ...  om_collectivite=LIBRECOM_NOTIFDEM
    ...  courriel=mlheureux@notif.fr
    ...  notification=t

    &{args_petitionnaire1} =  Create Dictionary
    ...  particulier_nom=Charette
    ...  particulier_prenom=Suzette
    ...  om_collectivite=LIBRECOM_NOTIFDEM
    ...  courriel=scharette@notif.fr
    ...  notification=t

    &{args_autres_demandeurs} =  Create Dictionary
    ...  petitionnaire=${args_petitionnaire1}

    &{args_demande} =  Create Dictionary
    ...  dossier_autorisation_type_detaille=Permis de construire pour une maison individuelle et / ou ses annexes
    ...  demande_type=Dépôt Initial
    ...  om_collectivite=LIBRECOM_NOTIFDEM
    ...  depot_electronique=true
    ${di_notif_auto1} =  Ajouter la demande par WS  ${args_demande}  ${args_petitionnaire_principal}  ${args_autres_demandeurs}

    # Ajout de l'instruction de notification automatique sans lettretype
    # La notification doit se faire à l'ajout de l'instruction
    Depuis la page d'accueil  mpaulet  mpaulet
    Ajouter une instruction au DI  ${di_notif_auto1}  TEST_NOTIF_AUTO
    Element Should Contain  css=div#suivi_notification_jsontotab  mlheureux@notif.fr
    Element Should Contain  css=div#suivi_notification_jsontotab  en cours d'envoi
    Element Should Contain  css=div#suivi_notification_jsontotab  scharette@notif.fr
    
Notification automatique via le portail citoyen d'une instruction avec lettretype sans signature requise
    [Documentation]  Vérifie le bon fonctionnement de la notification automatique
    ...  via le portail citoyen des demandeurs

    Depuis la page d'accueil  admin  admin

    # Ajout d'un dossier et d'une instruction de notification auto
    # Seul le petitionnaire principal a un courriel et accepte les notification
    # c'est donc le seul pétitionnaire qui devra être notifié
    &{args_petitionnaire_principal} =  Create Dictionary
    ...  particulier_nom=Desjardins
    ...  particulier_prenom=Sargent
    ...  om_collectivite=LIBRECOM_NOTIFDEM
    ...  courriel=sdesjardins@notif.fr
    ...  notification=t

    &{args_petitionnaire1} =  Create Dictionary
    ...  particulier_nom=Boisclair
    ...  particulier_prenom=Rabican
    ...  om_collectivite=LIBRECOM_NOTIFDEM
    ...  courriel=rboisclair@notif.fr
    ...  notification=t

    &{args_autres_demandeurs} =  Create Dictionary
    ...  petitionnaire=${args_petitionnaire1}

    &{args_demande} =  Create Dictionary
    ...  dossier_autorisation_type_detaille=Permis de construire pour une maison individuelle et / ou ses annexes
    ...  demande_type=Dépôt Initial
    ...  om_collectivite=LIBRECOM_NOTIFDEM
    ...  depot_electronique=true
    ${di_notif_auto1} =  Ajouter la demande par WS  ${args_demande}  ${args_petitionnaire_principal}  ${args_autres_demandeurs}

    # Ajout de l'instruction de notification automatique avec lettretype sans signature
    # La notification doit se faire à la finalisation de la lettretype
    Depuis la page d'accueil  mpaulet  mpaulet
    Ajouter une instruction au DI et la finaliser  ${di_notif_auto1}  TEST_NOTIF_AUTO_LETTRETYPE
    Element Should Contain  css=div#suivi_notification_jsontotab  sdesjardins@notif.fr
    Element Should Contain  css=div#suivi_notification_jsontotab  en cours d'envoi
    Element Should Contain  css=div#suivi_notification_jsontotab  rboisclair@notif.fr

Notification automatique via le portail citoyen d'une instruction avec lettretype et avec retour signature
    [Documentation]  Vérifie le bon fonctionnement de la notification automatique
    ...  via le portail citoyen des demandeurs

    Depuis la page d'accueil  admin  admin

    # Ajout d'un dossier et d'une instruction de notification auto
    # Seul le petitionnaire principal a un courriel et accepte les notification
    # c'est donc le seul pétitionnaire qui devra être notifié
    &{args_petitionnaire_principal} =  Create Dictionary
    ...  qualite=personne morale
    ...  personne_morale_denomination=Denomination
    ...  personne_morale_nom=Tabor
    ...  personne_morale_prenom=Phaneuf
    ...  om_collectivite=LIBRECOM_NOTIFDEM
    ...  courriel=tphaneuf@notif.fr
    ...  notification=t

    &{args_petitionnaire1} =  Create Dictionary
    ...  qualite=personne morale
    ...  personne_morale_raison_sociale=raison sociale
    ...  personne_morale_nom=Labrosse
    ...  personne_morale_prenom=Patrick
    ...  om_collectivite=LIBRECOM_NOTIFDEM
    ...  courriel=plabosse@notif.fr
    ...  notification=t

    &{args_autres_demandeurs} =  Create Dictionary
    ...  petitionnaire=${args_petitionnaire1}

    &{args_demande} =  Create Dictionary
    ...  dossier_autorisation_type_detaille=Permis de construire pour une maison individuelle et / ou ses annexes
    ...  demande_type=Dépôt Initial
    ...  om_collectivite=LIBRECOM_NOTIFDEM
    ...  depot_electronique=true
    ${di_notif_auto1} =  Ajouter la demande par WS  ${args_demande}  ${args_petitionnaire_principal}  ${args_autres_demandeurs}

    # Ajout de l'instruction de notification automatique avec lettretype avec signature
    # La notification doit se faire à l'ajout de la date de retour
    Depuis la page d'accueil  admin  admin
    Ajouter une instruction au DI et la finaliser  ${di_notif_auto1}  TEST_NOTIF_AUTO_SIGN_LETTRETYPE
    Depuis l'instruction du dossier d'instruction  ${di_notif_auto1}  TEST_NOTIF_AUTO_SIGN_LETTRETYPE
    Page Should Not Contain Element  css=fieldset#fieldset-sousform-instruction-suivi
    # Remplissage de la date de retour de signature
    ${date_retour_sign} =  Convert Date  ${DATE_FORMAT_YYYY-MM-DD}  result_format=%d/%m/%Y
    Click On SubForm Portlet Action  instruction  modifier_suivi
    Input Datepicker  date_retour_signature  ${date_retour_sign}
    Click On Submit Button In Subform
    # Vérification des infos
    Element Should Contain  css=div#suivi_notification_jsontotab  tphaneuf@notif.fr
    Element Should Contain  css=div#suivi_notification_jsontotab  en cours d'envoi
    Element Should Contain  css=div#suivi_notification_jsontotab  plabosse@notif.fr

Notification manuelle via le portail citoyen d'une instruction sans lettretype
    [Documentation]  Vérifie le bon fonctionnement de la notification manuelle
    ...  via le portail citoyen des demandeurs

    Depuis la page d'accueil  admin  admin

    # Ajout d'un dossier et d'une instruction de notification auto
    # Seul le petitionnaire principal a un courriel et accepte les notification
    # c'est donc le seul pétitionnaire qui devra être notifié
    &{args_petitionnaire_principal} =  Create Dictionary
    ...  particulier_nom=Chandonnet
    ...  particulier_prenom=Honoré
    ...  om_collectivite=LIBRECOM_NOTIFDEM
    ...  courriel=hchandonnet@notif.fr
    ...  notification=t

    &{args_petitionnaire1} =  Create Dictionary
    ...  particulier_nom=Dufresne
    ...  particulier_prenom=Villette
    ...  om_collectivite=LIBRECOM_NOTIFDEM
    ...  courriel=vdufresne@notnotif.fr
    ...  notification=t

    &{args_autres_demandeurs} =  Create Dictionary
    ...  petitionnaire=${args_petitionnaire1}

    &{args_demande} =  Create Dictionary
    ...  dossier_autorisation_type_detaille=Permis de construire pour une maison individuelle et / ou ses annexes
    ...  demande_type=Dépôt Initial
    ...  om_collectivite=LIBRECOM_NOTIFDEM
    ...  depot_electronique=true
    ${di_notif_auto1} =  Ajouter la demande par WS  ${args_demande}  ${args_petitionnaire_principal}  ${args_autres_demandeurs}

    # Ajout de l'instruction de notification automatique sans lettretype
    Depuis la page d'accueil  mpaulet  mpaulet
    Ajouter une instruction au DI  ${di_notif_auto1}  TEST_NOTIF_MAN
    # L'action ne doit être dans le portlet
    Portlet Action Should Be In SubForm  instruction  notification_manuelle_portal

    # Utilisation de l'action
    Click On SubForm Portlet Action  instruction  notification_manuelle_portal  modale
    Cliquer sur le bouton de la fenêtre modale  Confirmer
    Wait Until Page Contains  La notification a été générée.

    # Vérifie que la page s'est bien mis à jour lors de la validation
    Element Should Contain  css=div#suivi_notification_jsontotab  hchandonnet@notif.fr
    Element Should Contain  css=div#suivi_notification_jsontotab  en cours d'envoi
    Element Should Not Contain  css=div#suivi_notification_jsontotab  vdufresne@notnotif.fr

Notification manuelle via le portail citoyen d'une instruction avec lettretype sans signature requise
    [Documentation]  Vérifie le bon fonctionnement de la notification manuelle
    ...  via le portail citoyen des demandeurs

    Depuis la page d'accueil  admin  admin

    # Ajout d'un dossier et d'une instruction de notification auto
    # Seul le petitionnaire principal a un courriel et accepte les notification
    # c'est donc le seul pétitionnaire qui devra être notifié
    &{args_petitionnaire_principal} =  Create Dictionary
    ...  qualite=personne morale
    ...  personne_morale_denomination=denom1
    ...  personne_morale_nom=Lapierre
    ...  personne_morale_prenom=Ormazd
    ...  om_collectivite=LIBRECOM_NOTIFDEM
    ...  courriel=olapierre@notif.fr
    ...  notification=t

    &{args_petitionnaire1} =  Create Dictionary
    ...  qualite=personne morale
    ...  personne_morale_denomination=denom2
    ...  personne_morale_nom=Poisson
    ...  personne_morale_prenom=Warrane
    ...  om_collectivite=LIBRECOM_NOTIFDEM
    ...  courriel=pwarrane@notnotif.fr
    ...  notification=t

    &{args_autres_demandeurs} =  Create Dictionary
    ...  petitionnaire=${args_petitionnaire1}

    &{args_demande} =  Create Dictionary
    ...  dossier_autorisation_type_detaille=Permis de construire pour une maison individuelle et / ou ses annexes
    ...  demande_type=Dépôt Initial
    ...  om_collectivite=LIBRECOM_NOTIFDEM
    ...  depot_electronique=true
    ${di_notif_auto1} =  Ajouter la demande par WS  ${args_demande}  ${args_petitionnaire_principal}  ${args_autres_demandeurs}

    # Ajout de l'instruction de notification manuelle avec lettretype sans signature
    Depuis la page d'accueil  mpaulet  mpaulet
    Ajouter une instruction au DI et la finaliser  ${di_notif_auto1}  TEST_NOTIF_MAN_LETTRETYPE
    # L'action doit être dans le portlet
    Depuis l'instruction du dossier d'instruction  ${di_notif_auto1}  TEST_NOTIF_MAN_LETTRETYPE
    Portlet Action Should Be In SubForm  instruction  notification_manuelle_portal

    # Utilisation de l'action
    Click On SubForm Portlet Action  instruction  notification_manuelle_portal  modale
    Cliquer sur le bouton de la fenêtre modale  Confirmer
    Wait Until Page Contains  La notification a été générée.

    # Vérifie que la page s'est bien mis à jour lors de la validation
    Element Should Contain  css=div#suivi_notification_jsontotab  olapierre@notif.fr
    Element Should Contain  css=div#suivi_notification_jsontotab  en cours d'envoi
    Element Should Not Contain  css=div#suivi_notification_jsontotab  pwarrane@notnotif.fr

Notification manuelle via le portail citoyen d'une instruction avec lettretype et signature requise
    [Documentation]  Vérifie le bon fonctionnement de la notification manuelle
    ...  via le portail citoyen des demandeurs

    Depuis la page d'accueil  admin  admin

    # Ajout d'un dossier et d'une instruction de notification auto
    # Seul le petitionnaire principal a un courriel et accepte les notification
    # c'est donc le seul pétitionnaire qui devra être notifié
    &{args_petitionnaire_principal} =  Create Dictionary
    ...  particulier_nom=Doucet
    ...  particulier_prenom=Merle
    ...  om_collectivite=LIBRECOM_NOTIFDEM
    ...  courriel=mdoucet@notif.fr
    ...  notification=t

    &{args_petitionnaire1} =  Create Dictionary
    ...  particulier_nom=Riel
    ...  particulier_prenom=Chappell
    ...  om_collectivite=LIBRECOM_NOTIFDEM
    ...  courriel=criel@notnotif.fr
    ...  notification=t

    &{args_autres_demandeurs} =  Create Dictionary
    ...  petitionnaire=${args_petitionnaire1}

    &{args_demande} =  Create Dictionary
    ...  dossier_autorisation_type_detaille=Permis de construire pour une maison individuelle et / ou ses annexes
    ...  demande_type=Dépôt Initial
    ...  om_collectivite=LIBRECOM_NOTIFDEM
    ...  depot_electronique=true
    ${di_notif_auto1} =  Ajouter la demande par WS  ${args_demande}  ${args_petitionnaire_principal}  ${args_autres_demandeurs}

    # Ajout de l'instruction de notification automatique avec lettretype avec signature
    Depuis la page d'accueil  admin  admin
    Ajouter une instruction au DI et la finaliser  ${di_notif_auto1}  TEST_NOTIF_MAN_SIGN_LETTRETYPE
    # L'action ne doit être dans le portlet
    Depuis l'instruction du dossier d'instruction  ${di_notif_auto1}  TEST_NOTIF_MAN_SIGN_LETTRETYPE
    Portlet Action Should Not Be In SubForm  instruction  notification_manuelle_portal
    # Ajout d'une date de signature
    # Remplissage de la date de retour de signature
    ${date_retour_sign} =  Convert Date  ${DATE_FORMAT_YYYY-MM-DD}  result_format=%d/%m/%Y
    Click On SubForm Portlet Action  instruction  modifier_suivi
    Input Datepicker  date_retour_signature  ${date_retour_sign}
    Click On Submit Button In Subform
    Portlet Action Should Be In SubForm  instruction  notification_manuelle_portal

    # Utilisation de l'action
    Click On SubForm Portlet Action  instruction  notification_manuelle_portal  modale
    Cliquer sur le bouton de la fenêtre modale  Confirmer
    Wait Until Page Contains  La notification a été générée.

    # Vérifie que la page s'est bien mis à jour lors de la validation
    Element Should Contain  css=div#suivi_notification_jsontotab  mdoucet@notif.fr
    Element Should Contain  css=div#suivi_notification_jsontotab  en cours d'envoi
    Element Should Not Contain  css=div#suivi_notification_jsontotab  criel@notnotif.fr