*** Settings ***
Documentation  Actions spécifiques aux divisions.

*** Keywords ***
Depuis le tableau des divisions
    [Documentation]  Permet d'accéder au tableau des divisions.

    # On ouvre le tableau
    Depuis le listing  division

Ajouter la division depuis le menu
    [Documentation]  Permet d'ajouter une division.
    [Arguments]  ${code}=null  ${libelle}=null  ${description}=null  ${chef}=null  ${debut}=null  ${fin}=null  ${direction}=null

    # On ouvre le tableau des divisions
    Depuis le tableau des divisions
    # On clique sur l'icone d'ajout
    Click On Add Button
    # On remplit le formulaire
    Saisir la division  ${code}  ${libelle}  ${description}  ${chef}  ${debut}  ${fin}  ${direction}
    # On valide le formulaire
    Click On Submit Button
    # On vérifie le message de validation
    Valid Message Should Contain  Vos modifications ont bien été enregistrées.

Saisir la division
    [Documentation]  Permet de remplir le formulaire d'une division.
    [Arguments]  ${code}  ${libelle}  ${description}  ${chef}  ${debut}  ${fin}  ${direction}

    # On saisit la code
    Run Keyword If  '${code}' != 'null'  Input Text  code  ${code}
    # On saisit le libelle
    Run Keyword If  '${libelle}' != 'null'  Input Text  libelle  ${libelle}
    # On saisit la description
    Run Keyword If  '${description}' != 'null'  Input Text  description  ${description}
    # On saisit le nom du chef
    Run Keyword If  '${chef}' != 'null'  Input Text  chef  ${chef}
    # On sélectionne la direction
    Run Keyword If  '${direction}' != 'null'  Select From List By Label  direction  ${direction}
    # On saisit la date de début de validité
    Run Keyword If  '${debut}' != 'null'  Input Datepicker  om_validite_debut  ${debut}
    # On saisit la date de fin de validite
    Run Keyword If  '${fin}' != 'null'  Input Datepicker  om_validite_fin  ${fin}
    
Gerer la division par WS
    [Tags]  division
    [Arguments]  ${args}
    [Documentation]  Gerer l'ajout, modification ou suppression d'une division via un webservice
    ...    Arguements attentdus :
    ...    - code (string)  code de la division a renseigner
    ...    - libelle (string)  libelle de la division a renseigner
    ...    - chef (string) valeur à affecter à la division
    ...    - direction (string) libelle de la direction a liée à la division
    ...    - description (string | optionnel) valeur à affecter à la division, optionnel
    ...    - om_validite_debut (string | optionnel) valeur à affecter à la division, optionnel
    ...    - om_validite_fin (string | optionnel) valeur à affecter à la division, optionnel
    ...    - delete (string | optionnel) definie à 'true' en cas de supression du parametre

    ${session} =  Catenate  http${PROJECT_NAME}
    Create Session  ${session}  ${PROJECT_URL}tests_services/rest_entry.php
    ${headers} =  Create Dictionary  Content-Type=application/json

    # Convertion de dictionnaire enshaine JSON
    ${json_string}=  evaluate  json.dumps(${args})  json

    ${resp}  Post Request  ${session}  /division  data=${json_string}  headers=${headers}

    # On verifie s'il y a eu une erreur
    ${status} =  Run Keyword And Return Status  To Json  ${resp.content}
    Run Keyword If  '${status}' != 'True'  Log  ${resp.content}  WARN

    # Convertion de chaine JSON en dict python
    ${resp} =  To Json  ${resp.content}

    Run Keyword If  '${resp["http_code"]}' != '200'  Log  ${resp["message"]}  WARN
    Should be Equal  '${resp["http_code"]}'  '200'