*** Settings ***
Documentation     Actions spécifiques aux pièces.

*** Keywords ***
Depuis le contexte du message dans le dossier d'instruction
    [Documentation]  Accède au formulaire
    [Arguments]  ${dossier_instruction}  ${dossier_message}

    Depuis l'onglet des messages du dossier d'instruction  ${dossier_instruction}
    Click Element Until No More Element  xpath=//a[text()[contains(.,"${dossier_message}")]]


Marquer comme lu le message dans le dossier d'instruction
    [Documentation]  Marque comme lu le message
    [Arguments]  ${dossier_instruction}  ${dossier_message}

    # On accède à l'enregistrement
    Depuis le contexte du message dans le dossier d'instruction  ${dossier_instruction}  ${dossier_message}
    #
    Click On SubForm Portlet Action  dossier_message  marquer_comme_lu
    #
    Wait Until Keyword Succeeds  ${TIMEOUT}  ${RETRY_INTERVAL}  Valid Message Should Contain  Le message a été marqué comme lu
    #
    Form Static Value Should Be  lu  Oui


Marquer comme non lu le message dans le dossier d'instruction
    [Documentation]  Marque comme non lu le message
    [Arguments]  ${dossier_instruction}  ${dossier_message}

    # On accède à l'enregistrement
    Depuis le contexte du message dans le dossier d'instruction  ${dossier_instruction}  ${dossier_message}
    #
    Click On SubForm Portlet Action  dossier_message  marquer_comme_non_lu
    #
    Wait Until Keyword Succeeds  ${TIMEOUT}  ${RETRY_INTERVAL}  Valid Message Should Contain  Le message a été marqué comme non lu
    #
    Form Static Value Should Be  lu  Non


Supprimer le message dans le dossier d'instruction
    [Documentation]  Supprime l'enregistrement
    [Arguments]  ${dossier_instruction}  ${dossier_message}

    # On accède à l'enregistrement
    Depuis le contexte du message dans le dossier d'instruction  ${dossier_instruction}  ${dossier_message}
    # On clique sur le bouton supprimer
    Click On SubForm Portlet Action  dossier_message  supprimer
    # On valide le formulaire
    Click On Submit Button


Ajouter un message dans le dossier d'instruction
    [Documentation]  Ajoute un enregistrement
    [Arguments]  ${dossier_instruction}  ${message_content}

    # On accède à l'enregistrement
    Depuis le contexte du dossier d'instruction  ${dossier_instruction}
    On clique sur l'onglet  dossier_message  Message(s)
    Click On Add Button
    Input Text  contenu  ${message_content}
    # On valide le formulaire
    Click On Submit Button

    ${dossier_message} =  Wait Until Keyword Succeeds  ${TIMEOUT}  ${RETRY_INTERVAL}
    ...  Get Text  css=span#dossier_message.field_value

    #Retour sur l'onglet
    Depuis le contexte du dossier d'instruction  ${dossier_instruction}
    On clique sur l'onglet  dossier_message  Message(s)

    [Return]  ${dossier_message}


Effectuer une recherche avancée sur les messages
    [Documentation]  Accède au menu des messages voulu (Défaut : Tous les messages). Affiche la recherche
    ...  avancée puis saisit les valeurs passées en paramètre dedans avant de valider le
    ...  formulaire.
    [Arguments]  ${search_values}  ${menu}=messages_tous_retours 

    Depuis le listing  ${menu}
    Click Element  css=#toggle-advanced-display
    Wait Until Page Contains  Afficher la recherche simple
    Remplir le formulaire de recherche avancée  ${search_values}
    Click Element  adv-search-submit
    ${status} =  Run Keyword And Return Status  Wait Until Keyword Succeeds  ${TIMEOUT}  ${RETRY_INTERVAL}  Wait Until Page Contains Element   css=#adv-search-submit.advs-unvalidate-field-search
    Run Keyword If  ${status} == True  Click Element Until No More Element  css=#adv-search-submit.advs-unvalidate-field-search
    La Page Ne Doit Pas Contenir D'erreur


Remplir le formulaire de recherche avancée
    [Documentation]  Remplit le formulaire
    [Arguments]  ${values}

    Si "dossier" existe dans "${values}" on execute "Input Text until text is correct" dans le formulaire
    Si "type" existe dans "${values}" on execute "Select From List By Label" dans le formulaire
    Si "emetteur" existe dans "${values}" on execute "Input Text" dans le formulaire
    Si "date_emission_min" existe dans "${values}" on execute "Input Text" dans le formulaire
    Si "date_emission_max" existe dans "${values}" on execute "Input Text" dans le formulaire
    Si "instructeur" existe dans "${values}" on execute "Input Text" dans le formulaire
    Si "instructeur_2" existe dans "${values}" on execute "Select From List By Label" dans le formulaire
    Si "division" existe dans "${values}" on execute "Input Text" dans le formulaire
    Si "collectivite" existe dans "${values}" on execute "Input Text" dans le formulaire
    Si "enjeu" existe dans "${values}" on execute "Input Text until text is correct" dans le formulaire


Ouvrir la recherche avancée Tous Les Messages
    # On s'assure d'être sur la bonne page Sinon 
    ${on_page_message} =  Run Keyword And Return Status  Le titre de la page doit être  Instruction > Messages > Tous Les Messages
    # On se connecte en tant que "admin"
    Run Keyword If  ${on_page_message} == False  Depuis la page d'accueil  admin  admin
    # On se place sur une gestion des messages
    Run Keyword If  ${on_page_message} == False  Go To Submenu In Menu  instruction  messages_tous_retours
    Run Keyword If  ${on_page_message} == False  Le titre de la page doit être  Instruction > Messages > Tous Les Messages

    # On ouvre la recherche avancée si elle n'est pas déjà ouverte
    ${adv-search-adv-fields} =  Run Keyword And Return Status  Wait Until Element Is Visible  css=div#adv-search-adv-fields
    Run Keyword If  ${adv-search-adv-fields} == False  Click Element  css=#toggle-advanced-display
    Run Keyword If  ${adv-search-adv-fields} == False  Wait Until Element Is Visible  css=div#adv-search-adv-fields
    #Sinon On reset la recherche
    Run Keyword If  ${adv-search-adv-fields} == True and ${on_page_message} == True  Click Element  css=#advanced-form .raz_advs
    Run Keyword If  ${adv-search-adv-fields} == True and ${on_page_message} == True  Sleep  0.2