*** Settings ***
Documentation     Notification des demandeurs

# On inclut les mots-clefs
Resource    resources/resources.robot
# On ouvre et on ferme le navigateur respectivement au début et à la fin
# du Test Suite.
Suite Setup    For Suite Setup
Suite Teardown    For Suite Teardown

*** Test Cases ***
Constitution du jeu de données
    [Documentation]  constitution d'un jeu de données servant à tester le bon fonctionnement
    ...  de la notification des demandeurs

    Depuis la page d'accueil  admin  admin
    # Enregistrement de la date pour la saisie des formulaire
    ${date_courante} =  Convert Date  ${DATE_FORMAT_YYYY-MM-DD}  result_format=%d/%m/%Y
    Set Suite Variable  ${date_courante}

    # CONTEXTE
    Set Suite Variable  ${acteur}  notifTiers
    Set Suite Variable  ${collectivite}  LIBRECOM_NOTIFTIERS
    &{librecom_values} =  Create Dictionary
    ...  om_collectivite_libelle=${collectivite}
    ...  departement=22
    ...  commune=002
    ...  insee=22002
    ...  direction_code=Notif
    ...  direction_libelle=Direction de ${collectivite}
    ...  direction_chef=Chef
    ...  division_code=NotifT
    ...  division_libelle=Division NotifT
    ...  division_chef=Chef
    ...  guichet_om_utilisateur_nom=NotificationTiers Guichet
    ...  guichet_om_utilisateur_email=ntguichet@openads-test.fr
    ...  guichet_om_utilisateur_login=ntguichet
    ...  guichet_om_utilisateur_pwd=ntguichet
    ...  instr_om_utilisateur_nom=NotificationTiers Instr
    ...  instr_om_utilisateur_email=ninstr@openads-test.fr
    ...  instr_om_utilisateur_login=ninstr
    ...  instr_om_utilisateur_pwd=ninstr
    ...  acteur=${acteur}
    Isolation d'un contexte  ${librecom_values}

    # PARAMETRAGE
    # Activation de l'option de paramétrage des tiers pour la collectivité LIBRECOM_NOTIFTIERS
    &{params} =  Create Dictionary
    ...  libelle=option_parametrage_notification_auto_tiers
    ...  valeur=true
    ...  om_collectivite=agglo
    Ajouter ou modifier le paramètre depuis le menu  ${params}
    # Activation de l'option option_dossier_commune et de l'option option_mode_service_consulte
    &{om_param} =  Create Dictionary
    ...  libelle=option_dossier_commune
    ...  valeur=true
    ...  om_collectivite=agglo
    Ajouter ou modifier le paramètre depuis le menu  ${om_param}
    Activer le mode service consulté
    # ajoute le paramètre 'acteur' à la collectivité/au service
    &{om_param} =  Create Dictionary
    ...  libelle=platau_acteur_service_consulte
    ...  valeur=${acteur}
    ...  om_collectivite=${collectivite}
    Ajouter ou modifier le paramètre depuis le menu  ${om_param}
    # définir les paramètres de type de demande
    &{platau_type_demande_initial} =  Create Dictionary
    ...  libelle=platau_type_demande_initial_PCI
    ...  valeur=DI
    ...  om_collectivite=agglo
    Ajouter ou modifier le paramètre depuis le menu  ${platau_type_demande_initial}
    # paramètrage du titre et du message de notification
    &{om_param} =  Create Dictionary
    ...  libelle=parametre_courriel_tiers_type_titre
    ...  valeur=[openADS] Notification pour les tiers concernant le dossier (avec un caractère accentué) (avec un caractère accentué) [DOSSIER]
    ...  om_collectivite=${collectivite}
    Ajouter ou modifier le paramètre depuis le menu  ${om_param}

    &{om_param} =  Create Dictionary
    ...  libelle=parametre_courriel_tiers_type_message
    ...  valeur=Bonjour les tiers (avec un caractère accentué), veuillez prendre connaissance du(des) document(s) suivant(s) :<br> [LIEN_TELECHARGEMENT_DOCUMENT]<br>[LIEN_TELECHARGEMENT_ANNEXE]
    ...  om_collectivite=${collectivite}
    Ajouter ou modifier le paramètre depuis le menu  ${om_param}

    &{om_param} =  Create Dictionary
    ...  libelle=parametre_notification_url_acces
    ...  valeur=http://localhost/openads/
    ...  om_collectivite=agglo
    Ajouter ou modifier le paramètre depuis le menu  ${om_param}
   

    # PARAMÉTRAGE NOTIF AUTO
    # On ajoute 2 communes : 1 lié au dossier l'autre non
    Set Suite Variable  ${lib_commune}  NTC
    Set Suite Variable  ${code_commune}  ${librecom_values.commune}
    ${code_dept} =  Set Variable    ${librecom_values.departement}
    &{com_values} =  Create Dictionary
    ...  typecom=COM
    ...  com=${code_commune}
    ...  reg=20
    ...  dep=${code_dept}
    ...  arr=100
    ...  tncc=0
    ...  ncc=NOTIFATC
    ...  nccenr=NOTIFATC
    ...  libelle=${lib_commune}
    ...  can=20
    ...  om_validite_debut=23/11/2020
    Ajouter commune avec dates validité  ${com_values}
    ${lib_commune_2} =  Set Variable  NTC2
    ${code_commune_2} =  Set Variable  22003
    &{com_values} =  Create Dictionary
    ...  typecom=COM
    ...  com=${code_commune_2}
    ...  reg=20
    ...  dep=${code_dept}
    ...  arr=200
    ...  tncc=0
    ...  ncc=NOTIFFTC
    ...  nccenr=NOTIFFTC
    ...  libelle=${lib_commune_2}
    ...  can=20
    ...  om_validite_debut=${date_courante}
    Ajouter commune avec dates validité  ${com_values}

    # On ajoute 2 départements
    #  - 1 associé à la commune du dossier
    #  - 1 non associé au dossier
    ${lib_dept} =  Set Variable  Dept NTC
    &{dept_values} =  Create Dictionary
    ...  dep=${code_dept}
    ...  reg=20
    ...  cheflieu=20001
    ...  tncc=0
    ...  ncc=DEPT1
    ...  nccenr=DEPT1NOT
    ...  libelle=${lib_dept}
    ...  om_validite_debut=${date_courante}
    Ajouter département  ${dept_values}
    ${lib_dept_2} =  Set Variable  Dept NTC2
    ${code_dept_2} =  Set Variable  23
    &{dept_values} =  Create Dictionary
    ...  dep=${code_dept_2}
    ...  reg=23
    ...  cheflieu=23000
    ...  tncc=1
    ...  ncc=DEPT2
    ...  nccenr=DEPT2NOT
    ...  libelle=${lib_dept_2}
    ...  om_validite_debut=${date_courante}
    Ajouter département  ${dept_values}

    # On ajoute une catégorie de tiers consulté
    ${om_collectivite_tiers} =  Create List  ${librecom_values.om_collectivite_libelle}
    Set Suite Variable  ${cat_tiers}  Categorie test notif tiers
    &{categorie_tiers} =  Create Dictionary
    ...  code=CAT_TEST_NTC
    ...  libelle=${cat_tiers}
    ...  description=Categorie servant pour le test de la notification des tiers consultés.
    ...  om_collectivite=${om_collectivite_tiers}
    ${id_cat_tiers} =  Ajouter la categorie de tiers consulte  ${categorie_tiers}
    Set Suite Variable  ${id_cat_tiers}

    Set Suite Variable  ${cat_tiers_2}  Categorie test acteur
    &{categorie_tiers} =  Create Dictionary
    ...  code=CAT_TEST_ANTC
    ...  libelle=${cat_tiers_2}
    ...  description=Categorie servant pour le test de l'onglet acteur des DI.
    ...  om_collectivite=${om_collectivite_tiers}
    ${id_cat_tiers_2} =  Ajouter la categorie de tiers consulte  ${categorie_tiers}
    Set Suite Variable  ${id_cat_tiers_2}

    # tiers consulté
    Set Suite Variable  ${tcnotif}  Tiers consulté notifiable
    Set Suite Variable  ${liste_diffusion_tc}  tcnotifiable@atreal.fr
    &{tc_values} =  Create Dictionary
    ...  categorie_tiers_consulte=${cat_tiers}
    ...  abrege=TCN
    ...  liste_diffusion=${liste_diffusion_tc}
    ...  libelle=${tcnotif}
    ...  ville=${collectivite}
    ...  accepte_notification_email=true
    Ajouter le tiers consulte depuis le listing  ${tc_values}

    Set Suite Variable  ${tacteur1}  Tiers acteur B
    Set Suite Variable  ${liste_diffusion_ta}  acteur@atreal.fr
    &{tc_values} =  Create Dictionary
    ...  categorie_tiers_consulte=${cat_tiers_2}
    ...  abrege=TA1
    ...  liste_diffusion=${liste_diffusion_ta}
    ...  libelle=${tacteur1}
    ...  ville=${collectivite}
    ...  accepte_notification_email=true
    Ajouter le tiers consulte depuis le listing  ${tc_values}
    Set Suite Variable  ${tacteur2}  Tiers acteur A
    &{tc_values} =  Create Dictionary
    ...  categorie_tiers_consulte=${cat_tiers_2}
    ...  abrege=TA2
    ...  adresse=8 avenue Bouvard
    ...  complement=complement
    ...  cp=74000
    ...  liste_diffusion=${liste_diffusion_ta}
    ...  libelle=${tacteur2}
    ...  ville=${collectivite}
    ...  accepte_notification_email=true
    ...  uid_platau_acteur=plop
    Ajouter le tiers consulte depuis le listing  ${tc_values}
    Set Suite Variable  ${tiersSansMail}  Tiers sans mail
    &{tc_values} =  Create Dictionary
    ...  categorie_tiers_consulte=${cat_tiers_2}
    ...  abrege=TASM
    ...  libelle=${tiersSansMail}
    ...  ville=${collectivite}
    ...  accepte_notification_email=true
    Ajouter le tiers consulte depuis le listing  ${tc_values}
    Set Suite Variable  ${tiersNonNotifiable}  Tiers non notifiable
    &{tc_values} =  Create Dictionary
    ...  categorie_tiers_consulte=${cat_tiers_2}
    ...  abrege=TANN
    ...  liste_diffusion=${liste_diffusion_ta}
    ...  libelle=${tiersNonNotifiable}
    ...  ville=${collectivite}
    Ajouter le tiers consulte depuis le listing  ${tc_values}
    Set Suite Variable  ${tiersNonLieComDep}  Tiers non lié commune / département
    &{tc_values} =  Create Dictionary
    ...  categorie_tiers_consulte=${cat_tiers_2}
    ...  abrege=TANLC/D
    ...  liste_diffusion=${liste_diffusion_ta}
    ...  libelle=${tiersNonLieComDep}
    ...  ville=${collectivite}
    ...  accepte_notification_email=true
    Ajouter le tiers consulte depuis le listing  ${tc_values}

    # types d'habilitation de tiers consulté
    ${type_habilitation_ok} =  Set Variable  TYPE HAB NOTIFIABLE
    &{type_habilitation_tiers_consulte} =  Create Dictionary
    ...  code=457
    ...  libelle=${type_habilitation_ok}
    ...  om_validite_debut=${date_courante}
    Ajouter un type d'habilitation de tiers consulté  ${type_habilitation_tiers_consulte}

    # habilitations 
    @{communes} =  Create List  ${code_commune} - ${lib_commune}  ${code_commune_2} - ${lib_commune_2}
    @{depts} =  Create List  ${code_dept} - ${lib_dept}  ${code_dept_2} - ${lib_dept_2}
    &{habilitation_tiers_consulte_values} =  Create Dictionary
    ...  type_habilitation_tiers_consulte=${type_habilitation_ok}
    ...  tiers_consulte=${tcnotif}
    Ajouter une habilitation de tiers consulté  ${habilitation_tiers_consulte_values}  ${depts}  ${communes}
    &{habilitation_tiers_consulte_values} =  Create Dictionary
    ...  type_habilitation_tiers_consulte=${type_habilitation_ok}
    ...  tiers_consulte=${tacteur1}
    Ajouter une habilitation de tiers consulté  ${habilitation_tiers_consulte_values}  ${depts}  ${communes}
    &{habilitation_tiers_consulte_values} =  Create Dictionary
    ...  type_habilitation_tiers_consulte=${type_habilitation_ok}
    ...  tiers_consulte=${tacteur2}
    Ajouter une habilitation de tiers consulté  ${habilitation_tiers_consulte_values}  ${depts}  ${communes}
    &{habilitation_tiers_consulte_values} =  Create Dictionary
    ...  type_habilitation_tiers_consulte=${type_habilitation_ok}
    ...  tiers_consulte=${tiersSansMail}
    Ajouter une habilitation de tiers consulté  ${habilitation_tiers_consulte_values}  ${depts}  ${communes}
    &{habilitation_tiers_consulte_values} =  Create Dictionary
    ...  type_habilitation_tiers_consulte=${type_habilitation_ok}
    ...  tiers_consulte=${tiersNonNotifiable}
    Ajouter une habilitation de tiers consulté  ${habilitation_tiers_consulte_values}  ${depts}  ${communes}
    &{habilitation_tiers_consulte_values} =  Create Dictionary
    ...  type_habilitation_tiers_consulte=${type_habilitation_ok}
    ...  tiers_consulte=${tiersNonLieComDep}
    Ajouter une habilitation de tiers consulté  ${habilitation_tiers_consulte_values}

    # PARAMETRAGE EVENEMENTS
    &{args_lettretype} =  Create Dictionary
    ...  id=test_NOTIF_tiers
    ...  libelle=Test
    ...  sql=Aucune REQUÊTE
    ...  titre=&idx, &destinataire, aujourdhui&aujourdhui, datecourrier&datecourrier, &departement
    ...  corps=Ceci est un document
    ...  actif=true
    ...  collectivite=agglo
    Ajouter la lettre-type depuis le menu  &{args_lettretype}
    # On ajoute un événement avec notification automatique des tiers consulté
    # et on test l'affichage du champs de sélection des types d'habilitation
    @{etat_source} =  Create List  delai de notification envoye
    @{type_di} =  Create List  PCI - P - Initial
    @{type_habilitation_tiers_consulte} =  Create List  ${type_habilitation_ok}
    Set Suite Variable  ${evenement_notif_auto_tc}  TEST_NOTIF_TC
    &{args_evenement} =  Create Dictionary
    ...  libelle=${evenement_notif_auto_tc}
    ...  etats_depuis_lequel_l_evenement_est_disponible=${etat_source}
    ...  dossier_instruction_type=${type_di}
    ...  lettretype=test_NOTIF_tiers Test
    ...  notification_tiers=Notification automatique
    ...  type_habilitation_tiers_consulte=${type_habilitation_tiers_consulte}
    Ajouter l'événement depuis le menu  ${args_evenement}


