*** Settings ***
Resource  resources/resources.robot
Suite Setup  For Suite Setup
Suite Teardown  For Suite Teardown
Documentation  Reprise sur abandon - Une reprise sur abandon est lié à un emplacement.
...  La reprise sur abandon est ajoutable seulement à partir d'un emplacement.

*** Test Cases ***
Constitution du jeu de données
    [Documentation]  Creation du jeu de donnée

    ${testid} =  Set Variable  140
    Set Suite Variable  ${testid}

    Depuis la page d'accueil  admin  admin

    &{cimetiere01} =  Create Dictionary
    ...  cimetierelib=ENITSELAP${testid}
    ...  adresse1=EERF ENITSELAP${testid}
    ...  adresse2=
    ...  cp=81680085
    ...  ville=LIBREVILLE
    ...  observations=
    Ajouter le cimetière  ${cimetiere01}
    Set Suite Variable  ${cimetiere01}
    
    &{zone01_cim01} =  Create Dictionary
    ...  cimetiere=${cimetiere01.cimetierelib}
    ...  zonetype=CARRE
    ...  zonelib=81680085${testid}
    Ajouter la zone  ${zone01_cim01}
    Set Suite Variable  ${zone01_cim01}

    &{voie01_zone01_cim01} =  Create Dictionary
    ...  zone=${zone01_cim01.zonetype} ${zone01_cim01.zonelib} (${zone01_cim01.cimetiere})
    ...  voietype=ALLEE
    ...  voielib=81680085${testid}
    Ajouter la voie  ${voie01_zone01_cim01}
    Set Suite Variable  ${voie01_zone01_cim01}

    &{type_de_sepulture_01} =  Create Dictionary
    ...  code=81680085${testid}
    ...  libelle=Type de sépulture 81680085${testid}
    ${type_de_sepulture_01.id} =  Ajouter le *type de sépulture*  ${type_de_sepulture_01}
    Set Suite Variable  ${type_de_sepulture_01}

    # On ajoute une concession
    &{concession01} =  Create Dictionary
    ...  famille=SUPASAYANJIN${testid}
    ...  numero=81680085
    ...  cimetierelib=${cimetiere01.cimetierelib}
    ...  zonelib=${zone01_cim01.zonetype} ${zone01_cim01.zonelib}
    ...  voielib=${voie01_zone01_cim01.voietype} ${voie01_zone01_cim01.voielib}
    ...  sepulturetype=${type_de_sepulture_01.libelle}
    ${concession01.id} =  Ajouter la concession  ${concession01}
    Set Suite Variable  ${concession01}

    &{concession02} =  Create Dictionary
    ...  famille=${testid}CONCESSIONVERIFSUIVI
    ...  numero=41
    ...  cimetierelib=${cimetiere01.cimetierelib}
    ...  zonelib=${zone01_cim01.zonetype} ${zone01_cim01.zonelib}
    ...  voielib=${voie01_zone01_cim01.voietype} ${voie01_zone01_cim01.voielib}
    ...  sepulturetype=${type_de_sepulture_01.libelle}
    ...  date_abandon=${DATE_FORMAT_DD/MM/YYYY}
    ${concession02.id} =  Ajouter la concession  ${concession02}
    Set Suite Variable  ${concession02}


