*** Settings ***
Documentation  Tests des suggestions de communes basées sur le numéro de dossier saisi.

Resource  resources/resources.robot
Suite Setup  For Suite Setup
Suite Teardown  For Suite Teardown


*** Test Cases ***
Initialisation du paramétrage
    [Documentation]  Configure via WS les paramètres pour :
    ...  - option_dossier_saisie_numero_complet : permet la saisie du numéro complet de dossier (ex: PC0130772200013)
    ...  - option_dossier_commune : active les suggestions de commune basées sur ce numéro
    ...  Les deux sont configurés pour la collectivité "agglo"

    &{param_saisie_complete} =  Create Dictionary
    ...  valeur=true
    ...  libelle=option_dossier_saisie_numero_complet
    ...  om_collectivite=agglo
    Gerer le paramètre par WS   ${param_saisie_complete}

    &{param_dossier_commune} =  Create Dictionary
    ...  libelle=option_dossier_commune
    ...  valeur=true
    ...  om_collectivite=agglo
    Gerer le paramètre par WS  ${param_dossier_commune}


Création des communes pour les suggestions
    [Documentation]  Crée les communes de test nécessaires pour vérifier les suggestions :
    ...  - Communes avec préfixe 13 : TESTCITY013077, TESTCITY013177, TESTCITY013277
    ...  - Communes avec préfixe 966 : TESTLOIN96601, TESTLOIN96611
    
    Run Keyword If   '${CONTEXT_COMMUNE_CREATED}' == 'False'   Initialisation du jeu de données Commune
    Set Global Variable  ${CONTEXT_COMMUNE_CREATED}  True

    Depuis la page d'accueil  admin  admin
    # Création des communes avec préfixe 13
    &{commune} =  Create Dictionary
    ...  typecom=COM
    ...  com=13077
    ...  reg=13
    ...  dep=13
    ...  arr=133
    ...  ncc=TESTCITY013077
    ...  nccenr=TESTCITY013077
    ...  libelle=TESTCITY013077
    ${commune_id} =  Ajouter commune avec dates validité  ${commune}

    &{commune} =  Create Dictionary
    ...  typecom=COM
    ...  com=13277
    ...  reg=13
    ...  dep=13
    ...  arr=133
    ...  ncc=TESTCITY013277
    ...  nccenr=TESTCITY013277
    ...  libelle=TESTCITY013277
    ${commune_id} =  Ajouter commune avec dates validité  ${commune}

    # Création des communes avec préfixe 966
    &{commune} =  Create Dictionary
    ...  typecom=COM
    ...  com=96601
    ...  reg=99
    ...  dep=966
    ...  arr=966
    ...  ncc=TESTLOIN96601
    ...  nccenr=TESTLOIN96601
    ...  libelle=TESTLOIN96601
    ${commune_id} =  Ajouter commune avec dates validité  ${commune}

    &{commune} =  Create Dictionary
    ...  typecom=COM
    ...  com=96611
    ...  reg=99
    ...  dep=966
    ...  arr=966
    ...  ncc=TESTLOIN96611
    ...  nccenr=TESTLOIN96611
    ...  libelle=TESTLOIN96611
    ${commune_id} =  Ajouter commune avec dates validité  ${commune}

Vérification des suggestions de commune avec préfixes 13 et 966
    [Documentation]  Vérifie le fonctionnement des suggestions de commune :
    ...  - Avec le numéro PC0130772200013 : suggère TESTCITY013077, affiche TESTCITY013177 et TESTCITY013277
    ...  - Avec le numéro PC96601122A0001 : suggère TESTLOIN96611, affiche TESTLOIN96601
    
    # Accéder au formulaire de nouveau dossier
    Depuis la page d'accueil  guichet  guichet
    Go To Submenu In Menu  guichet_unique  nouveau-dossier
    Le titre de la page doit être  Guichet Unique > Nouvelle Demande > Nouveau Dossier

    # Saisir le numéro et attendre la mise à jour des suggestions
    Wait Until Keyword Succeeds  ${TIMEOUT}  ${RETRY_INTERVAL}  Element Should Be Visible  css=#num_doss_complet
    Input Text until text is correct  css=#num_doss_complet  PC0130772200013
    Wait Until Element Is Visible    css=div#commune_chosen    timeout=${TIMEOUT}    error=Le champ commune n'est pas visible
    Wait Until Element Is Enabled    css=div#commune_chosen    timeout=${TIMEOUT}    error=Le champ commune n'est pas activé
    Simulate Event  css=input#num_doss_complet  change
    ${status} =  Run Keyword And Return Status  Page Should Contain Element  css=div#commune_loader_div.loader
    Run Keyword If  '${status}' == 'False'  Simulate Event  css=input#num_doss_complet  change
    Wait Until Keyword Succeeds  ${TIMEOUT}  ${RETRY_INTERVAL}  Page Should Not Contain Element  css=div#commune_loader_div.loader
    
    # Vérifier les suggestions de commune
    Select From Chosen List Suggestions Should Contain  commune  13077 - TESTCITY013077
    
    # Vérifier les communes proches non suggérées
    Select From Chosen List Should Contain  commune  13177 - TESTCITY013177
    Select From Chosen List Should Contain  commune  13277 - TESTCITY013277
    
    # Vérifier les suggestions avec un numéro de dossier avec préfixe966
    Input Text until text is correct  css=#num_doss_complet  PC96601122A0001
    Wait Until Element Is Visible    css=div#commune_chosen    timeout=${TIMEOUT}    error=Le champ commune n'est pas visible
    Wait Until Element Is Enabled    css=div#commune_chosen    timeout=${TIMEOUT}    error=Le champ commune n'est pas activé
    Simulate Event  css=input#num_doss_complet  change
    Wait Until Keyword Succeeds  ${TIMEOUT}  ${RETRY_INTERVAL}  Page Should Not Contain Element  css=div#commune_loader_div.loader
    
    # Vérifier la commune suggérée
    Select From Chosen List Suggestions Should Contain  commune  96611 - TESTLOIN96611
    
    # Vérifier la commune proche non suggérée
    Select From Chosen List Should Contain  commune  96601 - TESTLOIN96601

Réinitialisation du paramétrage
    [Documentation]  Désactive les options qui ont été activées pour les tests :
    ...  - option_dossier_saisie_numero_complet : désactive la saisie du numéro complet
    ...  - option_dossier_commune : désactive les suggestions de commune

    # Réinitialisation du paramètre de saisie
    &{param_saisie_complete} =  Create Dictionary
    ...  libelle=option_dossier_saisie_numero_complet
    ...  valeur=false
    ...  om_collectivite=agglo
    Gerer le paramètre par WS  ${param_saisie_complete}

    # Réinitialisation du paramètre de suggestions
    &{param_dossier_commune} =  Create Dictionary
    ...  libelle=option_dossier_commune
    ...  valeur=false
    ...  om_collectivite=agglo
    Gerer le paramètre par WS  ${param_dossier_commune}