*** Settings ***
Documentation  Fonctions et méthodes de traitement

*** Keywords ***


Entourer de guillements les valeurs contenant des espaces
    [Tags]  utils
    [Arguments]  @{values_to_convert}

    ${nb_keys} =  Get length  ${values_to_convert}
    @{values_converted} =  Create List
    # Gestion des noms de colonnes contenant des espaces
    : FOR  ${key}  IN RANGE  ${nb_keys}
    \  ${is_value_contain_space}=  Run Keyword And Return Status  Should Contain  @{values_to_convert}[${key}]  ${SPACE}
    \  Run Keyword If  ${is_value_contain_space} == True  Append To List  ${values_converted}  "@{values_to_convert}[${key}]"  ELSE  Append To List  ${values_converted}  @{values_to_convert}[${key}]

    [return]  ${values_converted}
    
Convertir les colonnes du listing en colonnes d'export csv
    [Tags]  utils
    [Arguments]  @{keys_to_convert}

    ${columns_converted} =  Entourer de guillements les valeurs contenant des espaces  @{keys_to_convert}

    # Composition de la chaîne de caractère contenant les noms de colonnes
    ${list_column_csv} =  Catenate  SEPARATOR=;  @{columns_converted}

    [return]  ${list_column_csv}

Verifier les valeurs enregistrés dans le formulaire de consultation de l'objet
    [Documentation]  Verifie que le formulaire contient les infos passées en paramètres
    ...  Le formulaire peut etre un sous formulaire
    [Tags]  utils
    [Arguments]  ${valeurs}

    :FOR    ${cle}    IN    @{valeurs}
    \    Element Should Contain    css=#${cle}    ${valeurs.${cle}}

Vérifier les valeurs d'une recherche
    [Tags]  utils
    [Arguments]  ${given_values}  ${headers}=${TAB_REF_COLUMNS}  @{keys_to_verify}
    [Documentation]  Permet de vérifier les valeurs d'une recherche.
    ...  Ce keyword prend pour paramètre :
    ...   1/ ${given_value} : Un dictionnaire contenant les valeurs de l'enregistrement.
    ...   2/ ${headers} : La liste des colonnes du listing sous format list ou le nombre de colonne avec pour première
    ...     colonne 1 (type integer)
    ...   3/ @{keys_to_verify} : Les clés à vérifier sous format liste, ces clés correspondent aux clés du dictionnaire
    ...     comportant les valeurs de l'enregistrement
    ...  Par défaut, la variable ${headers} prend la liste des colonnes des tables de références et
    ...  la liste @{keys_to_verify} prend la liste id code et libelle des tables de références

    ${is_list_empty} =  Get length  ${keys_to_verify}
    # On vérifie si la liste est spécifiée, sinon on prend la liste par défaut suivante
    @{keys_to_verify} =  Run Keyword If  ${is_list_empty} == 0  Create List  id  code  libelle  ELSE  Set Variable  @{keys_to_verify}

    ${nb_columns}=    Get length  ${headers}

    : FOR  ${index}  IN RANGE  ${nb_columns}
    \  ${expected_value}=  Set Variable  ${given_values.@{keys_to_verify}[${index}]}
    \  Element Should Contain    css=.tab-tab tbody tr td.col-${index} a    ${expected_value}

Vérifier le nom des colonnes du listing
    [Tags]  utils
    [Arguments]  @{headers}
    [Documentation]  Permet de vérifier si le nom des colonnes du listing sont corrects
    ...  Pour cela on prend une liste en paramètre, il faut que les colonnes soient listées
    ...  dans l'ordre où elles sont affichées dans l'interface.
    ...  Par défaut, le paramètre récupère la liste des colonnes générique des tables de références.

    ${is_list_empty} =  Get length  ${headers}
    # On vérifie si la liste est spécifiée, sinon on prend la liste par défaut suivante
    @{headers} =  Run Keyword If  ${is_list_empty} == 0  Create List  @{TAB_REF_COLUMNS}  ELSE  Set Variable  @{headers}
    # On vérifie que chaque colonne est présente dans l'ordre des 'headers' fournis
    ${nb_columns}=    Get length  ${headers}
    : FOR  ${index}  IN RANGE  ${nb_columns}
    \  ${column_name} =  Set Variable  @{headers}[${index}]
    \  Element Should Contain  css=.tab-tab tr th.col-${index} a  ${column_name}