Vérification de l'ajout d'une reprise sur abandon
    [Documentation]  Permet de vérifier le bon fonctionnement de l'ajout d'une reprise sur abandon

    # On ajoute une reprise sur abandon
    &{reprise_abandon}=  Create Dictionary
    ...  statut=En cours
    ...  etat=1 - Phase préliminaire
    ...  datecreation=${DATE_FORMAT_DD/MM/YYYY}
    ...  dateconvocationvisite1=28/05/2024
    ...  dateconstatpv1=28/05/2024
    ...  descriptionpv1=NON
    ...  personnepresentepv1=BIBI
    ...  datenotificationpv1=28/05/2024
    ...  debutaffichage1pv1=28/05/2024
    ...  finaffichage1pv1=28/05/2024
    ...  debutaffichage2pv1=28/05/2024
    ...  finaffichage2pv1=28/05/2024
    ...  debutaffichage3pv1=28/05/2024
    ...  finaffichage3pv1=28/05/2024
    ...  dateconvocationvisite2=28/05/2024
    ...  dateconstatpv2=28/05/2024
    ...  descriptionpv2=NON
    ...  personnepresentepv2=BIBI
    ...  datenotificationpv2=28/05/2024
    ...  debutaffichagepv2=28/05/2024
    ...  finaffichagepv2=28/05/2024
    ...  datedeliberation=28/05/2024
    ...  numrefdeliberation=CFGRPFDOF242
    ...  deliberation=p-concession-1.jpg
    ...  datearrete=28/05/2024
    ...  numrefarrete=CFGRPFDOF564
    ...  arrete=p-concession-1.jpg
    ...  datearretedebut=28/05/2024
    ...  datearretefin=30/05/2024

    Depuis le formulaire d'ajout d'une reprise sur abandon  ${concession01.id}
    Select From List By Label  css=#statut  choisir statut
    Select From List By Label  css=#etat  choisir état

    Click On Submit Button In Subform

    Error Message Should Contain  Le champ date de création est obligatoire
    Error Message Should Contain  Le champ état est obligatoire
    Error Message Should Contain  Le champ statut est obligatoire
    Error Message Should Contain  SAISIE NON ENREGISTRÉE

    Depuis le formulaire d'ajout d'une reprise sur abandon  ${concession01.id}
    Saisir les valeurs dans le formulaire d'une reprise sur abandon  ${reprise_abandon}

    Click On Submit Button In Subform

    Valid Message Should Contain  Vos modifications ont bien été enregistrées.

    Verifier les valeurs enregistrés dans le formulaire de consultation de l'objet  ${reprise_abandon}

    ${reprise_abandon.id} =  Get Value  css=#sformulaire #reprise_abandon
    Set Suite Variable  ${reprise_abandon}

Vérification de la modification d'une reprise sur abandon
    [Documentation]  Permet de vérifier le bon fonctionnement de la modification d'une reprise sur abandon

    # On ajoute une reprise sur abandon
    &{update_reprise_abandon}=  Create Dictionary
    ...  statut=Annulée
    ...  etat=2 - Convocation première visite
    ...  datecreation=28/05/2025
    ...  dateconvocationvisite1=28/05/2025
    ...  dateconstatpv1=28/05/2025
    ...  descriptionpv1=PLOP
    ...  personnepresentepv1=BLABAL
    ...  datenotificationpv1=28/05/2025
    ...  debutaffichage1pv1=28/05/2025
    ...  finaffichage1pv1=28/05/2025
    ...  debutaffichage2pv1=28/05/2025
    ...  finaffichage2pv1=28/05/2025
    ...  debutaffichage3pv1=28/05/2025
    ...  finaffichage3pv1=28/05/2025
    ...  dateconvocationvisite2=28/05/2025
    ...  dateconstatpv2=28/05/2025
    ...  descriptionpv2=PLOP
    ...  personnepresentepv2=BLABLA
    ...  datenotificationpv2=28/05/2025
    ...  debutaffichagepv2=28/05/2025
    ...  finaffichagepv2=28/05/2025
    ...  datedeliberation=28/05/2024
    ...  numrefdeliberation=CFGRPFDOF243
    ...  deliberation=p-concession-1.jpg
    ...  datearrete=28/05/2024
    ...  numrefarrete=CFGRPFDOF564
    ...  arrete=p-concession-1.jpg
    ...  datearretedebut=28/05/2024
    ...  datearretefin=30/05/2024

    Depuis le formulaire de modification d'une reprise sur abandon  ${reprise_abandon.id}

    Saisir les valeurs dans le formulaire d'une reprise sur abandon  ${update_reprise_abandon}

    Click On Submit Button In Subform

    Valid Message Should Contain  Vos modifications ont bien été enregistrées.

    Verifier les valeurs enregistrés dans le formulaire de consultation de l'objet  ${update_reprise_abandon}

Vérification de la suppression d'une reprise sur abandon
    [Documentation]  Permet de vérifier le bon fonctionnement de la suppression d'une reprise sur abandon

    Depuis le formulaire de suppression d'une reprise sur abandon  ${reprise_abandon.id}

    Click On Submit Button In Subform

    Valid Message Should Contain  La suppression a été correctement effectuée.