Gestion de l'affichage en fonction de l'option "option_parametrage_notification_auto_tiers"
    [Documentation]  Gere l'affichage en fonction de l'option "option_parametrage_notification_auto_tiers"

    Depuis la page d'accueil  admin  admin
    # Ajout d'un administrateur général à la commune pour paramètrer la notification automatique
    Ajouter l'utilisateur depuis le menu  
    ...    Lucien Marcheciel
    ...    cmonpere@guerredesetoiles.galaxie
    ...    lulu 
    ...    lulu
    ...    ADMINISTRATEUR TECHNIQUE ET FONCTIONNEL
    ...    LIBRECOM_NOTIFTIERS
    # SUppression de l'option au niveau de l'agglo
    &{param_args} =  Create Dictionary
    ...  selection_col=libellé
    ...  search_value=option_parametrage_notification_auto_tiers
    ...  click_value=agglo
    Supprimer le paramètre (surcharge)  ${param_args}
    # Activation de l'option de paramétrage des tiers pour la collectivité LIBRECOM_NOTIFTIERS
    # pour la suite des tests
    &{params} =  Create Dictionary
    ...  libelle=option_parametrage_notification_auto_tiers
    ...  valeur=true
    ...  om_collectivite=LIBRECOM_NOTIFTIERS
    Ajouter ou modifier le paramètre depuis le menu  ${params}

    # Vérification que pour la collectivité LIBRECOM_NOTIFTIERS les champs de paramétrage de la
    # notification automatique des tiers et l'onglet acteur des DI sont visibles.
    Depuis la page d'accueil  lulu  lulu
    # Le champs Catégorie de tiers acteurs doit être accessible depuis le formulaire de paramétrage
    # des types de dossiers d'instruction
    Depuis le formulaire de modification d'un type de dossier d'instruction  PCI  P
    Element Should Be Visible  css=select#categories_tiers
    # Le champs notification tiers dois contenir la valeur "notification automatique"
    Depuis le formulaire de modification de l'événement  ${evenement_notif_auto_tc}
    @{expected_select_value} =  Create List  Aucune  Notification manuelle  Notification automatique
    Select List Should Be  notification_tiers  ${expected_select_value}
    Select From List By Label  css=select#notification_tiers  Notification automatique
    Wait Until Page Contains Element  css=#type_habilitation_tiers_consulte
    # Accède à l'onglet acteur d'un dossier déjà existant. Si on y accède <=> l'onglet est visible
    # Récupère le payload de création DI
    &{args_petitionnaire} =  Create Dictionary
    ...  particulier_nom=natc
    ...  particulier_prenom=natc
    &{args_demande} =  Create Dictionary
    ...  dossier_autorisation_type_detaille=Permis de construire pour une maison individuelle et / ou ses annexes
    ...  demande_type=Dépôt Initial
    ...  commune=${lib_commune}
    ${di_libelle} =  Ajouter la nouvelle demande  ${args_demande}  ${args_petitionnaire}
    Depuis l'onglet acteur du dossier d'instruction  ${di_libelle}


    # Vérification que pour les autres collectivités les champs de paramétrage de la
    # notification automatique des tiers et l'onglet acteur ne sont pas visible.
    Depuis la page d'accueil  admin  admin
    # Le champs Catégorie de tiers acteurs ne doit pas être visible dans le formulaire de paramétrage
    # des types de dossiers d'instruction
    Depuis le formulaire de modification d'un type de dossier d'instruction  PCI  P
    Page Should Not Contain Element  css=select#categories_tiers
    # Le champs notification tiers dois contenir la valeur "notification automatique"
    Depuis le formulaire de modification de l'événement  ${evenement_notif_auto_tc}
    # @{expected_select_value} =  Create List  Aucune  Notification manuelle
    Select List Should Be  notification_tiers  ${expected_select_value}
    # Accède à l'onglet acteur d'un dossier déjà existant. Si on y accède <=> l'onglet est visible
    Depuis le contexte du dossier d'instruction  ${di_libelle}
    Page Should Not Contain Element  css=a#lien_dossier_tiers

    # Suppression de l'option de paramétrage des tiers pour la collectivité LIBRECOM_NOTIFTIERS
    &{param_args} =  Create Dictionary
    ...  selection_col=libellé
    ...  search_value=option_parametrage_notification_auto_tiers
    ...  click_value=LIBRECOM_NOTIFTIERS
    Supprimer le paramètre (surcharge)  ${param_args}
    # Reactivation de l'option de paramétrage des tiers sur l'agglo pour la suite des tests
    &{params} =  Create Dictionary
    ...  libelle=option_parametrage_notification_auto_tiers
    ...  valeur=true
    ...  om_collectivite=agglo
    Ajouter ou modifier le paramètre depuis le menu  ${params}

