*** Settings ***
Documentation  Test sur la télétransmission

# On inclut les mots-clefs
Resource  resources/resources.robot
# On ouvre/ferme le navigateur au début/à la fin du Test Suite.
Suite Setup  For Suite Setup
Suite Teardown  For Suite Teardown

*** Test Cases ***
Vérification du champs date d'envoi en validation
    [Documentation]  Vérifie que le champs date d'envoi en validation fonctionne correctement.

    Depuis la page d'accueil  admin  admin
    # Ajout d'un dossier d'instruction
    &{args_petitionnaire} =  Create Dictionary
    ...  particulier_nom=Test140Clavet
    ...  particulier_prenom=Test140prenom
    ...  om_collectivite=MARSEILLE
    &{args_demande} =  Create Dictionary
    ...  dossier_autorisation_type_detaille=Permis de construire pour une maison individuelle et / ou ses annexes
    ...  demande_type=Dépôt Initial
    ...  om_collectivite=MARSEILLE
    #
    ${di} =  Ajouter la demande par WS  ${args_demande}  ${args_petitionnaire}
    #
    Depuis l'onglet instruction du dossier d'instruction  ${di}
    Wait Until Keyword Succeeds  ${TIMEOUT}  ${RETRY_INTERVAL}  Click Element  link:Notification du delai legal maison individuelle
    # Le champ ne doit pas être modifiable dans le suivi des dates
    Wait Until Keyword Succeeds  ${TIMEOUT}  ${RETRY_INTERVAL}  Click On SubForm Portlet Action  instruction  modifier_suivi
    ${attribute} =  Get Element Attribute  css=#date_envoi_circuit_signature  type
    Should Be Equal As Strings  ${attribute}  hidden
    # Le champ ne doit pas être modifiable dans le formulaire de modification
    Depuis l'onglet instruction du dossier d'instruction  ${di}
    Click Element  link:Notification du delai legal maison individuelle
    Wait Until Keyword Succeeds  ${TIMEOUT}  ${RETRY_INTERVAL}  Click On SubForm Portlet Action  instruction  definaliser
    Wait Until Keyword Succeeds  ${TIMEOUT}  ${RETRY_INTERVAL}  Click On SubForm Portlet Action  instruction  modifier
    ${attribute} =  Get Element Attribute  css=#date_envoi_circuit_signature  type
    Should Be Equal As Strings  ${attribute}  hidden

