*** Settings ***
Resource  resources/resources.robot
Suite Setup  For Suite Setup
Suite Teardown  For Suite Teardown
Documentation  Reprise sur abandon - Le listing global des reprises sur abandon affiche toutes
...  les reprises sur abandon avec une recherche avancée et un export csv

*** Test Cases ***
Constitution du jeu de données
    [Documentation]  Creation du jeu de donnée

    ${testid} =  Set Variable  141
    Set Suite Variable  ${testid}

    # On détermine la liste des noms de colonnes du listing global des reprises sur abandon
    @{col_reprise_abandon_global} =  Create List
    ...  id
    ...  emplacement
    ...  statut
    ...  état
    ...  date de création
    ...  envoi/affichage convocation 1ère visite
    ...  date de notification pv1
    ...  envoi/affichage convocation 2ème visite
    ...  date de notification pv2
    Set Suite Variable  ${col_reprise_abandon_global}

    # Clés à vérifier dans le résultat de recherche sur le listing global
    @{keys_to_verify_lg} =  Create List
    ...  id
    ...  emplacement
    ...  statut
    ...  etat
    ...  datecreation
    ...  dateconvocationvisite1
    ...  dateconstatpv1
    ...  dateconvocationvisite2
    ...  dateconstatpv2
    Set Suite Variable  ${keys_to_verify_lg}

    # On détermine la liste des colonnes du listing des reprises sur abandon
    # à partir d'un emplacement (sous formulaire)
    @{col_reprise_abandon_sf} =  Create List
    ...  id
    ...  statut
    ...  état
    Set Suite Variable  ${col_reprise_abandon_sf}

    # Clé à vérifier dans le résultat de la recherche dynamique du listing
    # depuis l'emplacement
    @{keys_to_verify_sf} =  Create List
    ...  id
    ...  statut
    ...  etat
    Set Suite Variable  ${keys_to_verify_sf}

    Depuis la page d'accueil  admin  admin

    &{cimetiere01} =  Create Dictionary
    ...  cimetierelib=ENITSELAP${testid}
    ...  adresse1=EERF ENITSELAP${testid}
    ...  adresse2=
    ...  cp=81680085
    ...  ville=LIBREVILLE
    ...  observations=
    Ajouter le cimetière  ${cimetiere01}
    Set Suite Variable  ${cimetiere01}

    &{zone01_cim01} =  Create Dictionary
    ...  cimetiere=${cimetiere01.cimetierelib}
    ...  zonetype=CARRE
    ...  zonelib=81680085${testid}
    Ajouter la zone  ${zone01_cim01}
    Set Suite Variable  ${zone01_cim01}

    &{voie01_zone01_cim01} =  Create Dictionary
    ...  zone=${zone01_cim01.zonetype} ${zone01_cim01.zonelib} (${zone01_cim01.cimetiere})
    ...  voietype=ALLEE
    ...  voielib=81680085${testid}
    Ajouter la voie  ${voie01_zone01_cim01}
    Set Suite Variable  ${voie01_zone01_cim01}

    &{type_de_sepulture_01} =  Create Dictionary
    ...  code=81680085${testid}
    ...  libelle=Type de sépulture 81680085${testid}
    ${type_de_sepulture_01.id} =  Ajouter le *type de sépulture*  ${type_de_sepulture_01}
    Set Suite Variable  ${type_de_sepulture_01}

    # On ajoute une concession
    &{concession01} =  Create Dictionary
    ...  famille=SUPASAYANJIN${testid}
    ...  numero=81680085
    ...  cimetierelib=${cimetiere01.cimetierelib}
    ...  zonelib=${zone01_cim01.zonetype} ${zone01_cim01.zonelib}
    ...  voielib=${voie01_zone01_cim01.voietype} ${voie01_zone01_cim01.voielib}
    ...  sepulturetype=${type_de_sepulture_01.libelle}
    ${concession01.id} =  Ajouter la concession  ${concession01}
    Set Suite Variable  ${concession01}

    &{reprise_abandon} =  Create Dictionary
    ...  statut=En cours
    ...  etat=1 - Phase préliminaire
    ...  datecreation=25/05/2026
    ...  dateconvocationvisite1=25/05/2026
    ...  dateconstatpv1=25/05/2026
    ...  descriptionpv1=NON
    ...  personnepresentepv1=BIBI
    ...  datenotificationpv1=25/05/2026
    ...  debutaffichage1pv1=25/05/2026
    ...  finaffichage1pv1=25/05/2026
    ...  debutaffichage2pv1=25/05/2026
    ...  finaffichage2pv1=25/05/2026
    ...  debutaffichage3pv1=25/05/2026
    ...  finaffichage3pv1=25/05/2026
    ...  dateconvocationvisite2=25/05/2026
    ...  dateconstatpv2=25/05/2026
    ...  descriptionpv2=NON
    ...  personnepresentepv2=BIBI
    ...  datenotificationpv2=25/05/2026
    ...  debutaffichagepv2=25/05/2026
    ...  finaffichagepv2=25/05/2026
    ...  arrete=p-concession-1.jpg
    ${reprise_abandon.id} =  Ajouter une reprise sur abandon  ${reprise_abandon}  ${concession01.id}
    Set Suite Variable  ${reprise_abandon}

    ${reprise_abandon.emplacement} =  Set Variable  concession - n°${concession01.id} - Famille : ${concession01.famille}

Vérification du nom des colonnes du listing global

    Depuis la page d'accueil  admin  admin

    # On va dans le listing global verifier si les infos correspondent
    Depuis le listing global des reprises sur abandon
    Vérifier le nom des colonnes du listing  ${col_reprise_abandon_global}

Vérification du bon fonctionnement de la recherche avancée sur le listing global
    [Documentation]  Permet de vérifier le bon fonctionnement de la recherche avancée
    ...  depuis le listing global

    Depuis la page d'accueil  admin  admin

    # On recherche la reprise sur abandon à vérifier
    Depuis le listing global des reprises sur abandon
    Input Text  css=#id  ${reprise_abandon.id}
    Click On Search Button
    Vérifier les valeurs d'une recherche  ${reprise_abandon}  ${col_reprise_abandon_global}  ${keys_to_verify_lg}

Vérification des informations du listing des reprises sur abandon dans emplacement
    [Documentation]  Permet de vérifier le nom des colonnes dans le listing et l'affichage
    ...  d'un résultat avec la recherche dynamique dans le sous formulaire

    Depuis la page d'accueil  admin  admin

    Depuis l'onglet 'reprise_abandon' de la concession  ${concession01.id}
    Vérifier le nom des colonnes du listing  ${col_reprise_abandon_sf}
    Input Text  css=#recherchedyn  ${reprise_abandon.id}
    Wait Until Keyword Succeeds  ${TIMEOUT}  ${RETRY_INTERVAL}  Element Should Contain  css=.soustab-container .pagination-text  [${reprise_abandon.id}]
    Vérifier les valeurs d'une recherche  ${reprise_abandon}  ${col_reprise_abandon_sf}  ${keys_to_verify_sf}