*** Settings ***
Documentation  Test les instructions

# On inclut les mots-clefs
Resource  resource.txt
# On ouvre/ferme le navigateur au début/à la fin du Test Suite.
Suite Setup  For Suite Setup
Suite Teardown  For Suite Teardown
# A chaque début de Test Case on se positionne sur le tableau bord administrateur
Test Setup  Depuis la page d'accueil  admin  admin

*** Test Cases ***
Création du jeu de données

    [Documentation]  Constitue le jeu de données.

    Ajouter le pétitionnaire fréquent  null  Monsieur  Dubois  Jean  null  null  null  null  null  null  true
    Ajouter le pétitionnaire fréquent  null  Madame  Dubois  Mireille  null  null  null  null  null  null  true


Rechercher le pétitionnaire fréquent

    [Documentation]  Lors de l'ajout d'une demande, rechercher un pétitionnaire
    ...  fréquent.

    Depuis la page d'accueil  guichet  guichet
    Depuis le contexte de nouvelle demande via le tableau de bord
    # On sélectionne le type de dossier d'autorisation détaillé
    Select From List By Label  dossier_autorisation_type_detaille  Permis de construire pour une maison individuelle et / ou ses annexes
    # On sélectionne le type de demande
    Wait Until Keyword Succeeds  5 sec  0.2 sec  Select From List By Label  demande_type  Dépôt Initial
    # On ajoute le pétitionnaire principal
    Wait Until Keyword Succeeds  5 sec  0.2 sec  Click Element  add_petitionnaire_principal
    # On saisit les 3 premières lettres du nom
    Wait Until Keyword Succeeds  5 sec  0.2 sec  Input Text  particulier_nom  Dub*
    # On clique sur le bouton de recherche
    Click Element  css=.search-frequent-16
    # On vérifie la liste des éléments disponibles
    ${list} =  Create List  Dubois Jean  Dubois Mireille
    Wait Until Keyword Succeeds  5 sec  0.2 sec  Select List Should Be  css=#select-petitionnaire  ${list}
    # On sélectionne un pétitionnaire
    Select From List By Label  css=#select-petitionnaire  Dubois Jean
    # On clique sur le bouton de validation
    Click Button    css=div.dialog-search-frequent-petitionnaire div.ui-dialog-buttonpane button.ui-button
    # On vérifie que la page ne contient pas d'erreur
    Page Should Not Contain Errors
    # On quitte le formulaire
    Click On Back Button In Subform
    # On vérifie le pétionnaire
    Page Should Contain  Monsieur Dubois Jean


Vérification du répertoire du dossier dans TODO

    [Documentation]  Vérifie la date de modification du répertoire créée à la
    ...  demande, celui-ci est modifié si une nouvelle demande est faite sur le
    ...  même dossier.

    #
    Depuis la page d'accueil  guichet  guichet
    #
    ${dossier_instruction} =  Ajouter La Nouvelle Demande Depuis Le Tableau De Bord  Permis de construire pour une maison individuelle et / ou ses annexes  Dépôt Initial  null  Monsieur  Louis  Daniel
    # On récupère le libellé du répertoire
    ${libelle_sans_espace} =  Sans espace  ${dossier_instruction}
    ${libelle_directory} =  Replace String  ${libelle_sans_espace}  P0  .P0
    # On récupère la date de dernière modification du répertoire
    ${create_time} =   Get Modified Time   ..${/}trs${/}numerisation${/}Todo${/}${libelle_directory}
    #
    Ajouter la demande sur existant sans créer de dossier d'instruction depuis le tableau de bord  ${dossier_instruction}  Dépot de pièces supplémentaires PI
    # On récupère la date de dernière modification du répertoire
    ${modify_time} =   Get Modified Time   ..${/}trs${/}numerisation${/}Todo${/}${libelle_directory}
    # Les dates ne devrait pas être égale
    Should Not Be Equal  ${create_time}  ${modify_time}