Fonctionnement de l'onglet acteur du dossier
    [Documentation]  Test du fonctionnement de l'onglet acteur d'un dossier.
    ...  Vérifie 3 cas d'usage :
    ...    1- Aucune catégorie de tiers n'est lié au type de dossier du dossier en cours
    ...       -> pas de tableau affiché dans l'onglet acteur
    ...    2- Des catégories de tiers sont liées au type de dossier du dossier en cours
    ...       -> présence d'un tableau par catégorie dans l'onglet. Possibilité d'ajouter
    ...          consulter et supprimer des acteurs d'une catégorie depuis le tableau.
    ...    3- Existance d'acteur dont la catégorie n'est plus liée au type de dossier du
    ...       dossier en cours
    ...       -> présence du tableau de cette catégorie avec son acteur. Possibilité d'ajouter
    ...          consulter et supprimer des acteurs de cette catégorie depuis le tableau.
    ...          Si tous les acteurs de ce tableau sont supprimés le tableau n'est plus affiché.

    # Création d'un dossier
    Depuis la page d'accueil  admin  admin
    &{args_petitionnaire} =  Create Dictionary
    ...  particulier_nom=test onglet
    ...  particulier_prenom=acteur
    ...  particulier_prenom=acteur
    ...  om_collectivite=${collectivite}
    &{args_demande} =  Create Dictionary
    ...  dossier_autorisation_type_detaille=Permis de construire pour une maison individuelle et / ou ses annexes
    ...  demande_type=Dépôt Initial
    ...  commune=${lib_commune}
    ...  om_collectivite=${collectivite}
    ${di_libelle} =  Ajouter la nouvelle demande  ${args_demande}  ${args_petitionnaire}

    # Cas 1 : Pas de catégorie de tiers ajoutable à un dossier
    # Création d'un dossier
    Depuis l'onglet acteur du dossier d'instruction  ${di_libelle}
    Page Should Contain  Aucun acteur à ajouter pour ce dossier.
    
    # Cas 2 : ajout de deux catégories de tiers au PCI initial. Un tableau doit être affiché
    # pour chaque catégorie
    @{categorie_tiers_dossier} =  Create List  ${cat_tiers}  ${cat_tiers_2}
    &{val_PCI} =  Create Dictionary
    ...  categories_tiers=${categorie_tiers_dossier}
    Modifier type de dossier d'instruction  PCI  P  ${val_PCI}

    Depuis l'onglet acteur du dossier d'instruction  ${di_libelle}
    # Test l'affichage des tableaux des catégories et de leur barre de titre par ordre alphabétique.
    Element Should Contain  css=#sousform-lien_dossier_tiers #actor-category-title:nth-of-type(1)  Categorie Test Acteur
    Page Should Contain Element  css=#sousform-acteur_category_${id_cat_tiers_2}
    Element Should Contain  css=#sousform-lien_dossier_tiers #actor-category-title:nth-of-type(2)  Categorie Test Notif Tiers
    Page Should Contain Element  css=#sousform-acteur_category_${id_cat_tiers}
    # Test du fonctionnement du formulaire d'ajout d'acteur
    Depuis le formulaire d'ajout des acteurs d'une catégorie au dossier  ${di_libelle}  ${id_cat_tiers_2}
    # TODO : vérifier le contenu du select
    @{tiers_selectionnable} =  Create List  ${tacteur1}  ${tacteur2}
    @{tiers_non_selectionnable} =  Create List  ${tcnotif}  ${tiersSansMail}  ${tiersNonNotifiable}  ${tiersNonLieComDep}
    # Rend le select visible pour permettre de voir les options
    Chosen List Should Contain List      select#tiers  ${tiers_selectionnable}
    Chosen List Should Not Contain List  select#tiers  ${tiers_non_selectionnable}
    # La catégorie doit être visible dans le fil d'Ariane
    Element Should Contain  css=div.subtitle  ${cat_tiers_2}
    # Vérifie que le formulaire d'ajout des acteurs affiche bien une erreur si
    # aucun tiers n'est sélection
    Click On Submit Button Until Message  Le remplissage du champs tiers est obligatoire.\nSAISIE NON ENREGISTRÉE
    Element Should Contain  css=div.subtitle  ${cat_tiers_2}
    # Ajout de deux acteurs et vérification de l'affichage trier par ordre alphabétique
    # dans le tableau correspondant
    @{acteurs} =  Create List  ${tacteur1}  ${tacteur2}
    Saisir des acteurs  ${acteurs}
    Click On Submit Button Until Message  L'acteurs ${tacteur1} a été ajouté au dossier.
    Wait Until Element Contains  css=#sousform-acteur_category_${id_cat_tiers_2} table tr.tab-data:nth-of-type(1)  ${tacteur2}
    Element Should Contain  css=#sousform-acteur_category_${id_cat_tiers_2} table tr.tab-data:nth-of-type(2)  ${tacteur1}
    # Vérifie l'affichage de la page de consultation d'un acteur
    Cliquer sur le bouton de consultation de l'acteur  ${tacteur2}
    Le portlet d'action ne doit pas être présent dans le sous-formulaire
    &{values_to_test} =  Create Dictionary
    ...  categorie_tiers_consulte=${cat_tiers_2}
    ...  abrege=TA2
    ...  adresse=8 avenue Bouvard
    ...  complement=complement
    ...  cp=74000
    ...  liste_diffusion=${liste_diffusion_ta}
    ...  tiers=${tacteur2}
    ...  ville=${collectivite}
    ...  accepte_notification_email=Oui
    ...  uid_platau_acteur=plop
    ${values}=  Get Dictionary Items  ${values_to_test}
    :FOR  ${key}  ${value}  IN  @{values}
    \  Element Should Contain  css=#${key}  ${value}
    Click On Back Button In SubForm
    # Vérifie le fonctionnement de la suppression de l'acteur.
    Cliquer sur le bouton de suppression de l'acteur  ${tacteur2}
    Wait Until Element Does Not Contain  css=#sousform-acteur_category_${id_cat_tiers_2}  ${tacteur2}

    # Cas 3 : délie la catégorie 2 du type de dossier et vérifie qu'elle apparait toujours sur le dossier
    # jusqu'à ce que ses acteurs soient supprimé
    @{categorie_tiers_dossier} =  Create List  ${cat_tiers}
    &{val_PCI} =  Create Dictionary
    ...  categories_tiers=${categorie_tiers_dossier}
    Modifier type de dossier d'instruction  PCI  P  ${val_PCI}

    Depuis l'onglet acteur du dossier d'instruction  ${di_libelle}
    Page Should Contain Element  css=#sousform-acteur_category_${id_cat_tiers_2}
    @{acteurs} =  Create List  ${tacteur2}
    # Vérifie que l'ajout d'acteur est toujours possible pour cette catégorie
    Ajouter des acteurs d'une catégorie au dossier  ${di_libelle}  ${id_cat_tiers_2}  ${acteurs}
    # Vérifie que la suppression d'acteur est toujours possible pour cette catégorie
    Cliquer sur le bouton de suppression de l'acteur  ${tacteur1}
    Wait Until Element Does Not Contain  css=#sousform-acteur_category_${id_cat_tiers_2}  ${tacteur1}
    # Vérifie que la consultation d'acteur est toujours possible pour cette catégorie
    Cliquer sur le bouton de consultation de l'acteur  ${tacteur2}
    Element Should Contain  css=#tiers  ${tacteur2}
    Click On Back Button In SubForm
    # Suppression du dernière acteur de la catégorie. Le tableau de la catégorie doit disparaître
    Cliquer sur le bouton de suppression de l'acteur  ${tacteur2}
    Wait Until Page Does Not Contain  ${cat_tiers_2}