Vérification des actions Envoi au circuit de signature et Retrait du circuit de signature et du suivi des dates à partir de l'instruction
    [Documentation]  Ce test case à pour but de vérifier que les actions Envoi au circuit de signature, Retrait du circuit de signature
    ...  et l'interface de suivi des dates depuis l'instruction fonctionnent

    Depuis la page d'accueil  admin  admin

    # On met l'évènement en télétransmissible
    &{evenement} =  Create Dictionary
    ...  libelle=Notification du delai legal maison individuelle
    ...  teletransmissible=true
    Modifier l'événement  ${evenement}

    # ajoute le DI
    &{args_petitionnaire} =  Create Dictionary
    ...  particulier_nom=TEST140TELETRNOM
    ...  particulier_prenom=TEST140TELETRPRENOM
    ...  om_collectivite=MARSEILLE
    &{args_demande} =  Create Dictionary
    ...  dossier_autorisation_type_detaille=DECLARATION PREALABLE SIMPLE
    ...  demande_type=Dépôt Initial
    ...  om_collectivite=MARSEILLE
    ${dossier_instruction_teletr} =  Ajouter la demande par WS  ${args_demande}  ${args_petitionnaire}

    # On ne peut envoyer un dossier final que si il est constitué. Vérification que le message apparaît bien lors du click sur l'action
    Depuis l'instruction du dossier d'instruction  ${dossier_instruction_teletr}  Notification du delai legal maison individuelle
    Portlet Action Should Be In SubForm  instruction  envoi_circuit_signature
    Click On SubForm Portlet Action  instruction  envoi_circuit_signature  modale
    Wait Until Keyword Succeeds  ${TIMEOUT}  ${RETRY_INTERVAL}  Click Element  css=.ui-dialog .ui-dialog-buttonset .ui-button-text-only
    Wait Until Keyword Succeeds  ${TIMEOUT}  ${RETRY_INTERVAL}  Error Message Should Contain  Les pièces constituantes du dossier final doivent être identifiées avant l'envoi en circuit de signature.
    Wait Until Keyword Succeeds  ${TIMEOUT}  ${RETRY_INTERVAL}  Error Message Should Contain  Pour cela, sélectionnez-les depuis l'onglet Pièces > Toutes les pièces puis validez via l'action Constituer le dossier final.

    # Constitution du dossier final
    Depuis le contexte du dossier d'instruction  ${dossier_instruction_teletr}
    &{document_numerise_values} =  Create Dictionary
    ...  uid_upload=testImportManuel.pdf
    ...  date_creation=${date_ddmmyyyy}
    ...  document_numerise_type=vues et coupes du projet dans le profil du terrain naturel
    Ajouter une pièce depuis le dossier d'instruction  ${dossier_instruction_teletr}  ${document_numerise_values}
    Click On Back Button In Subform
    Wait Until Keyword Succeeds  ${TIMEOUT}  ${RETRY_INTERVAL}  Click Element  link:Toutes les pièces
    Wait Until Keyword Succeeds  ${TIMEOUT}  ${RETRY_INTERVAL}  Element Should Be Visible  name:constituer_dossier_final
    Click Element  name:constituer_dossier_final
    Wait Until Keyword Succeeds  ${TIMEOUT}  ${RETRY_INTERVAL}  Message Should Contain  Le dossier final a bien été constitué.

    # On vérifie que le message concernant la constitution n'est plus présent
    # Et on clique sur l'action d'envoi en circuit de signature alors que l'id d'évènement n'est pas paramétré
    Depuis l'instruction du dossier d'instruction  ${dossier_instruction_teletr}  Notification du delai legal maison individuelle
    Click On SubForm Portlet Action  instruction  envoi_circuit_signature  modale
    Wait Until Keyword Succeeds  ${TIMEOUT}  ${RETRY_INTERVAL}  Click Element  css=.ui-dialog .ui-dialog-buttonset .ui-button-text-only
    Wait Until Keyword Succeeds  ${TIMEOUT}  ${RETRY_INTERVAL}  Error Message Should Contain  Veuillez contacter votre administrateur pour paramétrer l'identifiant de l'événement associé.
    # On ajoute l'id d'évènement pour l'envoi au circuit de signature dans les paramètres
    Ajouter le paramètre depuis le menu  id_evenement_envoi_circuit_signature  113  agglo

    # On envoie le dossier en circuit de signature
    Depuis l'instruction du dossier d'instruction  ${dossier_instruction_teletr}  Notification du delai legal maison individuelle
    Click On SubForm Portlet Action  instruction  envoi_circuit_signature  modale
    Wait Until Keyword Succeeds  ${TIMEOUT}  ${RETRY_INTERVAL}  Click Element  css=.ui-dialog .ui-dialog-buttonset .ui-button-text-only

    Wait Until Keyword Succeeds  ${TIMEOUT}  ${RETRY_INTERVAL}  Valid Message Should Contain  Votre dossier a été transmis avec succès
    Wait Until Keyword Succeeds  ${TIMEOUT}  ${RETRY_INTERVAL}  Element Should Contain  date_envoi_circuit_signature  ${date_ddmmyyyy}

    # On vérifie que l'instruction à bien été créée dans le listing des instructions
    Depuis l'onglet instruction du dossier d'instruction  ${dossier_instruction_teletr}
    Page Should Contain  Envoi au circuit de signature

    # Vérification de l'action de retrait du circuit signature
    # Et on clique sur l'action de retrait du circuit de signature alors que l'id d'évènement n'est pas paramétré
    Depuis l'instruction du dossier d'instruction  ${dossier_instruction_teletr}  Notification du delai legal maison individuelle
    Portlet Action Should Be In SubForm  instruction  retrait_circuit_signature
    Click On SubForm Portlet Action  instruction  retrait_circuit_signature  modale
    Wait Until Keyword Succeeds  ${TIMEOUT}  ${RETRY_INTERVAL}  Click Element  css=.ui-dialog .ui-dialog-buttonset .ui-button-text-only
    Wait Until Keyword Succeeds  ${TIMEOUT}  ${RETRY_INTERVAL}  Error Message Should Contain  Veuillez contacter votre administrateur pour paramétrer l'identifiant de l'événement associé.

    # On ajoute l'id d'évènement pour le retrait du circuit de signature dans les paramètres
    Ajouter le paramètre depuis le menu  id_evenement_retrait_circuit_signature  114  agglo

    # On retire notre dossier du circuit de signature
    Depuis l'instruction du dossier d'instruction  ${dossier_instruction_teletr}  Notification du delai legal maison individuelle
    Click On SubForm Portlet Action  instruction  retrait_circuit_signature  modale
    Wait Until Keyword Succeeds  ${TIMEOUT}  ${RETRY_INTERVAL}  Click Element  css=.ui-dialog .ui-dialog-buttonset .ui-button-text-only
    Wait Until Keyword Succeeds  ${TIMEOUT}  ${RETRY_INTERVAL}  Valid Message Should Contain  Votre dossier a été retiré du circuit de signature avec succès

    # On vérifie que l'instruction a bien été créée dans le linsting des instructions
    Depuis l'onglet instruction du dossier d'instruction  ${dossier_instruction_teletr}
    Page Should Contain  Retrait du circuit de signature

    # On renvoie notre dossier en circuit de signature
    Depuis l'instruction du dossier d'instruction  ${dossier_instruction_teletr}  Notification du delai legal maison individuelle
    Wait Until Keyword Succeeds  ${TIMEOUT}  ${RETRY_INTERVAL}  Element Should Contain  date_envoi_controle_legalite  Auto
    Wait Until Keyword Succeeds  ${TIMEOUT}  ${RETRY_INTERVAL}  Element Should Contain  date_retour_controle_legalite  Auto
    Click On SubForm Portlet Action  instruction  envoi_circuit_signature  modale
    Wait Until Keyword Succeeds  ${TIMEOUT}  ${RETRY_INTERVAL}  Click Element  css=.ui-dialog .ui-dialog-buttonset .ui-button-text-only

    # On ajoute notre date de retour signature ce qui vérouille le dossier
    Click On SubForm Portlet Action  instruction  modifier_suivi
    Wait Until Keyword Succeeds  ${TIMEOUT}  ${RETRY_INTERVAL}  Element Should Contain  date_envoi_controle_legalite  Auto
    Wait Until Keyword Succeeds  ${TIMEOUT}  ${RETRY_INTERVAL}  Element Should Contain  date_retour_controle_legalite  Auto
    Input Datepicker  date_retour_signature  ${date_ddmmyyyy}
    Click On Submit Button In Subform
    Valid Message Should Contain  Le document va être télétransmis. Les champs "Date d'Envoi au Contrôle de Légalité" et "Date de Retour du Contrôle de Légalité" seront mises à jour automatiquement.

    # On change d'utilisateur pour éviter d'avoir le bypass et on vérifie que l'on ne peut plus ajouter, modifier ou supprimer les pièces du dossier
    Depuis la page d'accueil  instr  instr
    Depuis l'onglet des pièces du dossier d'instruction  ${dossier_instruction_teletr}
    Wait Until Keyword Succeeds  ${TIMEOUT}  ${RETRY_INTERVAL}  Element Should Not Be Visible  css=#action-soustab-blocnote-message-ajouter
    Wait Until Keyword Succeeds  ${TIMEOUT}  ${RETRY_INTERVAL}  Element Should Not Be Visible  css=.dossier_final_select_recommandees
    Wait Until Keyword Succeeds  ${TIMEOUT}  ${RETRY_INTERVAL}  Click Element  link:Toutes les pièces
    Wait Until Keyword Succeeds  ${TIMEOUT}  ${RETRY_INTERVAL}  Element Should Be Disabled  css=#checkbox_select_all_none
    Wait Until Keyword Succeeds  ${TIMEOUT}  ${RETRY_INTERVAL}  Element Should Be Disabled  css=.checkbox-dossier_final

    Depuis la page d'accueil  admin  admin
    # On remet l'évènement en non télétransmissible
    &{evenement} =  Create Dictionary
    ...  libelle=Notification du delai legal maison individuelle
    ...  teletransmissible=false
    Modifier l'événement  ${evenement}
    # On supprime les paramètre d'id d'évènement
    Supprimer le paramètre  id_evenement_envoi_circuit_signature
    Supprimer le paramètre  id_evenement_retrait_circuit_signature

