*** Settings ***
Resource  resources/resources.robot
Suite Setup  For Suite Setup
Suite Teardown  For Suite Teardown
Documentation  Permet de vérifier le bon fonctionnement de l'abstracteur geocimetiere
...  en utilisant un connecteur de test factice.


*** Test Cases ***
Constitution du jeu de données
    [Documentation]  Permet de constituer le jeu de données qui servira pour les prochains scénarios.
    #
    Depuis la page d'accueil  admin  admin
    Supprimer le paramètre  option_localisation
    Ajouter le paramètre depuis le menu  option_localisation  sig_externe  null
    Copy File  ..${/}tests${/}binary_files${/}geocimetiere_test${/}sig.inc.php  ..${/}dyn${/}
    #
    Set Suite Variable  ${testid}  220
    #
    &{cimetiere01} =  Create Dictionary
    ...  cimetierelib=CIMETIERE${testid}-01
    ...  adresse1=RUE DE LA REPUBLIQUE
    ...  adresse2=
    ...  cp=99607
    ...  ville=LIBREVILLE
    ...  observations=
    ${cimetiere01.id} =  Ajouter le cimetière  ${cimetiere01}
    Set Suite Variable  ${cimetiere01}
    #
    &{zone01_cim01} =  Create Dictionary
    ...  cimetiere=${cimetiere01.cimetierelib}
    ...  zonetype=CARRE
    ...  zonelib=Z${testid}-01
    ${zone01_cim01.id} =  Ajouter la zone  ${zone01_cim01}
    Set Suite Variable  ${zone01_cim01}
    #
    &{voie01_zone01_cim01} =  Create Dictionary
    ...  zone=${zone01_cim01.zonetype} ${zone01_cim01.zonelib} (${zone01_cim01.cimetiere})
    ...  voietype=ALLEE
    ...  voielib=V${testid}-01
    ${voie01_zone01_cim01.id} =  Ajouter la voie  ${voie01_zone01_cim01}
    Set Suite Variable  ${voie01_zone01_cim01}

    &{concession01} =  Create Dictionary
    ...  famille=DURAND${testid}
    ...  numero=17
    ...  cimetierelib=${cimetiere01.cimetierelib}
    ...  zonelib=${zone01_cim01.zonetype} ${zone01_cim01.zonelib}
    ...  voielib=${voie01_zone01_cim01.voietype} ${voie01_zone01_cim01.voielib}
    ${concession01.id} =  Ajouter la concession  ${concession01}
    Set Suite Variable  ${concession01}

    &{concession02} =  Create Dictionary
    ...  famille=DUPONT${testid}
    ...  numero=18
    ...  cimetierelib=${cimetiere01.cimetierelib}
    ...  zonelib=${zone01_cim01.zonetype} ${zone01_cim01.zonelib}
    ...  voielib=${voie01_zone01_cim01.voietype} ${voie01_zone01_cim01.voielib}
    ${concession02.id} =  Ajouter la concession  ${concession02}
    Set Suite Variable  ${concession02}

