*** Settings ***
Documentation  Teste l'import spécifique de fichiers CSV

# On inclut les mots-clefs
Resource  resources/resources.robot
Test Teardown    Run Keyword If Test Failed    Capture Page Screenshot
# On ouvre/ferme le navigateur au début/à la fin du Test Suite.
Suite Setup  For Suite Setup
Suite Teardown  For Suite Teardown


*** Test Case ***
Ouvre le formulaire de l'import spécifique ADS2007 depuis le menu

    [Documentation]  Ce test case permet de vérifier que le formulaire d'import
    ...  spécifique des dossiers sous le format ADS2007, est accessible depuis
    ...  le menu

    Depuis la page d'accueil    admin    admin
    Go To Submenu In Menu  administration  import_specific
    Click Element  id=action-import-ads2007-importer
    La page ne doit pas contenir d'erreur
    Page Should Not Contain  objet est invalide


Import avec succès de dossiers ADS 2007
    [Documentation]  Ce test case permet de vérifier que l'import ads2007
    ...  fonctionne correctement
    ...  Vérifie également que les dossiers sont correctements affichés
    ...  dans les listings.
    #
    Depuis la page d'accueil    admin    admin
    # Ajout d'une collectivité avec une lettre dans son code insee
    Gerer la collectivité par WS avec paramètres  COLL_TEST_LETTRE  mono
    &{param_division} =  Create Dictionary
    ...  libelle=insee
    ...  valeur=2B000
    ...  om_collectivite=COLL_TEST_LETTRE
    Gerer le paramètre par WS  ${param_division}
    # On importe les dossiers
    Depuis l'import spécifique    ads2007
    Add File    fic1    import_specific_success_ads2007.csv
    Click On Submit Button In Import CSV
    # On vérifie le résultat
    Résultat de l'import doit contenir  5 ligne(s) dans le fichier dont :
    Résultat de l'import doit contenir  - 1 ligne(s) d'entête
    Résultat de l'import doit contenir  - 4 ligne(s) importée(s)

    Le dossier d'instruction doit exister  PD 044185 07 R0013
    Le dossier d'instruction doit exister  PA 044185 08 R0051
    Le dossier d'instruction doit exister  PA 044185 08 R0051M01

    # Vérifie que les dossiers sont correctements affichés dans les listings
    Go To Submenu In Menu  guichet_unique  autre-dossier
    Wait Until Page Contains Element  css=#adv-search-classic-fields input
    Input Text  css=#adv-search-classic-fields input  PD04418507R0013
    Click On Search Button
    Wait Until Element Contains  css=#tab-demande_autre_dossier table.tab-tab  PD 044185 07 R0013

    Wait Until Page Contains Element  css=#adv-search-classic-fields input
    Input Text  css=#adv-search-classic-fields input  PA04418508R0051
    Click On Search Button
    Wait Until Element Contains  css=#tab-demande_autre_dossier table.tab-tab  PA 044185 08 R0051

    Wait Until Page Contains Element  css=#adv-search-classic-fields input
    Input Text  css=#adv-search-classic-fields input  PA04418508R0051M01
    Click On Search Button
    Wait Until Element Contains  css=#tab-demande_autre_dossier table.tab-tab  PA 044185 08 R0051M01


    Go To Submenu In Menu  instruction  dossier_instruction_recherche
    Input Text  css=div#adv-search-adv-fields input#dossier  PD04418507R0013
    Click On Search Button
    Wait Until Element Contains  css=#tab-dossier_instruction table.tab-tab  PD 044185 07 R0013

    Input Text  css=div#adv-search-adv-fields input#dossier  PA04418508R0051
    Click On Search Button
    Wait Until Element Contains  css=#tab-dossier_instruction table.tab-tab  PA 044185 08 R0051

    Input Text  css=div#adv-search-adv-fields input#dossier  PA04418508R0051M01
    Click On Search Button
    Wait Until Element Contains  css=#tab-dossier_instruction table.tab-tab  PA 044185 08 R0051M01

    # Attention : suite au modif de code une ligne du csv ne fonctionne plus
    # lors de l'import car ce cas n'est plus géré (ligne pour tester un PCI)
    # A la place c'est un PA qui est testé. A voir si elle devra être remise plus tard
    Depuis le contexte du dossier d'autorisation  PA 044185 13 R0077
    Element Should Contain  da_description_projet  TEST IMPORT SPECIFIQUE DI INITIAL
    Element Should Contain  depot_initial  11/03/2013
    Element Should Contain  date_depot_DOC  20/06/2013
    Element Should Contain  date_depot_DAACT  21/06/2013
    Depuis le contexte du dossier d'instruction  PA 044185 13 R0077
    Page Should Contain  COLL_TEST_LETTRE
    # TODO : ajouter  la vérification des adresses des dossiers

    # On désactive le suffixe P0 pour les permit de démolir initiaux puis on
    # réimporte les dossiers afin de vérifier que le PD a bien été mis à jour
    # et qu'un autre sans P0 n'a pas été créé
    Depuis le listing  dossier_instruction_type
    Use Simple Search   type de dossier d'autorisation détaillé  PD (Permis de démolir)
    Click On Link  Initial
    Click On Form Portlet Action  dossier_instruction_type  modifier
    Unselect Checkbox  suffixe
    Click On Submit Button
    # On importe les dossiers
    Depuis l'import spécifique    ads2007
    Add File    fic1    import_specific_modif_ads2007.csv
    Click On Submit Button In Import CSV
    # On vérifie le résultat
    Résultat de l'import doit contenir  3 ligne(s) dans le fichier dont :
    Résultat de l'import doit contenir  - 1 ligne(s) d'entête
    Résultat de l'import doit contenir  - 2 ligne(s) importée(s)

    # On vérifie qu'un nouveau dossier n'a pas été créé
    Le dossier d'instruction ne doit pas exister  PD 044185 07 R0013P0

    # On vérifie que le bon dossier a été mis à jour
    Depuis le contexte du dossier d'instruction    PD 044185 07 R0013
    Wait Until Keyword Succeeds  ${TIMEOUT}  ${RETRY_INTERVAL}  Element Should Contain  css=#date_depot  29/06/2008

    # Vérifie la description du projet, la date de DOC et de DAACT du DA
    # Ils doivent être modifié par le modificatif
    # La date de dépôt initial ne doit pas être modifié
    Le dossier d'instruction doit exister  PA 044185 13 R0077M01
    Depuis le contexte du dossier d'autorisation  PA 044185 13 R0077
    Element Should Contain  da_description_projet  TEST IMPORT SPECIFIQUE DI MODIFICATIF
    Element Should Contain  depot_initial  11/03/2013
    Element Should Contain  date_depot_DOC  26/06/2013
    Element Should Contain  date_depot_DAACT  27/06/2013

    # On remet le sufixe au dossiers initiaux PD
    Depuis le listing  dossier_instruction_type
    Use Simple Search   type de dossier d'autorisation détaillé  PD (Permis de démolir)
    Click On Link  Initial
    Click On Form Portlet Action  dossier_instruction_type  modifier
    Select Checkbox  suffixe
    Click On Submit Button