Vérification des messages lors du suivi des dates d'un évènement télétransmissible
    [Documentation]  Ce test case à pour but de vérifier de vérifier les messages présent lors du suivi des dates à partir de l'interface de suivi

    Depuis la page d'accueil  admin  admin
    &{evenement} =  Create Dictionary
    ...  libelle=Notification du delai legal maison individuelle
    ...  teletransmissible=true
    Modifier l'événement  ${evenement}

    Ajouter le paramètre depuis le menu  id_evenement_envoi_circuit_signature  113  agglo
    Ajouter le paramètre depuis le menu  id_evenement_retrait_circuit_signature  114  agglo

    # ajoute le DI sur lequel la vérification sera effectuée
    &{args_petitionnaire} =  Create Dictionary
    ...  particulier_nom=TEST140TELETRNOM02
    ...  particulier_prenom=TEST140TELETRPRENOM02
    ...  om_collectivite=MARSEILLE
    &{args_demande} =  Create Dictionary
    ...  dossier_autorisation_type_detaille=DECLARATION PREALABLE SIMPLE
    ...  demande_type=Dépôt Initial
    ...  om_collectivite=MARSEILLE
    ${dossier_instruction_teletr_02} =  Ajouter la demande par WS  ${args_demande}  ${args_petitionnaire}

    # Constitution du dossier final
    Depuis le contexte du dossier d'instruction  ${dossier_instruction_teletr_02}
    &{document_numerise_values} =  Create Dictionary
    ...  uid_upload=testImportManuel.pdf
    ...  date_creation=15/09/2015
    ...  document_numerise_type=vues et coupes du projet dans le profil du terrain naturel
    Ajouter une pièce depuis le dossier d'instruction  ${dossier_instruction_teletr_02}  ${document_numerise_values}
    Click On Back Button In Subform
    Wait Until Keyword Succeeds  ${TIMEOUT}  ${RETRY_INTERVAL}  Click Element  link:Toutes les pièces
    Wait Until Keyword Succeeds  ${TIMEOUT}  ${RETRY_INTERVAL}  Element Should Be Visible  name:constituer_dossier_final
    Click Element  name:constituer_dossier_final
    Wait Until Keyword Succeeds  ${TIMEOUT}  ${RETRY_INTERVAL}  Message Should Contain  Le dossier final a bien été constitué.

    Depuis l'instruction du dossier d'instruction  ${dossier_instruction_teletr_02}  Notification du delai legal maison individuelle
    Click On SubForm Portlet Action  instruction  envoi_circuit_signature  modale
    Wait Until Keyword Succeeds  ${TIMEOUT}  ${RETRY_INTERVAL}  Click Element  css=.ui-dialog .ui-dialog-buttonset .ui-button-text-only

    # Vérification des messages en fonction du type de mise à jour
    Depuis l'instruction du dossier d'instruction  ${dossier_instruction_teletr_02}  Notification du delai legal maison individuelle
    ${instruction} =  Get Value  css=.form-content input#instruction
    ${code_barres} =  STR_PAD_LEFT  ${instruction}  10  0
    ${code_barres} =  Catenate  11${code_barres}
    Go To Submenu In Menu  suivi  suivi_mise_a_jour_des_dates
    Select From List By Value  css=#type_mise_a_jour  date_retour_signature
    Input Datepicker  date  ${date_ddmmyyyy}
    Input Text  css=#code_barres  ${code_barres}
    Wait Until Keyword Succeeds  ${TIMEOUT}  ${RETRY_INTERVAL}  Click Element  name:validation

    Wait Until Keyword Succeeds  ${TIMEOUT}  ${RETRY_INTERVAL}  Valid Message Should Contain  Le document va être télétransmis. Les champs "Date d'Envoi au Contrôle de Légalité" et "Date de Retour du Contrôle de Légalité" seront mises à jour automatiquement.
    Element Should Contain  lib-date_envoi_controle_legalite  Auto
    Element Should Contain  lib-date_retour_controle_legalite  Auto
    Click Element  name:validation
    Wait Until Keyword Succeeds  ${TIMEOUT}  ${RETRY_INTERVAL}  Valid Message Should Contain  Saisie enregistrée

    Select From List By Value  css=#type_mise_a_jour  date_retour_signature;date_envoi_controle_legalite
    Input Datepicker  date  ${date_ddmmyyyy}
    Input Text  css=#code_barres  ${code_barres}
    Wait Until Keyword Succeeds  ${TIMEOUT}  ${RETRY_INTERVAL}  Click Element  name:validation
    Wait Until Keyword Succeeds  ${TIMEOUT}  ${RETRY_INTERVAL}  Error Message Should Contain  Le document est éligible à la télétransmission. Les "Date d'Envoi au Contrôle de Légalité" et "Date de Retour du Contrôle de Légalité" seront mises à jour automatiquement.
    Element Should Contain  lib-date_envoi_controle_legalite  Auto
    Element Should Contain  lib-date_retour_controle_legalite  Auto
    Click On Back Button

    Select From List By Value  css=#type_mise_a_jour  date_envoi_controle_legalite
    Input Datepicker  date  ${date_ddmmyyyy}
    Input Text  css=#code_barres  ${code_barres}
    Wait Until Keyword Succeeds  ${TIMEOUT}  ${RETRY_INTERVAL}  Click Element  name:validation
    Wait Until Keyword Succeeds  ${TIMEOUT}  ${RETRY_INTERVAL}  Error Message Should Contain  Le document va être télétransmis. Vous ne pouvez pas mettre à jour la "Date d'Envoi au Contrôle de Légalité", qui le sera automatiquement, ainsi que la "Date de Retour du Contrôle de Légalité".
    Element Should Contain  lib-date_envoi_controle_legalite  Auto
    Element Should Contain  lib-date_retour_controle_legalite  Auto
    Click On Back Button

    Select From List By Value  css=#type_mise_a_jour  date_retour_controle_legalite
    Input Datepicker  date  ${date_ddmmyyyy}
    Input Text  css=#code_barres  ${code_barres}
    Wait Until Keyword Succeeds  ${TIMEOUT}  ${RETRY_INTERVAL}  Click Element  name:validation
    Wait Until Keyword Succeeds  ${TIMEOUT}  ${RETRY_INTERVAL}  Error Message Should Contain  Le document va être télétransmis. Vous ne pouvez pas mettre à jour la "Date d'Envoi au Contrôle de Légalité", qui le sera automatiquement, ainsi que la "Date de Retour du Contrôle de Légalité".
    Element Should Contain  lib-date_envoi_controle_legalite  Auto
    Element Should Contain  lib-date_retour_controle_legalite  Auto

    Depuis la page d'accueil  admin  admin
    # On remet l'évènement en non télétransmissible
    &{evenement} =  Create Dictionary
    ...  libelle=Notification du delai legal maison individuelle
    ...  teletransmissible=false
    Modifier l'événement  ${evenement}
    # On supprime les paramètre d'id d'évènement
    Supprimer le paramètre  id_evenement_envoi_circuit_signature
    Supprimer le paramètre  id_evenement_retrait_circuit_signature

