*** Settings ***
Documentation  Tests relatif à l'import et l'export des bibles.

# On inclut les mots-clefs
Resource  resources/resources.robot
# On ouvre/ferme le navigateur au début/à la fin du Test Suite.
Suite Setup  For Suite Setup
Suite Teardown  For Suite Teardown


*** Test Cases ***
Création du jeu de données
    [Documentation]  L'objectif est d'avoir des éléments rattachés à des collectivités
    ...  mono distinctes et à la multicollectivité.
    ...  Change également le code des PC pour le passer sur 3 caractères

    # En tant qu'administrateur
    Depuis la page d'accueil  admin  admin
    # Donnée 1/8 : collectivité 'Plan de Cuques' de niveau 1
    Ajouter la collectivité depuis le menu  Plan de Cuques  mono
    # Donnée 2/8 : collectivité 'Plan de Campagne' de niveau 1
    Ajouter la collectivité depuis le menu  Plan de Campagne  mono
    # Donnée 3/8 : bible rattachée à Plan de Cuques
    Ajouter une bible depuis l'onglet de l'événement  Notification du delai legal maison individuelle  Bibcuq  Bibcuq  complément 1  Oui  Permis de construire  Plan de Cuques
    # Donnée 4/8 : bible rattachée à Plan de Campagne
    Ajouter une bible depuis l'onglet de l'événement  Notification du delai legal maison individuelle  Bibcamp  Bibcamp  complément 1  Oui  Permis de construire  Plan de Campagne
    # Donnée 5/8 : bible pré-chargée rattachée à Plan de Cuques
    Set Suite Variable  ${evenement_bible_precharge}  affichage_obligatoire
    Set Suite Variable  ${txt_bible}  tst_precharge
    Ajouter une bible depuis l'onglet de l'événement  ${evenement_bible_precharge}  tst_precharge  ${txt_bible}  null  Non  Permis de construire  Plan de Cuques  Oui
    # Donnée 6/8 : guichetier rattaché à 'Plan de Cuques'
    Ajouter l'utilisateur  Bilodeau Simone  support@atreal.fr  quicuq  quicuq  GUICHET UNIQUE  Plan de Cuques
    # Donnée 7/8 : instructeur rattaché à 'Plan de Cuques'
    Ajouter l'utilisateur  Huard Franck  support@atreal.fr  instrcuq  instrcuq  INSTRUCTEUR  Plan de Cuques
    # Ajouter la direction depuis le menu  PDC  Direction PDC  null  Chef PDC  null  null  Plan de Cuques
    &{param_direction} =  Create Dictionary
    ...  code=PDC
    ...  libelle=Direction PDC
    ...  chef=Chef PDC
    ...  om_collectivite=Plan de Cuques
    Gerer la direction par WS  ${param_direction}
    # Ajouter la division depuis le menu  PDC  subdivision PDC  null  ${param_direction.chef}  null  null  ${param_direction.libelle}
    &{param_division_PDC} =  Create Dictionary
    ...  code=PDC
    ...  libelle=subdivision PDC
    ...  chef=${param_direction.chef}
    ...  direction=${param_direction.libelle}
    Gerer la division par WS  ${param_division_PDC}
    Ajouter l'instructeur depuis le menu  Huard Franck  ${param_division_PDC.libelle}  instructeur  Huard Franck
    # Donnée 8/8 : affectation automatique du nouvel instructeur
    &{args_affectation} =  Create Dictionary
    ...  instructeur=Huard Franck (PDC)
    ...  om_collectivite=Plan de Cuques
    Ajouter l'affectation depuis le menu  ${args_affectation}

    # On passe le code du type de DA sur 3 caractères
    &{args_type_da} =  Create Dictionary
    ...  code=PCI
    Modifier le type de dossier d'autorisation  PC  ${args_type_da}

    # On crée une nouvelle demande via le tableau de bord
    &{args_petitionnaire} =  Create Dictionary
    ...  particulier_nom=Pellerin
    ...  particulier_prenom=Olivier
    ...  om_collectivite=Plan de Cuques
    &{args_demande} =  Create Dictionary
    ...  dossier_autorisation_type_detaille=Permis de construire pour une maison individuelle et / ou ses annexes
    ...  demande_type=Dépôt Initial
    ...  om_collectivite=Plan de Cuques
    ${di_libelle} =  Ajouter la demande par WS  ${args_demande}  ${args_petitionnaire}

    Set Suite Variable  ${di_libelle}


Filtre des bibles ajoutées automatiquement sur une instruction
    [Documentation]  L'objet de ce 'Test Case' est de vérifier le filtre des
    ...    éléments de la bible proposés dans les instructions des DI selon
    ...    la collectivité à laquelle ils sont rattachés.
    ...    Un 2ème cas d'utilisation est un TNR, on vérifie que pour un code de type de
    ...    DA sur 3 caractères, l'ajout d'une bible sur une instruction fonctionne.

    # En tant qu'instructeur de Plan de Cuques
    Depuis la page d'accueil  instrcuq  instrcuq
    # On ouvre l'onglet instruction du nouveau DI
    Depuis l'onglet instruction du dossier d'instruction  ${di_libelle}
    # On accède à l'instruction
    Click On Link  Notification du delai legal maison individuelle
    # On reprend la rédaction
    Click On SubForm Portlet Action  instruction  definaliser
    # On revient au tableau
    Click On Back Button In Subform
    # On ré-accède à l'instruction
    Click On Link  Notification du delai legal maison individuelle
    # On modifie l'instruction
    Click On SubForm Portlet Action  instruction  modifier
    # On ajoute automatiquement la bible de Plan de Cuques
    Ajout automatique de complément(s) d'instruction
    # On vérifie le contenu du champ complément 1
    HTML Should Contain  complement_om_html  Bibcuq
    HTML Should Not Contain  complement_om_html  Bibcamp
    # On revient au tableau
    Depuis l'onglet instruction du dossier d'instruction  ${di_libelle}
    # On ré-accède à l'instruction
    Click On Link  Notification du delai legal maison individuelle
    # On modifie l'instruction
    Click On SubForm Portlet Action  instruction  modifier
    # On ouvre la bible du complément 1
    Ouvrir la bible du complément d'instruction n°  1
    Element Text Should Not Be  content0  Bibcamp
    Element Text Should Be  content0  Bibcuq
    Element Should Not Be Visible  content1


Insertion des bibles pré-chargés à l'ajout d'une instruction

    # Ajoute l'instruction entrainant l'ajout du texte de bible precharge
    Ajouter une instruction au DI  ${di_libelle}  ${evenement_bible_precharge}
    # Vérifie que le texte de bible a bien été ajouté dans les compléments
    Click On Back Button In Subform
    # TODO : a refactorer en utilisant une boucle
    Element Should Contain  fieldset-sousform-instruction-complement   ${txt_bible}
    Element Should Contain  fieldset-sousform-instruction-complement-2  ${txt_bible}
    Element Should Contain  fieldset-sousform-instruction-complement-3  ${txt_bible}
    Element Should Contain  fieldset-sousform-instruction-complement-4  ${txt_bible}


Réinitialisation du jeu de données
    [Documentation]  On remet le type de DA dans l'état initial

    Depuis la page d'accueil  admin  admin
    &{args_type_da} =  Create Dictionary
    ...  code=PC
    Modifier le type de dossier d'autorisation  PCI  ${args_type_da}