Rejet lors de l'import de dossiers ADS 2007
    #
    Depuis la page d'accueil    admin    admin
    # On importe l'établissement
    Depuis l'import spécifique    ads2007
    Add File    fic1    import_specific_fail_ads2007.csv
    Click On Submit Button In Import CSV
    # On vérifie le résultat
    Résultat de l'import doit contenir  7 ligne(s) dans le fichier dont :
    Résultat de l'import doit contenir  - 1 ligne(s) d'entête
    Résultat de l'import doit contenir  - 1 ligne(s) importée(s)
    Résultat de l'import doit contenir  - 4 ligne(s) rejetée(s)

Import spécifique de communes
    [Documentation]  On vérifie que l'import spécifique de communes fonctionne

    Depuis la page d'accueil  admin  admin

    # isole le contexte du test (création d'une collectivité)
    &{isolation_values} =  Create Dictionary
    ...  om_collectivite_libelle=LIBRECOM1
    ...  departement=013
    ...  commune=098
    ...  insee=13098
    ...  direction_code=W40
    ...  direction_libelle=Direction de LIBRECOM1
    ...  direction_chef=Chef
    ...  division_code=W40
    ...  division_libelle=Division W40
    ...  division_chef=Chef
    ...  guichet_om_utilisateur_nom=Gregory Dumoulin
    ...  guichet_om_utilisateur_email=gregorydumoulin@openads-test.fr
    ...  guichet_om_utilisateur_login=gdumoulin
    ...  guichet_om_utilisateur_pwd=gdumoulin
    ...  instr_om_utilisateur_nom=Madeleine Dubeau
    ...  instr_om_utilisateur_email=madeleinedubeau@openads-test.fr
    ...  instr_om_utilisateur_login=mdubeau
    ...  instr_om_utilisateur_pwd=mdubeau
    Isolation d'un contexte  ${isolation_values}

    # va sur la page d'import spécifique de communes
    Depuis l'import spécifique   commune

    # téléverse le fichier CSV des communes à importer
    ${import_communes_file} =  Set Variable  import_specific_communes_ok.csv
    Add File  fic1  ${import_communes_file}
    Click On Submit Button In Import CSV

    # vérifie que l'opération est un succès
    Résultat de l'import doit contenir  41 ligne(s) dans le fichier dont :
    Résultat de l'import doit contenir  - 1 ligne(s) d'entête
    Résultat de l'import doit contenir  - 39 ligne(s) insérée(s)
    Résultat de l'import doit contenir  - 0 ligne(s) rejetée(s)
    Résultat de l'import doit contenir  - 1 ligne(s) vide(s)