Activation de la notification par mail
    [Documentation]  Active la notification par mail des demandeurs

    Depuis la page d'accueil  admin  admin

    &{om_param} =  Create Dictionary
    ...  libelle=option_notification
    ...  valeur=mail
    ...  om_collectivite=${collectivite}
    Ajouter ou modifier le paramètre depuis le menu  ${om_param}

    Démarrer maildump

TNR doublon notification tiers consulté
    [Documentation]  Test de la notification automatique des tiers consultés.
    ...  Vérifie que seul les tiers ayant le type d'habilitation sélectionné
    ...  sont notifiés. Vérifie également que le service consulté en charge du
    ...  dossier n'est pas notifié et qu'uniquement les tiers associés à la
    ...  commune et au département du dossier le sont.

    # Préparation de la consultation entrante du dossier
    # Change le type affichage du type de DA
    &{args_da_type} =  Create Dictionary
    ...  affichage_form=CONSULTATION ENTRANTE
    Modifier le type de dossier d'autorisation  Permis de construire  ${args_da_type}
    # Récupère le payload de création DI
    ${json_payload} =  Get File  ${EXECDIR}${/}binary_files${/}json_payload_ref.txt
    ${json_payload} =  Replace String  ${json_payload}  3XY-DK4-7X  000-AAA-00
    ${json_payload} =  Replace String  ${json_payload}  7XY-DK8-5X  AAA-000-00
    ${json_payload} =  Replace String  ${json_payload}  13055  ${code_commune}
    ${json_payload} =  Replace String  ${json_payload}  SDF-ZER-74R  ${acteur}
    ${json_payload} =  Replace String  ${json_payload}  EF-DSQ-4512  ${acteur}
    ${payload_dict} =  To Json  ${json_payload}
    # Préparation de la tâche de création du dossier
    ${task_values} =  Create Dictionary
    ...  type=create_DI_for_consultation
    ...  json_payload=${json_payload}
    Ajouter la tâche par WS  ${task_values}

    # Ajout du dossier sur lequel on va déclencher la notification automatique
    # associé à la commune et à la consultation entrante voulu
    ${msg} =  Déclencher le traitement des tâches par WS
    # Récupération du numéro de dossier
    ${search_values} =  Create Dictionary
    ...  source_depot=Plat'AU
    ...  om_collectivite=${collectivite}
    Depuis le contexte du dossier d'instruction par la recherche avance  ${search_values}  ${collectivite}
    Wait Until Keyword Succeeds  ${TIMEOUT}  ${RETRY_INTERVAL}  Page Should Contain Element  css=#dossier_libelle
    ${di_notif_auto_tiers} =  Get Text  css=#dossier_libelle

    # Ajout des acteurs à notifier
    @{acteurs} =  Create List  ${tcnotif}
    Ajouter des acteurs d'une catégorie au dossier  ${di_notif_auto_tiers}  ${id_cat_tiers}  ${acteurs}

    # Ajout de l'instruction declenchant la notification et saisie de la date de retour
    # de signature pour déclencher la notification des tiers
    ${inst_notif_auto} =  Ajouter une instruction au DI et la finaliser  ${di_notif_auto_tiers}  ${evenement_notif_auto_tc}
    Click On SubForm Portlet Action  instruction  modifier_suivi
    Input Datepicker  date_retour_signature  ${date_courante}
    Click On Submit Button In Subform

    Wait until element contains  css=tr:nth-child(1) td[data-column-id="émetteur"]      admin (Administrateur) (automatique)
    Page Should Contain Element  xpath=//tr/td[normalize-space(text()) = "${tcnotif} : ${liste_diffusion_tc}"]  None  INFO  1

    # Réinitialise le type affichage du type de DA
    &{args_da_type} =  Create Dictionary
    ...  affichage_form=ADS
    Modifier le type de dossier d'autorisation  Permis de construire  ${args_da_type}

Rétablissement des paramètres


    # Désactivation de l'option de paramétrage des tiers pour la collectivité LIBRECOM_NOTIFTIERS
    &{param_args} =  Create Dictionary
    ...  selection_col=libellé
    ...  search_value=option_parametrage_notification_auto_tiers
    ...  click_value=agglo
    Supprimer le paramètre (surcharge)  ${param_args}
    # Désactivation de l'option option_dossier_commune et de l'option option_mode_service_consulte
    &{param_args} =  Create Dictionary
    ...  selection_col=libellé
    ...  search_value=option_dossier_commune
    ...  click_value=agglo
    Supprimer le paramètre (surcharge)  ${param_args}
    Désactiver le mode service consulté
    # supprime le paramètre 'acteur' de la collectivité/au service
    &{param_args} =  Create Dictionary
    ...  selection_col=libellé
    ...  search_value=platau_acteur_service_consulte
    ...  click_value=${collectivite}
    Supprimer le paramètre (surcharge)  ${param_args}
    # définir les paramètres de type de demande
    &{param_args} =  Create Dictionary
    ...  selection_col=libellé
    ...  search_value=platau_type_demande_initial_PCI
    ...  click_value=agglo
    Supprimer le paramètre (surcharge)  ${param_args}