*** Settings ***
Resource  resources/resources.robot
Suite Setup  For Suite Setup
Suite Teardown  For Suite Teardown
Documentation  ...


*** Test Cases ***
Constitution du jeu de données
    [Documentation]  ...
    #
    Depuis la page d'accueil  admin  admin
    #
    Set Suite Variable  ${testid}  150
    #
    &{cimetiere01} =  Create Dictionary
    ...  cimetierelib=CIMETIERE${testid}-01
    ...  adresse1=RUE DE LA REPUBLIQUE
    ...  adresse2=
    ...  cp=99607
    ...  ville=LIBREVILLE
    ...  observations=
    Ajouter le cimetière  ${cimetiere01}
    Set Suite Variable  ${cimetiere01}
    #
    &{zone01_cim01} =  Create Dictionary
    ...  cimetiere=${cimetiere01.cimetierelib}
    ...  zonetype=CARRE
    ...  zonelib=Z${testid}-01
    Ajouter la zone  ${zone01_cim01}
    Set Suite Variable  ${zone01_cim01}

    &{voie01_zone01_cim01} =  Create Dictionary
    ...  zone=${zone01_cim01.zonetype} ${zone01_cim01.zonelib} (${zone01_cim01.cimetiere})
    ...  voietype=ALLEE
    ...  voielib=V${testid}-01
    Ajouter la voie  ${voie01_zone01_cim01}
    Set Suite Variable  ${voie01_zone01_cim01}
    #
    &{concession01} =  Create Dictionary
    ...  famille=DURAND${testid}
    ...  numero=12
    ...  cimetierelib=${cimetiere01.cimetierelib}
    ...  zonelib=${zone01_cim01.zonetype} ${zone01_cim01.zonelib}
    ...  voielib=${voie01_zone01_cim01.voietype} ${voie01_zone01_cim01.voielib}
    ${concession01.id} =  Ajouter la concession  ${concession01}
    Set Suite Variable  ${concession01}


Vérification de l'indicateur Mort pour la France

    Depuis la page d'accueil  admin  admin

    # On ajoute le defunt mort pour la france
    &{defunt} =  Create Dictionary
    ...  titre=Monsieur
    ...  nom=harald le deux
    ...  prenom=nord
    ...  datenaissance=01/01/1970
    ...  lieunaissance=ARLES
    ...  datedeces=25/05/2017
    ...  lieudeces=LIBREVILLE
    ...  parente=LOLO
    ...  nature=cercueil
    ...  mort_pour_la_france=Oui
    ${defunt.id} =  Ajouter le defunt dans le contexte de la concession  ${defunt}  ${concession01.id}

    # On vérifie que le badge s'affiche correctement
    Depuis le contexte de la concession  ${concession01.id}
    Element Should Be Visible  css=#badge_mplf

    &{defunt_modif} =  Create Dictionary
    ...  mort_pour_la_france=Non
    Modifier le défunt dans le contexte de la concession  ${defunt_modif}  ${defunt.id}  ${concession01.id}

    # On vérifie que le badge s'affiche correctement
    Depuis le contexte de la concession  ${concession01.id}
    Element Should Not Be Visible  css=#badge_mplf

    # On ajoute un autre defunt mort pour la france
    &{defunt02} =  Create Dictionary
    ...  titre=Monsieur
    ...  nom=harald le deux
    ...  prenom=nord
    ...  datenaissance=01/01/1970
    ...  lieunaissance=ARLES
    ...  datedeces=25/05/2017
    ...  lieudeces=LIBREVILLE
    ...  parente=LOLO
    ...  nature=cercueil
    ...  mort_pour_la_france=Oui
    ${defunt02.id} =  Ajouter le defunt dans le contexte de la concession  ${defunt02}  ${concession01.id}

    # On vérifie que le badge s'affiche correctement
    Depuis le contexte de la concession  ${concession01.id}
    Element Should Be Visible  css=#badge_mplf

    &{defunt_modif} =  Create Dictionary
    ...  mort_pour_la_france=Oui
    Modifier le défunt dans le contexte de la concession  ${defunt_modif}  ${defunt.id}  ${concession01.id}

    # On vérifie que le badge s'affiche toujours
    Depuis le contexte de la concession  ${concession01.id}
    Element Should Be Visible  css=#badge_mplf