TNR erreur de base de données sur l'import ads2007 si le type du DI n'existe pas
    [Documentation]  On vérifie que l'import ads2007 ne provoque pas d'erreur de base de donnée
    ...  si le type du DI n'existe pas. La ligne doit simplement être rejetée.

    Depuis la page d'accueil  admin  admin

    # isole le contexte du test (création d'une collectivité)
    &{isolation_values} =  Create Dictionary
    ...  om_collectivite_libelle=TNRADS2007
    ...  departement=042
    ...  commune=024
    ...  insee=42024
    ...  direction_code=TNRADS2007
    ...  direction_libelle=Direction de TNRADS2007
    ...  direction_chef=Chef
    ...  division_code=TNRADS2007
    ...  division_libelle=Division TNRADS2007
    ...  division_chef=Chef
    ...  guichet_om_utilisateur_nom=Mason Laprise
    ...  guichet_om_utilisateur_email=mlaprise@openads-test.fr
    ...  guichet_om_utilisateur_login=mlaprise
    ...  guichet_om_utilisateur_pwd=mlaprise
    ...  instr_om_utilisateur_nom=Victorine Nadeau
    ...  instr_om_utilisateur_email=vnadeau@openads-test.fr
    ...  instr_om_utilisateur_login=vnadeau
    ...  instr_om_utilisateur_pwd=vnadeau
    Isolation d'un contexte  ${isolation_values}

    # va sur la page d'import spécifique de communes
    Depuis l'import spécifique   ads2007

    # téléverse le fichier CSV des communes à importer
    ${import_communes_file} =  Set Variable  import_specific_tnr_ads2007.csv
    Add File  fic1  ${import_communes_file}
    Click On Submit Button In Import CSV

    # vérifie que l'opération est un succès
    Résultat de l'import doit contenir  3 ligne(s) dans le fichier dont :
    Résultat de l'import doit contenir  - 1 ligne(s) d'entête
    Résultat de l'import doit contenir  - 0 ligne(s) importée(s)
    Résultat de l'import doit contenir  - 1 ligne(s) rejetée(s)
    Résultat de l'import doit contenir  - 1 ligne(s) vide(s)

    La page ne doit pas contenir d'erreur

