*** Settings ***
Documentation  Test les instructions

# On inclut les mots-clefs
Resource  resource.txt
# On ouvre/ferme le navigateur au début/à la fin du Test Suite.
Suite Setup  For Suite Setup
Suite Teardown  For Suite Teardown
# A chaque début de Test Case on se positionne sur le tableau bord administrateur
Test Setup  Depuis la page d'accueil  admin  admin

*** Variables ***

${json_consultation}  {"module":"consultation"}

*** Test Cases ***
Création du jeu de données

    [Documentation]  Constitue le jeu de données.

    Depuis la page d'accueil  guichet  guichet
    #
    ${di} =  Ajouter La Nouvelle Demande Depuis Le Tableau De Bord  Permis de construire pour une maison individuelle et / ou ses annexes  Dépôt Initial  personne morale  null  null  null  Bati&Co  null  Monsieur  Leroy  Georges
    #
    Set Suite Variable  ${di}
    #
    Depuis la page d'accueil  admin  admin
    #
    Modifier l'état  11  null  null  null  null  null  null  null  null  null  null  null  null  null  null  null  [nom_petitionnaire_principal]
    #
    Ajouter la consultation depuis le contexte du dossier d'instruction  ${di}  Atelier du Patrimoine


Vérification de l'édition de la consulation

    [Documentation]  Vérifie l'affichage des champs de fusion sur une
    ...  consultation.

    Depuis le contexte de la consultation  ${di}  Atelier du Patrimoine
    # On clique sur l'action édition
    Click On SubForm Portlet Action  consultation  pdfetat
    # On ouvre le PDF
    Open PDF  file
    # On vérifie le champ de fusion
    Wait Until Keyword Succeeds  5 sec  0.2 sec  Page Should Contain  Bati&Co représenté par Monsieur Leroy Georges
    # On ferme le PDF
    Close PDF


TNR Routine de mise à jour des consultations tacites

    [Documentation]  Permet de vérifie l'état des consultations après le
    ...  traitement tacite.

    #
    Vérifier le code retour du web service et vérifier que son message est  Post  maintenance  ${json_consultation}  200  2 consultations mise(s) à jour.
    #
    Depuis la page d'accueil  instr  instr
    # On vérifie que le widget à bien notifié l'instructeur
    Page Should Contain  Vous avez 1 consultation pour laquelle un avis a été rendu.
    # On clique pour voir la liste des consultations depuis le widget
    Click On Link  Voir mes retours de consultation
    # On clique sur le dossier en question
    Click On Link  PC 013055 12 00002P0
    # On vérifie que les champs ont bien été mis à jour par le webservice
    Wait Until Keyword Succeeds  5 sec  0.2 sec  Form Static Value Should Be  css=#lu  Non
    Form Static Value Should Be  css=#avis_consultation  Tacite
    Form Static Value Should Be  css=#date_retour  01/02/2013


TNR Vérifie que le fichier est supprimé à la suppression de la consultation

    [Documentation]  Vérifie dans le filestorage si le fichier de l'édition de
    ...  la consultation est correctement supprimé lors de la suppression de la
    ...  consultation.

    #
    Ajouter la consultation depuis le contexte du dossier d'instruction  ${di}  AUTRE
    # Récupération de l'UID
    Depuis le contexte de la consultation  ${di}  AUTRE
    ${uid} =  Get Value  om_fichier_consultation
    ${path_1} =  Get Substring  ${uid}  0  2
    ${path_2} =  Get Substring  ${uid}  0  4
    # Vérification dans le filestorage
    File Should Exist  ..${/}trs${/}1${/}${path_1}${/}${path_2}${/}${uid}
    File Should Exist  ..${/}trs${/}1${/}${path_1}${/}${path_2}${/}${uid}.info
    #
    Depuis le contexte de la consultation  ${di}  AUTRE
    # On clique sur l'action de définalisation
    Wait Until Keyword Succeeds  5 sec  0.2 sec  Click On SubForm Portlet Action  consultation  definalisation
    # On vérifie le message de validation
    Wait Until Keyword Succeeds  5 sec  0.2 sec  Valid Message Should Be  La definalisation du document s'est effectuée avec succès.
    #
    Supprimer la consultation depuis le contexte du dossier d'instruction  ${di}  AUTRE
    # Vérification dans le filestorage
    File Should Not Exist  ..${/}trs${/}1${/}${path_1}${/}${path_2}${/}${uid}
    File Should Not Exist  ..${/}trs${/}1${/}${path_1}${/}${path_2}${/}${uid}.info