Vérification du bon fonctionnement du lien entre courrier et la reprise sur abandon
    [Documentation]  Permet de vérifier que la liaison avec courrier est correctement implémentée
    ...  et que les champs de fusion sont bien appliqués.

    # On ajoute une reprise sur abandon
    &{reprise_abandon}=  Create Dictionary
    ...  statut=En cours
    ...  etat=1 - Phase préliminaire
    ...  effectuee=t
    ...  datecreation=${DATE_FORMAT_DD/MM/YYYY}
    ...  dateconvocationvisite1=21/05/2024
    ...  dateconstatpv1=22/05/2024
    ...  heureconstatpv1=01:00:00
    ...  descriptionpv1=descriptionpv1
    ...  personnepresentepv1=champpersonnepresentepv1
    ...  datenotificationpv1=23/05/2024
    ...  debutaffichage1pv1=24/05/2024
    ...  finaffichage1pv1=25/05/2024
    ...  debutaffichage2pv1=26/05/2024
    ...  finaffichage2pv1=27/05/2024
    ...  debutaffichage3pv1=28/05/2024
    ...  finaffichage3pv1=29/05/2024
    ...  dateconvocationvisite2=30/05/2024
    ...  dateconstatpv2=01/06/2024
    ...  heureconstatpv2=12:00:00
    ...  descriptionpv2=descriptionpv2
    ...  personnepresentepv2=champpersonnepresentepv2
    ...  datenotificationpv2=02/06/2024
    ...  debutaffichagepv2=03/06/2024
    ...  finaffichagepv2=04/06/2024
    ...  datedeliberation=28/05/2024
    ...  numrefdeliberation=CFGRPFDOF242
    ...  deliberation=p-concession-1.jpg
    ...  datearrete=28/05/2024
    ...  numrefarrete=CFGRPFDOF564
    ...  arrete=p-concession-1.jpg
    ...  datearretedebut=28/05/2024
    ...  datearretefin=30/05/2024
    ${reprise_abandon.id} =  Ajouter une reprise sur abandon   ${reprise_abandon}  ${concession01.id}

    Depuis le formulaire d'ajout d'un courrier dans le contexte de la concession  ${concession01.id}
    # On sélectionne le contexte reprise sur abandon sur le formulaire d'ajout du courrier
    Select From List By Label  css=#contexte  reprise sur abandon

    Wait Until Keyword Succeeds  ${TIMEOUT}  ${RETRY_INTERVAL}  Element Should Be Visible  css=#reprise_abandon
    Select From List By Label  css=#reprise_abandon  id ${reprise_abandon.id} - du ${reprise_abandon.datecreation}
    Select From List By Label  css=#lettretype  reprise_abandon_pv_convo_1 Pv de convocation
    Click On Submit Button

    # On vérifie que l'édition du courrier contient bien les informations de la reprise sélectionnée
    @{champs_fusion} =  Create List
    ...  ${reprise_abandon.id}
    ...  ${concession01.id}
    ...  ${reprise_abandon.statut}
    ...  ${reprise_abandon.etat}
    ...  ${reprise_abandon.datecreation}
    ...  ${reprise_abandon.effectuee}
    ...  ${reprise_abandon.dateconvocationvisite1}
    ...  ${reprise_abandon.dateconstatpv1}
    ...  ${reprise_abandon.heureconstatpv1}
    ...  ${reprise_abandon.descriptionpv1}
    ...  ${reprise_abandon.personnepresentepv1}
    ...  ${reprise_abandon.datenotificationpv1}
    ...  ${reprise_abandon.debutaffichage1pv1}
    ...  ${reprise_abandon.finaffichage1pv1}
    ...  ${reprise_abandon.debutaffichage2pv1}
    ...  ${reprise_abandon.finaffichage2pv1}
    ...  ${reprise_abandon.debutaffichage3pv1}
    ...  ${reprise_abandon.finaffichage3pv1}
    ...  ${reprise_abandon.dateconvocationvisite2}
    ...  ${reprise_abandon.dateconstatpv2}
    ...  ${reprise_abandon.heureconstatpv2}
    ...  ${reprise_abandon.descriptionpv2}
    ...  ${reprise_abandon.personnepresentepv2}
    ...  ${reprise_abandon.datenotificationpv2}
    ...  ${reprise_abandon.debutaffichagepv2}
    ...  ${reprise_abandon.finaffichagepv2}
    ...  ${reprise_abandon.datedeliberation}
    ...  ${reprise_abandon.numrefdeliberation}
    ...  ${reprise_abandon.datearrete}
    ...  ${reprise_abandon.numrefarrete}
    ...  ${reprise_abandon.datearretedebut}
    ...  ${reprise_abandon.datearretefin}

    Wait Until Keyword Succeeds  ${TIMEOUT}  ${RETRY_INTERVAL}  Click On SubForm Portlet Action  courrier  pdf-edition  new_window
    Vérifier Que Le PDF Contient Des Strings  ${OM_PDF_TITLE}  ${champs_fusion}