Vérification du bon fonctionnement du sig externe
    [Documentation]  Permet de vérifier que l'abstracteur et le connecteur fonctionne correctement
    ...  La méthode qui doit être implémentée est redirection_web

    Remove File  ..${/}dyn${/}sig.inc.php
    Depuis la page d'accueil  admin  admin

    Element Should Contain  css=.widget_localisation>.widget-content-wrapper>.widget-content  Erreur de configuration du SIG. Veuillez contacter votre administrateur. Pas de SIG configuré pour la collectivité

    Depuis le listing des concessions
    Error Message Should Be  Erreur de configuration du SIG. Veuillez contacter votre administrateur. Pas de SIG configuré pour la collectivité

    Depuis le contexte de la concession  ${concession01.id}
    Error Message Should Be  Erreur de configuration du SIG. Veuillez contacter votre administrateur. Pas de SIG configuré pour la collectivité

    Copy File  ..${/}tests${/}binary_files${/}geocimetiere_test${/}sig.inc.php  ..${/}dyn${/}
    Depuis la page d'accueil  admin  admin
    # Vérification du lien généré sur le tableau de bord
    ${attr_href_tdb} =  Get Element Attribute  css=div.widget_localisation > div.widget-content-wrapper > div.widget-content > a  href
    Element Should Contain  css=div.widget_localisation > div.widget-content-wrapper > div.widget-content > a  ACCÉDER AU SIG
    Should Be Equal  http://localhost/  ${attr_href_tdb}

    # Vérification du lien généré dans le listing.
    Depuis le listing des concessions
    Use Simple Search  famille  ${concession01.famille}
    ${attr_href_01} =  Get Element Attribute  css=#action-tab-concession-left-localiser-sig-externe-${concession01.id}  href
    Should Be Equal  http://localhost/1/${concession01.id}  ${attr_href_01}
    Use Simple Search  famille  ${concession02.famille}
    ${attr_href_02} =  Get Element Attribute  css=#action-tab-concession-left-localiser-sig-externe-${concession02.id}  href
    Should Be Equal  http://localhost/1/${concession02.id}  ${attr_href_02}

    # Vérification du lien généré dans la fiche de l'emplacement.
    Depuis le contexte de la concession  ${concession01.id}
    Element Should Contain  css=a.button  ACCÉDER AU SIG
    ${attr_href_01} =  Get Element Attribute  css=a.button.button-secondary  href
    Should Be Equal  http://localhost/1/${concession01.id}  ${attr_href_01}

    Depuis le contexte de la concession  ${concession02.id}
    Element Should Contain  css=a.button  ACCÉDER AU SIG
    ${attr_href_02} =  Get Element Attribute  css=a.button.button-secondary  href
    Should Be Equal  http://localhost/1/${concession02.id}  ${attr_href_02}

    Depuis le listing des cimetières
    Use Simple Search  id  ${cimetiere01.id}
    ${attr_href_cim_listing} =  Get Element Attribute  css=#action-tab-cimetiere-left-localiser-sig-externe-${cimetiere01.id}  href
    Should Be Equal  http://localhost/2/${cimetiere01.id}  ${attr_href_cim_listing}
    Depuis le contexte du cimetière  ${cimetiere01.cimetierelib}
    ${attr_href_cim_fiche} =  Get Element Attribute  css=#lien_sig_externe  href
    Should Be Equal  http://localhost/2/${cimetiere01.id}  ${attr_href_cim_fiche}

    Depuis le listing des zones
    Use Simple Search  id  ${zone01_cim01.id}
    ${attr_href_zone_listing} =  Get Element Attribute  css=#action-tab-zone-left-localiser-sig-externe-${zone01_cim01.id}  href
    Should Be Equal  http://localhost/3/${zone01_cim01.id}  ${attr_href_zone_listing}
    Depuis le contexte de la zone  ${zone01_cim01.id}
    ${attr_href_zone_fiche} =  Get Element Attribute  css=#lien_sig_externe  href
    Should Be Equal  http://localhost/3/${zone01_cim01.id}  ${attr_href_zone_fiche}

    Depuis le listing des voies
    Use Simple Search  id  ${voie01_zone01_cim01.id}
    ${attr_href_voie_listing} =  Get Element Attribute  css=#action-tab-voie-left-localiser-sig-externe-${voie01_zone01_cim01.id}  href
    Should Be Equal  http://localhost/4/${voie01_zone01_cim01.id}  ${attr_href_voie_listing}
    Depuis le contexte de la voie  ${voie01_zone01_cim01.id}
    ${attr_href_voie_fiche} =  Get Element Attribute  css=#lien_sig_externe  href
    Should Be Equal  http://localhost/4/${voie01_zone01_cim01.id}  ${attr_href_voie_fiche}

Désactivation du SIG externe
    [Documentation]  Permet de rétablir les paramètres par défaut

    Supprimer le paramètre  option_localisation
    Ajouter le paramètre depuis le menu  option_localisation  sig_interne  null
    Remove File  ..${/}dyn${/}sig.inc.php