*** Settings ***
Documentation    CRUD de la table instruction_notification
...    @author  generated
...    @package openADS
...    @version 18/11/2021 16:11

*** Keywords ***

Recuperer les cles dans le mail de notification
    [Documentation]  Recupere sous la forme d'une liste toutes les cles
    ...  presente dans le mail de notification à l'aide d'une regex.

    ${msg} =  Get Text  //body
    ${key_regex} =  Set Variable  [a-z0-9]{8}-[a-z0-9]{4}-[a-z0-9]{4}-[a-z0-9]{4}-[a-z0-9]{12}
    ${keys} =  Get Regexp Matches  ${msg}  ${key_regex}
    [Return]  ${keys}

Verifier que le lien de notification contiens
    [Documentation]  Utilise la clé fournit pour composer le lien. Ouvre la page du lien
    ...  puis cherche le texte voulu dans cette page.
    [Arguments]  ${cle}  ${text}  ${email}

    Go To  ${PROJECT_URL}/web/notification.php?key=${cle}

    Input Text  email  ${email}

    Click On Submit Button

    Wait Until Page Contains  ${text}

Verifier le mail de notification, son contenu et ses documents annexes
    [Documentation]  Vérifie sur la boite mail de test que le destinataire a bien
    ...  reçu un mail. Accède a ce mail et vérifie que le contenu est bien celui
    ...  attendu. Récupère les clés d'accès aux documents dans le mail et pour
    ...  chaque clé vérifie que le document contiens bien le texte voulu issus
    ...  de la liste de contenus du document passée en argument.
    ...  /!\ liste_contenus_document doit avoir autant d'élement que de clé
    ...      d'accès au document sinon le keyword fail
    [Arguments]  ${destinataire}  ${contenu}  ${liste_contenus_document}

    Verifier que le mail a bien été envoyé au destinataire  ${destinataire}
    Vérifier le contenu du mail  ${destinataire}  ${contenu}
    ${cles} =  Recuperer les cles dans le mail de notification
    ${nombre_cles} =  Get length  ${cles}
    :FOR  ${i}  IN RANGE  ${nombre_cles}
    \  Verifier que le lien de notification contiens  ${cles[${i}]}  ${liste_contenus_document[${i}]}  ${destinataire}