*** Settings ***
Documentation  Test de la gestion d'incomplétude

# On inclut les mots-clefs
Resource  resources/resources.robot
# On ouvre/ferme le navigateur au début/à la fin du Test Suite.
Suite Setup  For Suite Setup
Suite Teardown  For Suite Teardown


*** Test Cases ***
Constitution du Workflow de gestion d'une incomplétude
    [Documentation]  Création du Workflow complet permettant la gestion de l'incomplétude dans un dossier d'instruction

    Depuis la page d'accueil  admin  admin

    # Création des actions
    # incomplétude
    Set Suite Variable  ${incompletude_libelle}  incompletude_190
    &{args_action} =  Create Dictionary
    ...  action=${incompletude_libelle}
    ...  libelle=${incompletude_libelle}
    ...  regle_etat=etat
    ...  regle_incompletude=t
    ...  regle_etat_pendant_incompletude=archive_etat
    Ajouter l'action depuis le menu  ${args_action}
    # incomplétude notifiée
    Set Suite Variable  ${incompletude_notifiee_libelle}  incompletude_notifiee_190
    &{args_action} =  Create Dictionary
    ...  action=${incompletude_notifiee_libelle}
    ...  libelle=${incompletude_notifiee_libelle}
    ...  regle_etat=etat
    ...  regle_date_complet=null
    ...  regle_date_limite_incompletude=date_evenement+delai
    ...  regle_delai_incompletude=delai
    ...  regle_incomplet_notifie=t
    ...  regle_evenement_suivant_tacite_incompletude=t
    Ajouter l'action depuis le menu  ${args_action}
    # dépôt de pièce complémentaire
    Set Suite Variable  ${dpc_libelle}  dpc_190
    &{args_action} =  Create Dictionary
    ...  action=${dpc_libelle}
    ...  libelle=${dpc_libelle}
    ...  regle_date_dernier_depot=date_evenement
    Ajouter l'action depuis le menu  ${args_action}
    # complétude
    Set Suite Variable  ${completude_libelle}  completude_190
    &{args_action} =  Create Dictionary
    ...  action=${completude_libelle}
    ...  libelle=${completude_libelle}
    ...  regle_etat=archive_etat_pendant_incompletude
    ...  regle_accord_tacite=accord_tacite
    ...  regle_date_limite=archive_date_dernier_depot+archive_delai
    ...  regle_date_notification_delai=archive_date_dernier_depot+delai_notification
    ...  regle_date_complet=archive_date_dernier_depot
    ...  regle_date_limite_incompletude=null
    ...  regle_delai_incompletude=null
    ...  regle_incompletude=f
    ...  regle_incomplet_notifie=f
    ...  regle_etat_pendant_incompletude=null
    Ajouter l'action depuis le menu  ${args_action}

    # Création des états
    # incompletude
    &{args_etat} =  Create Dictionary
    ...  etat=${incompletude_libelle}
    ...  libelle=${incompletude_libelle}
    ...  statut=En cours
    Ajouter état  ${args_etat}
    # incompletude notifiée
    &{args_etat} =  Create Dictionary
    ...  etat=${incompletude_notifiee_libelle}
    ...  libelle=${incompletude_notifiee_libelle}
    ...  statut=En cours
    Ajouter état  ${args_etat}

    # Création des événements
    @{type_di} =  Create List  PCI - P - Initial
    # incomplétude notifiée
    &{args_evenement} =  Create Dictionary
    ...  libelle=${incompletude_notifiee_libelle}
    ...  retour=true
    ...  etat=${incompletude_notifiee_libelle}
    # Non nécessaire car récupéré depuis l'événement parent (incompletude_190)
    # ...  delai=3 Mois
    # ...  accord_tacite=Oui
    # ...  restriction=date_evenement<=archive_date_notification_delai
    ...  action=${incompletude_notifiee_libelle}
    ...  evenement_suivant_tacite=rejet tacite
    Ajouter l'événement depuis le menu  ${args_evenement}
    # incomplétude
    @{etat_source} =  Create List  delai de notification envoye
    &{args_evenement} =  Create Dictionary
    ...  libelle=${incompletude_libelle}
    ...  restriction=date_evenement<=archive_date_notification_delai
    ...  etats_depuis_lequel_l_evenement_est_disponible=${etat_source}
    ...  dossier_instruction_type=${type_di}
    ...  etat=${incompletude_libelle}
    ...  delai=3 Mois
    ...  accord_tacite=Oui
    ...  lettretype=piececomplementaire NOTIFICATION D'UNE DEMANDE DE PIECES COMPLEMENTAIRES
    ...  action=${incompletude_libelle}
    ...  evenement_retour_signature=${incompletude_notifiee_libelle}
    Ajouter l'événement depuis le menu  ${args_evenement}
    # dépôt de pièce complémentaire
    @{etat_source} =  Create List  ${incompletude_notifiee_libelle}
    &{args_evenement} =  Create Dictionary
    ...  libelle=${dpc_libelle}
    ...  etats_depuis_lequel_l_evenement_est_disponible=${etat_source}
    ...  dossier_instruction_type=${type_di}
    ...  lettretype=recepisse_DPC RECEPISSE DE DEPOT DE PIECES COMPLEMENTAIRES
    ...  action=${dpc_libelle}
    Ajouter l'événement depuis le menu  ${args_evenement}
    # completude
    &{args_evenement} =  Create Dictionary
    ...  libelle=${completude_libelle}
    ...  etats_depuis_lequel_l_evenement_est_disponible=${etat_source}
    ...  dossier_instruction_type=${type_di}
    ...  accord_tacite=Oui
    ...  delai_notification=1 Mois
    ...  action=${completude_libelle}
    Ajouter l'événement depuis le menu  ${args_evenement}

    # Modification de l'événement de récépissé
    &{args_evenement} =  Create Dictionary
    ...  libelle=Notification du delai legal maison individuelle
    ...  evenement_suivant_tacite=accord tacite (sans arrete)
    Modifier l'événement  ${args_evenement}