Vérification du bon fonctionnement de l'interface de suivi de la télétransmission au contrôle de légalité
    [Documentation]  Ce tests a pour but de vérifier le bon fonctionnement de l'interface de suivi de la télétransmission au cdl

    Depuis la page d'accueil  admin  admin
    &{evenement} =  Create Dictionary
    ...  libelle=Notification du delai legal maison individuelle
    ...  teletransmissible=true
    Modifier l'événement  ${evenement}

    Ajouter le paramètre depuis le menu  id_evenement_envoi_circuit_signature  113  agglo
    Ajouter le paramètre depuis le menu  id_evenement_retrait_circuit_signature  114  agglo

    # ajoute le DI sur lequel la vérification sera effectuée
    &{args_petitionnaire} =  Create Dictionary
    ...  particulier_nom=TEST140TELETRNOM03
    ...  particulier_prenom=TEST140TELETRPRENOM03
    ...  om_collectivite=MARSEILLE
    &{args_demande} =  Create Dictionary
    ...  dossier_autorisation_type_detaille=DECLARATION PREALABLE SIMPLE
    ...  demande_type=Dépôt Initial
    ...  om_collectivite=MARSEILLE
    ${dossier_instruction_teletr_03} =  Ajouter la demande par WS  ${args_demande}  ${args_petitionnaire}

    # Constitution du dossier final
    Depuis le contexte du dossier d'instruction  ${dossier_instruction_teletr_03}
    &{document_numerise_values} =  Create Dictionary
    ...  uid_upload=testImportManuel.pdf
    ...  date_creation=15/09/2015
    ...  document_numerise_type=vues et coupes du projet dans le profil du terrain naturel
    Ajouter une pièce depuis le dossier d'instruction  ${dossier_instruction_teletr_03}  ${document_numerise_values}
    Click On Back Button In Subform
    Wait Until Keyword Succeeds  ${TIMEOUT}  ${RETRY_INTERVAL}  Click Element  link:Toutes les pièces
    Wait Until Keyword Succeeds  ${TIMEOUT}  ${RETRY_INTERVAL}  Element Should Be Visible  name:constituer_dossier_final
    Click Element  name:constituer_dossier_final
    Wait Until Keyword Succeeds  ${TIMEOUT}  ${RETRY_INTERVAL}  Message Should Contain  Le dossier final a bien été constitué.

    # On envoie le dossier en circuit signature
    Depuis l'instruction du dossier d'instruction  ${dossier_instruction_teletr_03}  Notification du delai legal maison individuelle
    Click On SubForm Portlet Action  instruction  envoi_circuit_signature  modale
    Wait Until Keyword Succeeds  ${TIMEOUT}  ${RETRY_INTERVAL}  Click Element  css=.ui-dialog .ui-dialog-buttonset .ui-button-text-only

    # On ajoute la date de retour signature pour vérouiller le dossier
    Depuis l'instruction du dossier d'instruction  ${dossier_instruction_teletr_03}  Notification du delai legal maison individuelle
    Click On SubForm Portlet Action  instruction  modifier_suivi
    Input Datepicker  date_retour_signature  ${date_ddmmyyyy}
    Click On Submit Button In Subform

    # On accède à l'interface de suivi de la télétransmission au cdl
    ${dossier_instruction_teletr_03_sans_espace} =  Sans Espace  ${dossier_instruction_teletr_03}
    Go To Submenu In Menu  suivi  teletransmission
    Input Text  css=#dossier  ${dossier_instruction_teletr_03_sans_espace}
    Click Element  name:advanced-search-submit

    # On vérifie que notre dossier apparaît bien dans le listing et que son status est A télétransmettre
    Element Should Contain  css=td.col-0  ${dossier_instruction_teletr_03_sans_espace}
    Element Should Contain  css=td.col-1  ${date_ddmmyyyy}
    Element Should Contain  css=td.col-4  notifier
    Element Should Contain  css=td.col-5  A télétransmettre

    Depuis la page d'accueil  admin  admin
    # On remet l'évènement en non télétransmissible
    &{evenement} =  Create Dictionary
    ...  libelle=Notification du delai legal maison individuelle
    ...  teletransmissible=false
    Modifier l'événement  ${evenement}
    # On supprime les paramètre d'id d'évènement
    Supprimer le paramètre  id_evenement_envoi_circuit_signature
    Supprimer le paramètre  id_evenement_retrait_circuit_signature