*** Settings ***
Documentation  Test de la pastille (badge) indiquant le nombre de messages non lus
...            sur l'onglet Messages d'un dossier d'instruction.

# On inclut les mots-clefs
Resource  resources/resources.robot
# On ouvre/ferme le navigateur au début/à la fin du Test Suite.
Suite Setup  For Suite Setup
Suite Teardown  For Suite Teardown


*** Test Cases ***
Création du jeu de données

    [Documentation]  Constitue le jeu de données nécessaire au test de la pastille messages.

    &{args_petitionnaire} =  Create Dictionary
    ...  particulier_civilite=Monsieur
    ...  particulier_nom=Pastille
    ...  particulier_prenom=Test
    ...  om_collectivite=MARSEILLE

    &{args_demande} =  Create Dictionary
    ...  dossier_autorisation_type_detaille=Permis de construire pour une maison individuelle et / ou ses annexes
    ...  demande_type=Dépôt Initial
    ...  om_collectivite=MARSEILLE

    ${di_pastille} =  Ajouter la demande par WS  ${args_demande}  ${args_petitionnaire}
    Set Suite Variable  ${di_pastille}


Vérification de la pastille des messages non lus

    [Documentation]  Vérifie que la pastille de l'onglet Messages affiche le nombre
    ...  de messages non lus et "9+" lorsqu'il y en a plus de 9.

    Depuis la page d'accueil  admin  admin

    # Ajout d'un premier message (créé par admin, donc non lu par défaut)
    ${msg_premier} =  Ajouter un message dans le dossier d'instruction  ${di_pastille}  test badge pastille 1

    # Vérification que la pastille affiche "1"
    Depuis le contexte du dossier d'instruction  ${di_pastille}
    Wait Until Keyword Succeeds  ${TIMEOUT}  ${RETRY_INTERVAL}  Element Should Contain  css=a#dossier_message + .badge-onglet  1

    # Ajout de 9 messages supplémentaires non lus pour vérifier l'affichage "9+"
    :FOR  ${i}  IN RANGE  2  11
    \  Ajouter un message dans le dossier d'instruction  ${di_pastille}  test badge pastille ${i}

    # Vérification que la pastille affiche "9+"
    Depuis le contexte du dossier d'instruction  ${di_pastille}
    Wait Until Keyword Succeeds  ${TIMEOUT}  ${RETRY_INTERVAL}  Element Should Contain  css=a#dossier_message + .badge-onglet  9+

    # Marquage du premier message comme lu : la pastille doit passer de "9+" à "9"
    Marquer comme lu le message dans le dossier d'instruction  ${di_pastille}  ${msg_premier}
    Depuis le contexte du dossier d'instruction  ${di_pastille}
    Wait Until Keyword Succeeds  ${TIMEOUT}  ${RETRY_INTERVAL}  Element Should Contain  css=a#dossier_message + .badge-onglet  9