Vérification de l'affichage du champ Suivi sur la fiche de l'emplacement lors de l'ajout d'une reprise sur abandon
    [Documentation]  Sur la fiche de l'emplacement, le bloc abandon permet d'avoir des informations
    ...  sur la reprise sur abandon de l'emplacement. Le but est de vérifier que le champ de suivi
    ...  n'est pas présent lorsqu'il n'y a pas de reprise sur abandon sur l'emplacement puis que le
    ...  champ suivi apparaît sur la fiche de l'emplacement et que les champs abandon et date abandon
    ...  sont masqués.

    Depuis la page d'accueil  admin  admin

    Depuis le contexte de la concession  ${concession02.id}

    Wait Until Keyword Succeeds  ${TIMEOUT}  ${RETRY_INTERVAL}  Element Should Not Be Visible  css=#suivi_reprise
    Wait Until Keyword Succeeds  ${TIMEOUT}  ${RETRY_INTERVAL}  Element Should Be Visible  css=#abandon
    Wait Until Keyword Succeeds  ${TIMEOUT}  ${RETRY_INTERVAL}  Element Should Be Visible  css=#date_abandon

    &{reprise_abandon}=  Create Dictionary
    ...  statut=En cours
    ...  etat=1 - Phase préliminaire
    ...  effectuee=t
    ...  datecreation=${DATE_FORMAT_DD/MM/YYYY}
    ...  dateconvocationvisite1=21/05/2024
    ...  dateconstatpv1=22/05/2024
    ...  heureconstatpv1=01:00:00
    ...  descriptionpv1=descriptionpv1
    ...  personnepresentepv1=champpersonnepresentepv1
    ...  datenotificationpv1=23/05/2024
    ...  debutaffichage1pv1=24/05/2024
    ...  finaffichage1pv1=25/05/2024
    ...  debutaffichage2pv1=26/05/2024
    ...  finaffichage2pv1=27/05/2024
    ...  debutaffichage3pv1=28/05/2024
    ...  finaffichage3pv1=29/05/2024
    ...  dateconvocationvisite2=30/05/2024
    ...  dateconstatpv2=01/06/2024
    ...  heureconstatpv2=12:00:00
    ...  descriptionpv2=descriptionpv2
    ...  personnepresentepv2=champpersonnepresentepv2
    ...  datenotificationpv2=02/06/2024
    ...  debutaffichagepv2=03/06/2024
    ...  finaffichagepv2=04/06/2024
    ${reprise_abandon.id} =  Ajouter une reprise sur abandon   ${reprise_abandon}  ${concession02.id}

    Depuis le contexte de la concession  ${concession02.id}

    Wait Until Keyword Succeeds  ${TIMEOUT}  ${RETRY_INTERVAL}  Element Should Be Visible  css=#suivi_reprise
    Wait Until Keyword Succeeds  ${TIMEOUT}  ${RETRY_INTERVAL}  Element Should Not Be Visible  css=#abandon
    Wait Until Keyword Succeeds  ${TIMEOUT}  ${RETRY_INTERVAL}  Element Should Not Be Visible  css=#date_abandon

    Element Should Contain  css=#suivi_reprise  Reprise n°${reprise_abandon.id} du ${reprise_abandon.datecreation} (${reprise_abandon.statut}) - ${reprise_abandon.etat}

    Click On Form Portlet Action  concession  modifier
    La page ne doit pas contenir d'erreur