*** Settings ***
Documentation    Test du remplacement d'un document par sa version signée avec le profil JURISTE
Resource  resources/resources.robot

Suite Setup  For Suite Setup
Suite Teardown  For Suite Teardown

*** Test Cases ***
Constitution d'un jeu de données
    [Documentation]    Constitution du jeu de données nécessaire pour les tests.
    ...    Crée le dossier d'instruction pour le test avec les profils JURISTE et 
    ...    CHEF DE PROJET CONTENTIEUX

    # Connexion en tant qu'admin pour créer les dossiers
    Depuis la page d'accueil    admin    admin

    # Liste des arguments pour le dossier JURISTE
    &{args_demande} =    Create Dictionary
    ...    dossier_autorisation_type_detaille=Permis de construire pour une maison individuelle et / ou ses annexes
    ...    demande_type=Dépôt Initial
    ...    om_collectivite=MARSEILLE

    # Liste des arguments pour le pétitionnaire du dossier JURISTE
    &{args_petitionnaire} =    Create Dictionary
    ...    particulier_civilite=Monsieur
    ...    particulier_nom=MARTIN Jean
    ...    particulier_prenom=Jean
    ...    om_collectivite=MARSEILLE

    # Création du dossier JURISTE
    ${di_juriste} =    Ajouter la demande par WS    ${args_demande}    ${args_petitionnaire}
    
    
    Set Suite Variable    ${di_juriste}    ${di_juriste}

    # Liste des arguments pour le dossier CHEF DE PROJET CONTENTIEUX
    &{args_demande} =    Create Dictionary
    ...    dossier_autorisation_type_detaille=Permis de construire pour une maison individuelle et / ou ses annexes
    ...    demande_type=Dépôt Initial
    ...    om_collectivite=MARSEILLE
    ...    numero_dossier=PC0290120002

    # Liste des arguments pour le pétitionnaire du dossier CHEF DE PROJET CONTENTIEUX
    &{args_petitionnaire} =    Create Dictionary
    ...    particulier_civilite=Monsieur
    ...    particulier_nom=DUPONT Pierre
    ...    particulier_prenom=Jean
    ...    om_collectivite=MARSEILLE

    # Création du dossier CHEF DE PROJET CONTENTIEUX
    ${di_chef_projet_contentieux} =    Ajouter la demande par WS    ${args_demande}    ${args_petitionnaire}
    Set Suite Variable    ${di_chef_projet_contentieux}    ${di_chef_projet_contentieux}

Test remplacement document signé avec profil JURISTE
    [Documentation]    Test du remplacement de document signé après avoir attribué les droits nécessaires au profil JURISTE

    # Connexion avec le profil JURISTE
    Depuis la page d'accueil    juriste    juriste

    # Accès au dossier d'instruction
    Depuis l'onglet instruction du dossier d'instruction    ${di_juriste}

    # Accéder à l'instruction
    Click On Link    Notification du delai legal maison individuelle

    # Vérifier que l'action "Remplacer par le document signé" est présente et l'utiliser
    Click Link    Remplacer par le document signé
    Wait Until Page Contains Element    css=input#modale_date_retour_signature

    # Ajout de la date de retour signature
    ${date_retour_sign} =    Convert Date    ${DATE_FORMAT_YYYY-MM-DD}    result_format=%d/%m/%Y
    Input Datepicker    modale_date_retour_signature    ${date_retour_sign}

    # Ajout du nouveau document
    Add File    document_signe    testImportManuel.pdf

    # Validation de l'ajout
    Click On Submit Button In Subform

    # Vérification de réussite
    Valid Message Should Contain    Le document a bien été mis à jour.

    # Fermeture de la modale
    Click Element Until No More Element    css=.ui-dialog-titlebar-close

    # Vérification de la mise à jour de la date de retour signature
    Wait Until Element Contains    css=#date_retour_signature    ${date_retour_sign}

    # Vérification des pièces
    Depuis l'onglet des pièces du dossier d'instruction    ${di_juriste}

    # Vérifier que le document historisé n'est pas présent dans les téléchargements
    Click Element Until New Element
    ...    css=div[data-view="document_numerise_telechargement"]
    ...    css=div.switcher__label.onglet_active[data-view="document_numerise_telechargement"]
    La page ne doit pas contenir d'erreur
    Page Should Not Contain    _remplace_le_

    # Vérifier que le document historisé n'est pas présent dans l'onglet dossier final
    Click Element Until New Element
    ...    css=div[data-view="document_numerise_dossier_final"]
    ...    css=div.switcher__label.onglet_active[data-view="document_numerise_dossier_final"]
    La page ne doit pas contenir d'erreur

Test remplacement document signé avec profil CHEF DE SERVICE CONTENTIEUX
    [Documentation]    Test du remplacement de document signé après avoir attribué les droits nécessaires 
    ...    au profil CHEF DE SERVICE CONTENTIEUX

    # Connexion avec le profil CONTENTIEUX
    Depuis la page d'accueil    chefctx    chefctx

    # Accès au dossier d'instruction
    Depuis l'onglet instruction du dossier d'instruction    ${di_chef_projet_contentieux}

    # Accéder à l'instruction
    Click On Link    Notification du delai legal maison individuelle

    # Utiliser l'action et vérifier que la modale s'ouvre
    Click Link    Remplacer par le document signé
    Wait Until Page Contains Element    css=input#modale_date_retour_signature

    # Ajout de la date de retour signature
    ${date_retour_sign} =    Convert Date    ${DATE_FORMAT_YYYY-MM-DD}    result_format=%d/%m/%Y
    Input Datepicker    modale_date_retour_signature    ${date_retour_sign}

    # Ajout du nouveau document
    Add File    document_signe    testImportManuel.pdf

    # Validation de l'ajout
    Click On Submit Button In Subform

    # Vérification de réussite
    Valid Message Should Contain    Le document a bien été mis à jour.

    # Fermeture de la modale
    Click Element Until No More Element    css=.ui-dialog-titlebar-close

    # Vérification de la mise à jour de la date de retour signature
    Wait Until Element Contains    css=#date_retour_signature    ${date_retour_sign}

    # Vérification des pièces
    Depuis l'onglet des pièces du dossier d'instruction    ${di_chef_projet_contentieux}

    # Vérifier que le document historisé n'est pas présent dans les téléchargements
    Click Element Until New Element
    ...    css=div[data-view="document_numerise_telechargement"]
    ...    css=div.switcher__label.onglet_active[data-view="document_numerise_telechargement"]
    La page ne doit pas contenir d'erreur
    Page Should Not Contain    _remplace_le_

    # Vérifier que le document historisé n'est pas présent dans l'onglet dossier final
    Click Element Until New Element
    ...    css=div[data-view="document_numerise_dossier_final"]
    ...    css=div.switcher__label.onglet_active[data-view="document_numerise_dossier_final"]
    La page ne doit pas contenir d'erreur

Reset - Test remplacement document signé avec profils JURISTE et CHEF DE SERVICE CONTENTIEUX
    [Documentation]    Nettoie l'environnement après les tests en supprimant les dossiers créés
    ...    et en réinitialisant les variables
    
    # Connexion en tant qu'admin pour avoir les droits de suppression
    Depuis la page d'accueil    admin    admin
    
    # Suppression des dossiers créés
    Run Keyword And Ignore Error    Supprimer le dossier d'instruction    ${di_chef_projet_contentieux}
    Run Keyword And Ignore Error    Supprimer le dossier d'instruction    ${di_juriste}