Cas d'utilisation complet d'une incomplétude jusqu'à la complétude
    [Documentation]  Vérification du comportement des données d'un dossier d'instruction lors d'une incomplétude :
    ...  * l'état
    ...  * le délai
    ...  * la date limite d'instruction
    ...  * l'événement suivant tacite

    # Ajout du dossier d'instruction
    &{args_petitionnaire} =  Create Dictionary
    ...  particulier_nom=DESJARDINS
    ...  particulier_prenom=Laurent
    ...  om_collectivite=MARSEILLE
    &{args_demande} =  Create Dictionary
    ...  dossier_autorisation_type_detaille=Permis de construire pour une maison individuelle et / ou ses annexes
    ...  demande_type=Dépôt Initial
    ...  om_collectivite=MARSEILLE
    ${di} =  Ajouter la demande par WS  ${args_demande}  ${args_petitionnaire}

    # Récupèration des données à comparer
    Depuis le contexte du dossier d'instruction  ${di}
    ${etat_ph1} =  Get Text  etat
    ${date_complet_ph1} =  Get Text  date_complet
    ${delai_ph1} =  Get Text  delai
    ${date_limite_ph1} =  Get Text  date_limite
    ${evenement_suivant_tacite_ph1} =  Get Value  evenement_suivant_tacite
    ${incompletude_ph1} =  Get Value  incompletude
    ${incomplet_notifie_ph1} =  Get Value  incomplet_notifie
    ${date_limite_incompletude_ph1} =  Get Value  date_limite_incompletude
    ${evenement_suivant_tacite_incompletude_ph1} =  Get Value  evenement_suivant_tacite_incompletude
    ${etat_pendant_incompletude_ph1} =  Get Value  etat_pendant_incompletude
    ${delai_incompletude_ph1} =  Get Value  delai_incompletude

    # Ajout de l'instruction d'incomplétude
    Ajouter une instruction au DI et la finaliser  ${di}  ${incompletude_libelle}

    # Récupèration des données à comparer
    Depuis le contexte du dossier d'instruction  ${di}
    ${etat_ph2} =  Get Text  etat
    ${date_complet_ph2} =  Get Text  date_complet
    ${delai_ph2} =  Get Text  delai
    ${date_limite_ph2} =  Get Text  date_limite
    ${evenement_suivant_tacite_ph2} =  Get Value  evenement_suivant_tacite
    ${incompletude_ph2} =  Get Value  incompletude
    ${incomplet_notifie_ph2} =  Get Value  incomplet_notifie
    ${date_limite_incompletude_ph2} =  Get Value  date_limite_incompletude
    ${evenement_suivant_tacite_incompletude_ph2} =  Get Value  evenement_suivant_tacite_incompletude
    ${etat_pendant_incompletude_ph2} =  Get Value  etat_pendant_incompletude
    ${delai_incompletude_ph2} =  Get Value  delai_incompletude
    # Vérification des données par rapport à la phase précèdente
    Should Not Be Equal  ${etat_ph2}  ${etat_ph1}
    Should Be Equal  ${date_complet_ph2}  ${date_complet_ph1}
    Should Be Equal  ${delai_ph2}  ${delai_ph1}
    Should Be Equal  ${date_limite_ph2}  ${date_limite_ph1}
    Should Be Equal  ${evenement_suivant_tacite_ph2}  ${evenement_suivant_tacite_ph1}
    Should Not Be Equal  ${incompletude_ph2}  ${incompletude_ph1}
    Should Be Equal  ${incomplet_notifie_ph2}  ${incomplet_notifie_ph1}
    Should Be Equal  ${date_limite_incompletude_ph2}  ${date_limite_incompletude_ph1}
    Should Be Equal  ${evenement_suivant_tacite_incompletude_ph2}  ${evenement_suivant_tacite_incompletude_ph1}
    Should Not Be Equal  ${etat_pendant_incompletude_ph2}  ${etat_pendant_incompletude_ph1}
    Should Be Equal  ${delai_incompletude_ph2}  ${delai_incompletude_ph1}
    # Vérification des valeurs
    Should Be Equal  ${etat_ph2}  ${incompletude_libelle}
    Should Be Equal  ${incompletude_ph2}  t

    # Suivi des dates : modification de la date de notification qui ne déclenche pas l'événement d'incomplétude notifié car paramétré sur la date de retour signature (ce qui n'était pas possible avant la version 4.14)
    Depuis l'instruction du dossier d'instruction  ${di}  ${incompletude_libelle}
    Click On SubForm Portlet Action  instruction  modifier_suivi
    Input Datepicker  date_retour_rar  ${date_ddmmyyyy}
    Click On Submit Button In Subform
    Depuis l'onglet instruction du dossier d'instruction  ${di}
    Page Should Not Contain  ${incompletude_notifiee_libelle}
    # Suivi des dates : modification de la date de signature qui ne déclenche pas l'événement d'incomplétude notifié car date saisie hors délai
    Depuis l'instruction du dossier d'instruction  ${di}  ${incompletude_libelle}
    Click On SubForm Portlet Action  instruction  modifier_suivi
    ${date_35d} =  Add Time To Date  ${date_ddmmyyyy}  35 days  %d/%m/%Y  False  %d/%m/%Y
    Input Datepicker  date_retour_signature  ${date_35d}
    Click On Submit Button In Subform
    Depuis l'onglet instruction du dossier d'instruction  ${di}
    Page Should Not Contain  ${incompletude_notifiee_libelle}
    # Vide la date de retour signature pour exécuter la suite du scénario
    Depuis l'instruction du dossier d'instruction  ${di}  ${incompletude_libelle}
    Click On SubForm Portlet Action  instruction  modifier_suivi
    Input Text  date_retour_signature  ${EMPTY}
    Click On Submit Button In Subform
    # Suivi des dates : modification de la date de signature qui ne déclenche pas l'événement d'incomplétude notifié
    Depuis l'instruction du dossier d'instruction  ${di}  ${incompletude_libelle}
    Click On SubForm Portlet Action  instruction  modifier_suivi
    ${date_5d} =  Add Time To Date  ${date_ddmmyyyy}  5 days  %d/%m/%Y  False  %d/%m/%Y
    Input Datepicker  date_retour_signature  ${date_5d}
    Click On Submit Button In Subform
    Depuis l'onglet instruction du dossier d'instruction  ${di}
    Page Should Contain  ${incompletude_notifiee_libelle}

    # Récupèration des données à comparer
    Depuis le contexte du dossier d'instruction  ${di}
    ${etat_ph3} =  Get Text  etat
    ${date_complet_ph3} =  Get Text  date_complet
    ${delai_ph3} =  Get Text  delai
    ${date_limite_ph3_bf} =  Get Value  date_limite
    ${date_limite_ph3} =  Convert Date  ${date_limite_ph3_bf}  date_format=%Y-%m-%d  result_format=%d/%m/%Y
    ${evenement_suivant_tacite_ph3} =  Get Value  evenement_suivant_tacite
    ${incompletude_ph3} =  Get Value  incompletude
    ${incomplet_notifie_ph3} =  Get Value  incomplet_notifie
    ${date_limite_incompletude_ph3} =  Get Text  date_limite_incompletude
    ${evenement_suivant_tacite_incompletude_ph3} =  Get Value  evenement_suivant_tacite_incompletude
    ${etat_pendant_incompletude_ph3} =  Get Value  etat_pendant_incompletude
    ${delai_incompletude_ph3} =  Get Value  delai_incompletude
    # Vérification des données par rapport à la phase précèdente
    Should Not Be Equal  ${etat_ph3}  ${etat_ph2}
    Should Not Be Equal  ${date_complet_ph3}  ${date_complet_ph2}
    Should Be Equal  ${delai_ph3}  ${delai_ph2}
    Should Be Equal  ${date_limite_ph3}  ${date_limite_ph2}
    Should Be Equal  ${evenement_suivant_tacite_ph3}  ${evenement_suivant_tacite_ph2}
    Should Be Equal  ${incompletude_ph3}  ${incompletude_ph2}
    Should Not Be Equal  ${incomplet_notifie_ph3}  ${incomplet_notifie_ph2}
    Should Not Be Equal  ${date_limite_incompletude_ph3}  ${date_limite_incompletude_ph2}
    Should Not Be Equal  ${evenement_suivant_tacite_incompletude_ph3}  ${evenement_suivant_tacite_incompletude_ph2}
    Should Be Equal  ${etat_pendant_incompletude_ph3}  ${etat_pendant_incompletude_ph2}
    Should Not Be Equal  ${delai_incompletude_ph3}  ${delai_incompletude_ph2}
    # Vérification des valeurs
    Element Should Not Be Visible  date_complet
    Should Be Equal  ${date_complet_ph3}  ${EMPTY}
    Should Be Equal  ${etat_ph3}  ${incompletude_notifiee_libelle}
    Should Be Equal  ${incomplet_notifie_ph3}  t
    Should Be Equal  ${delai_incompletude_ph3}  3

    # Ajout de l'instruction de dépôt de pièce complétaire
    ${date_10d} =  Add Time To Date  ${date_ddmmyyyy}  10 days  %d/%m/%Y  False  %d/%m/%Y
    Ajouter une instruction au DI et la finaliser  ${di}  ${dpc_libelle}  ${date_10d}

    # Ajout de l'instruction de complétude
    ${date_15d} =  Add Time To Date  ${date_ddmmyyyy}  15 days  %d/%m/%Y  False  %d/%m/%Y
    Ajouter une instruction au DI  ${di}  ${completude_libelle}  ${date_15d}

    # Vérification de l'état, de la date de complétude, du délai, de la date limite d'instruction et de l'événement suivant tacite
    # L'état, le délai et l'événement suivant tacite doivent être identiques à la seconde vérification
    # La date de complétude doit être identique à la date de dépôt de la pièce complémentaire
    # la date limite d'instruction doit être différente de la vérification précédente
    # XXX

    # Récupèration des données à comparer
    Depuis le contexte du dossier d'instruction  ${di}
    ${etat_ph4} =  Get Text  etat
    ${date_complet_ph4} =  Get Text  date_complet
    ${delai_ph4} =  Get Text  delai
    ${date_limite_ph4} =  Get Text  date_limite
    ${evenement_suivant_tacite_ph4} =  Get Value  evenement_suivant_tacite
    ${incompletude_ph4} =  Get Value  incompletude
    ${incomplet_notifie_ph4} =  Get Value  incomplet_notifie
    ${date_limite_incompletude_ph4} =  Get Value  date_limite_incompletude
    ${evenement_suivant_tacite_incompletude_ph4} =  Get Value  evenement_suivant_tacite_incompletude
    ${etat_pendant_incompletude_ph4} =  Get Value  etat_pendant_incompletude
    ${delai_incompletude_ph4} =  Get Value  delai_incompletude
    # Vérification des données par rapport aux phases précèdentes
    Should Be Equal  ${etat_ph4}  ${etat_ph1}
    Should Not Be Equal  ${date_complet_ph4}  ${date_complet_ph3}
    Should Be Equal  ${delai_ph4}  ${delai_ph1}
    Should Not Be Equal  ${date_limite_ph4}  ${date_limite_ph3}
    Should Be Equal  ${evenement_suivant_tacite_ph4}  ${evenement_suivant_tacite_ph1}
    Should Not Be Equal  ${incompletude_ph4}  ${incompletude_ph3}
    Should Not Be Equal  ${incomplet_notifie_ph4}  ${incomplet_notifie_ph3}
    Should Not Be Equal  ${date_limite_incompletude_ph4}  ${date_limite_incompletude_ph3}
    Should Be Equal  ${evenement_suivant_tacite_incompletude_ph4}  ${evenement_suivant_tacite_incompletude_ph3}
    Should Not Be Equal  ${etat_pendant_incompletude_ph4}  ${etat_pendant_incompletude_ph3}
    Should Not Be Equal  ${delai_incompletude_ph4}  ${delai_incompletude_ph3}
    # Vérification des valeurs
    Element Should Be Visible  date_complet
    Should Be Equal  ${date_complet_ph4}  ${date_10d}
    Should Be Equal  ${etat_ph4}  delai de notification envoye
    Should Be Equal  ${incompletude_ph4}  f
    Should Be Equal  ${incomplet_notifie_ph4}  f
    Should Be Equal  ${delai_incompletude_ph4}  ${EMPTY}
    Should Be Equal  ${date_limite_incompletude_ph4}  ${EMPTY}
    Should Be Equal  ${etat_pendant_incompletude_ph4}  ${EMPTY}

    # Voir si ajouter ici ou dans le test 550 pour vérifier le WS de gestion des tacites
    # En cas d'incomplétude notifié sur un dossier, c'est l'événement suivant tacite incomplétude qui doit être utilisé et non l'événement suivant tacite du circuit normal