*** Settings ***
Documentation  Tests relatifs aux suggestions de type détaillé pour un Permis de Construire.

Resource  resources/resources.robot
Suite Setup  For Suite Setup
Suite Teardown  For Suite Teardown


*** Test Cases ***
Initialisation du paramétrage
    [Documentation]  Active l'option nécessaire pour les tests de suggestion
    ...  - option_dossier_saisie_numero_complet : permet la saisie du numéro complet de dossier

    Depuis la page d'accueil  admin  admin
    &{param_saisie_complete} =  Create Dictionary
    ...  valeur=true
    ...  libelle=option_dossier_saisie_numero_complet
    ...  om_collectivite=agglo
    Gerer le paramètre par WS   ${param_saisie_complete}

Vérification des types détaillés PC
    [Documentation]  Vérifie les suggestions de type détaillé pour un Permis de Construire :
    ...  - PCA - Permis de construire comprenant ou non des démolitions
    ...  - PCI - Permis de construire pour une maison individuelle
    
    # Se connecter et aller au formulaire
    Depuis la page d'accueil  guichet  guichet
    Go To Submenu In Menu  guichet_unique  nouveau-dossier
    Le titre de la page doit être  Guichet Unique > Nouvelle Demande > Nouveau Dossier

    # Saisir le numéro et attendre le chargement
    Wait Until Keyword Succeeds  ${TIMEOUT}  ${RETRY_INTERVAL}  Element Should Be Visible  css=#num_doss_complet
    Input Text until text is correct  css=#num_doss_complet  PC0131772200013
    Simulate Event  css=input#num_doss_complet  change
    ${status} =  Run Keyword And Return Status  Page Should Contain Element  css=div#commune_loader_div.loader
    Run Keyword If  '${status}' == 'False'  Simulate Event  css=input#num_doss_complet  change
    Wait Until Keyword Succeeds  ${TIMEOUT}  ${RETRY_INTERVAL}  Page Should Not Contain Element  css=div#commune_loader_div.loader

    # Vérifier les suggestions de type détaillé
    Select From Chosen List Suggestions Should Contain  dossier_autorisation_type_detaille  PCA - Permis de construire comprenant ou non des démolitions
    Select From Chosen List Suggestions Should Contain  dossier_autorisation_type_detaille  PCI - Permis de construire pour une maison individuelle et / ou ses annexes

Réinitialisation du paramétrage
    [Documentation]  Désactive l'option qui a été activée pour les tests
    ...  - option_dossier_saisie_numero_complet : désactive la saisie du numéro complet

    &{param_saisie_complete} =  Create Dictionary
    ...  libelle=option_dossier_saisie_numero_complet
    ...  valeur=false
    ...  om_collectivite=agglo
    Gerer le paramètre par WS  ${param_saisie_complete}