Ouvre le formulaire de l'import spécifique des utilisateurs de tiers consultés depuis le menu

    [Documentation]  Ce test case permet de vérifier que le formulaire d'import
    ...  spécifique des utilisateurs de tiers consultés, est accessible depuis
    ...  le menu

    Depuis la page d'accueil    admin    admin
    Go To Submenu In Menu  administration  import_specific
    Click Element  id=action-import-om_utilisateur_tiers-importer
    La page ne doit pas contenir d'erreur
    Page Should Not Contain  objet est invalide

Import spécifique des utilisateurs de tiers consultés

    [Documentation]  Ce test case permet de vérifier que l'import om_utilisateur_tiers
    ...  fonctionne correctement.
    #

    Depuis la page d'accueil    admin    admin

    # --- Infrastructure : département, communes, type habilitation ---

    &{dept_values} =  Create Dictionary
    ...  dep=40
    ...  reg=40
    ...  cheflieu=40040
    ...  tncc=0
    ...  ncc=DEPT_TC040
    ...  nccenr=DEPT_TC040
    ...  libelle=DEPT_TC040
    ...  om_validite_debut=01/01/2023
    Ajouter département  ${dept_values}

    &{com1} =  Create Dictionary
    ...  typecom=COM
    ...  com=40040
    ...  reg=40
    ...  dep=40
    ...  arr=400
    ...  tncc=0
    ...  ncc=SAINTAGATHON
    ...  nccenr=Saint-Agathon
    ...  libelle=Saint-Agathon
    ...  can=40
    ...  om_validite_debut=01/01/2023
    Ajouter commune avec dates validité  ${com1}

    &{com2} =  Create Dictionary
    ...  typecom=COM
    ...  com=40041
    ...  reg=40
    ...  dep=40
    ...  arr=401
    ...  tncc=0
    ...  ncc=RENNES
    ...  nccenr=Rennes
    ...  libelle=Rennes
    ...  can=40
    ...  om_validite_debut=01/01/2023
    Ajouter commune avec dates validité  ${com2}

    &{com3} =  Create Dictionary
    ...  typecom=COM
    ...  com=40042
    ...  reg=40
    ...  dep=40
    ...  arr=402
    ...  tncc=0
    ...  ncc=VANNES
    ...  nccenr=Vannes
    ...  libelle=Vannes
    ...  can=40
    ...  om_validite_debut=01/01/2023
    Ajouter commune avec dates validité  ${com3}

    &{type_hab} =  Create Dictionary
    ...  code=TYPE040
    ...  libelle=Type hab 040
    ...  om_validite_debut=01/01/2023
    Ajouter un type d'habilitation de tiers consulté  ${type_hab}

    # --- Création d'une catégorie de tiers consultés ---

    &{cat_values} =  Create Dictionary
    ...  code=CAT040
    ...  description=Catégorie TC test 040
    ...  libelle=Catégorie TC 040
    Ajouter la categorie de tiers consulte  ${cat_values}

    # --- Création des 3 tiers consultés avec habilitations ---

    &{tc1} =  Create Dictionary
    ...  categorie_tiers_consulte=Catégorie TC 040
    ...  abrege=22TC040A
    ...  libelle=TC Test Saint-Agathon
    ...  ville=Saint-Agathon
    ...  liste_diffusion=tc040a@test.fr
    ${id_tc_1} =  Ajouter le tiers consulte depuis le listing  ${tc1}
    @{com_hab_1} =  Create List  ${com1.com} - ${com1.libelle}
    &{hab1} =  Create Dictionary
    ...  type_habilitation_tiers_consulte=Type hab 040
    ...  tiers_consulte=TC Test Saint-Agathon
    ...  om_validite_debut=01/01/2023
    ...  om_validite_fin=31/12/2099
    Ajouter une habilitation de tiers consulté  ${hab1}  ${EMPTY}  ${com_hab_1}

    &{tc2} =  Create Dictionary
    ...  categorie_tiers_consulte=Catégorie TC 040
    ...  abrege=35TC040B
    ...  libelle=TC Test Rennes
    ...  ville=Rennes
    ...  liste_diffusion=tc040b@test.fr
    ${id_tc_2} =  Ajouter le tiers consulte depuis le listing  ${tc2}
    @{com_hab_2} =  Create List  ${com2.com} - ${com2.libelle}
    &{hab2} =  Create Dictionary
    ...  type_habilitation_tiers_consulte=Type hab 040
    ...  tiers_consulte=TC Test Rennes
    ...  om_validite_debut=01/01/2023
    ...  om_validite_fin=31/12/2099
    Ajouter une habilitation de tiers consulté  ${hab2}  ${EMPTY}  ${com_hab_2}

    &{tc3} =  Create Dictionary
    ...  categorie_tiers_consulte=Catégorie TC 040
    ...  abrege=56TC040C
    ...  libelle=TC Test Vannes
    ...  ville=Vannes
    ...  liste_diffusion=tc040c@test.fr
    ${id_tc_3} =  Ajouter le tiers consulte depuis le listing  ${tc3}
    @{com_hab_3} =  Create List  ${com3.com} - ${com3.libelle}
    &{hab3} =  Create Dictionary
    ...  type_habilitation_tiers_consulte=Type hab 040
    ...  tiers_consulte=TC Test Vannes
    ...  om_validite_debut=01/01/2023
    ...  om_validite_fin=31/12/2099
    Ajouter une habilitation de tiers consulté  ${hab3}  ${EMPTY}  ${com_hab_3}

    # --- Export des tiers consultés ---

    Depuis le listing  tiers_consulte
    ${link} =  Get Element Attribute  css=div.tab-export a  href
    ${output_dir}  ${output_name} =  Télécharger un fichier
    ...  ${SESSION_COOKIE}  ${link}  ${EXECDIR}${/}binary_files${/}

    # --- Import des utilisateurs depuis le fichier exporté ---

    Depuis l'import spécifique  om_utilisateur_tiers
    Add File  fic1  ${output_name}
    Click On Submit Button In Import CSV

    # --- Vérification du résultat de l'import ---

    La page ne doit pas contenir d'erreur
    Résultat de l'import doit contenir  3 ligne(s) correcte(s)
    Résultat de l'import doit contenir  0 ligne(s) rejetée(s)

    # --- Vérification des utilisateurs créés et du profil par défaut ---

    Depuis le contexte de l'utilisateur  22saint-agathon
    La page ne doit pas contenir d'erreur
    Form Static Value Should Be  css=#om_profil  SERVICE CONSULTÉ
    On clique sur l'onglet  lien_om_utilisateur_tiers_consulte  Lien Utilisateur / Tiers
    Page Should Contain  TC Test Saint-Agathon

    Depuis le contexte de l'utilisateur  35rennes
    La page ne doit pas contenir d'erreur
    Form Static Value Should Be  css=#om_profil  SERVICE CONSULTÉ
    On clique sur l'onglet  lien_om_utilisateur_tiers_consulte  Lien Utilisateur / Tiers
    Page Should Contain  TC Test Rennes

    Depuis le contexte de l'utilisateur  56vannes
    La page ne doit pas contenir d'erreur
    Form Static Value Should Be  css=#om_profil  SERVICE CONSULTÉ
    On clique sur l'onglet  lien_om_utilisateur_tiers_consulte  Lien Utilisateur / Tiers
    Page Should Contain  TC Test Vannes

    # --- Vérification du profil personnalisé (colonne profil_tiers) ---

    &{tc4} =  Create Dictionary
    ...  categorie_tiers_consulte=Catégorie TC 040
    ...  abrege=29TC040D
    ...  libelle=TC Test Quimper
    ...  ville=Quimper
    ...  liste_diffusion=tc040d@test.fr
    ${id_tc_4} =  Ajouter le tiers consulte depuis le listing  ${tc4}

    ${csv_header} =  Catenate  SEPARATOR=;
    ...  tiers  abrege  libelle_tiers  adresse  complement  cp  ville
    ...  liste_diffusion  accepte_notification_mail  identifiant_acteur_plateforme
    ...  utilisateur  categorie_tiers  libelle_categorie_tiers  code  description
    ...  date_debut_validite_categorie  date_fin_validite_categorie  service
    ...  type_habilitation_tiers  libelle_type_habilitation_tiers  texte_agrement
    ...  identifiant_commune  commune  identifiant_departement  departement
    ...  division_territoriales  date_debut_validite_habilitation
    ...  date_fin_validite_habilitation  specialite_tiers  profil_tiers
    ${csv_data} =  Catenate  SEPARATOR=;
    ...  ${id_tc_4}  29TC040D  ${EMPTY}  ${EMPTY}  ${EMPTY}  ${EMPTY}  ${EMPTY}
    ...  tc040d@test.fr  ${EMPTY}  ${EMPTY}  ${EMPTY}  ${EMPTY}  ${EMPTY}  ${EMPTY}
    ...  ${EMPTY}  ${EMPTY}  ${EMPTY}  ${EMPTY}  ${EMPTY}  ${EMPTY}  ${EMPTY}
    ...  ${EMPTY}  Saint-Agathon  ${EMPTY}  ${EMPTY}  ${EMPTY}  ${EMPTY}  ${EMPTY}
    ...  ${EMPTY}  INSTRUCTEUR
    Create File  ${EXECDIR}${/}binary_files${/}import_profil_custom.csv  ${csv_header}\n${csv_data}\n

    Depuis l'import spécifique  om_utilisateur_tiers
    Add File  fic1  import_profil_custom.csv
    Click On Submit Button In Import CSV

    La page ne doit pas contenir d'erreur
    Résultat de l'import doit contenir  1 ligne(s) correcte(s)
    Résultat de l'import doit contenir  0 ligne(s) rejetée(s)

    Depuis le contexte de l'utilisateur  29saint-agathon
    La page ne doit pas contenir d'erreur
    Form Static Value Should Be  css=#om_profil  INSTRUCTEUR
    On clique sur l'onglet  lien_om_utilisateur_tiers_consulte  Lien Utilisateur / Tiers
    Page Should Contain  TC Test Quimper

    [TearDown]  Run Keywords  No Operation
    ...    AND  Run Keyword If Test Failed    Capture Page Screenshot
    ...    AND  Supprimer Lien Utilisateur / Tiers Consulté  ${id_tc_4}
    ...    AND  Supprimer Lien Utilisateur / Tiers Consulté  ${id_tc_3}
    ...    AND  Supprimer Lien Utilisateur / Tiers Consulté  ${id_tc_2}
    ...    AND  Supprimer Lien Utilisateur / Tiers Consulté  ${id_tc_1}
    ...    AND  Supprimer une habilitation de tiers consulté  ${id_tc_3}
    ...    AND  Supprimer une habilitation de tiers consulté  ${id_tc_2}
    ...    AND  Supprimer une habilitation de tiers consulté  ${id_tc_1}
    ...    AND  Supprimer le tiers consulte  ${id_tc_4}
    ...    AND  Supprimer le tiers consulte  ${id_tc_3}
    ...    AND  Supprimer le tiers consulte  ${id_tc_2}
    ...    AND  Supprimer le tiers consulte  ${id_tc_1}