*** Settings ***
Resource  resources/resources.robot
Suite Setup  For Suite Setup
Suite Teardown  For Suite Teardown
Documentation  Tests sur les natures de défunt paramétrables


*** Test Cases ***
Constitution du jeu de données
    [Documentation]  Jeu de données pour les tests des natures de défunt
    #
    Depuis la page d'accueil  admin  admin
    #
    Set Suite Variable  ${TESTID}  038
    #
    &{cimetiere01} =  Create Dictionary
    ...  cimetierelib=CIMETIERE${TESTID}-01
    ...  adresse1=RUE DE LA REPUBLIQUE
    ...  adresse2=
    ...  cp=99607
    ...  ville=LIBREVILLE
    ...  observations=
    Ajouter le cimetière  ${cimetiere01}
    Set Suite Variable  ${cimetiere01}
    #
    &{zone01_cim01} =  Create Dictionary
    ...  cimetiere=${cimetiere01.cimetierelib}
    ...  zonetype=CARRE
    ...  zonelib=Z${TESTID}-01
    Ajouter la zone  ${zone01_cim01}
    Set Suite Variable  ${zone01_cim01}
    #
    &{voie01_zone01_cim01} =  Create Dictionary
    ...  zone=${zone01_cim01.zonetype} ${zone01_cim01.zonelib} (${zone01_cim01.cimetiere})
    ...  voietype=ALLEE
    ...  voielib=V${TESTID}-01
    Ajouter la voie  ${voie01_zone01_cim01}
    Set Suite Variable  ${voie01_zone01_cim01}
    #
    &{type_de_sepulture_01} =  Create Dictionary
    ...  code=TDS-${TESTID}-01
    ...  libelle=Type de sépulture ${TESTID}-01
    ${type_de_sepulture_01.id} =  Ajouter le *type de sépulture*  ${type_de_sepulture_01}
    Set Suite Variable  ${type_de_sepulture_01}
    #
    &{concession01} =  Create Dictionary
    ...  famille=DUPONT${TESTID}
    ...  numero=1
    ...  cimetierelib=${cimetiere01.cimetierelib}
    ...  zonelib=${zone01_cim01.zonetype} ${zone01_cim01.zonelib}
    ...  voielib=${voie01_zone01_cim01.voietype} ${voie01_zone01_cim01.voielib}
    ...  sepulturetype=${type_de_sepulture_01.libelle}
    ${concession01.id} =  Ajouter la concession  ${concession01}
    Set Suite Variable  ${concession01}
    #
    &{nature_defunt01} =  Create Dictionary
    ...  code=nature_test_${TESTID}
    ...  libelle=Nature Test ${TESTID}
    ...  taille=1.5
    ${nature_defunt01.id} =  Ajouter la *nature de défunt*  ${nature_defunt01}
    Set Suite Variable  ${nature_defunt01}
    #
    &{nature_expiree01} =  Create Dictionary
    ...  code=nature_expiree_${TESTID}
    ...  libelle=Nature Expirée ${TESTID}
    ...  taille=1
    ...  om_validite_debut=01/01/2019
    ...  om_validite_fin=01/01/2020
    ...  is_reductible=false
    ${nature_expiree01.id} =  Ajouter la *nature de défunt*  ${nature_expiree01}
    Set Suite Variable  ${nature_expiree01}
    #
    &{nature_future_reductible01} =  Create Dictionary
    ...  code=nature_future_reductible_${TESTID}
    ...  libelle=Nature Future Réductible ${TESTID}
    ...  taille=1
    ...  om_validite_debut=01/01/2020
    ...  om_validite_fin=01/01/2030
    ...  is_reductible=true
    ${nature_future_reductible01.id} =  Ajouter la *nature de défunt*  ${nature_future_reductible01}
    Set Suite Variable  ${nature_future_reductible01}
    #
    &{nature_non_reductible01} =  Create Dictionary
    ...  code=nature_non_reductible_${TESTID}
    ...  libelle=Nature Non Réductible ${TESTID}
    ...  taille=1
    ...  om_validite_debut=01/01/2020
    ...  om_validite_fin=01/01/2030
    ...  is_reductible=false
    ${nature_non_reductible01.id} =  Ajouter la *nature de défunt*  ${nature_non_reductible01}
    Set Suite Variable  ${nature_non_reductible01}
    #
    &{defunt_non_red} =  Create Dictionary
    ...  titre=Monsieur
    ...  nom=NONRED${TESTID}
    ...  prenom=TEST
    ...  datedeces=31/12/2019
    ...  lieudeces=LIBREVILLE
    ...  nature=${nature_non_reductible01.libelle}
    ...  dateinhumation=01/01/2020
    ${defunt_non_red.id} =  Ajouter le defunt dans le contexte de la concession  ${defunt_non_red}  ${concession01.id}
    Set Suite Variable  ${defunt_non_red}
    #
    &{defunt_red} =  Create Dictionary
    ...  titre=Madame
    ...  nom=REDUCT${TESTID}
    ...  prenom=TEST
    ...  datedeces=31/12/2019
    ...  lieudeces=LIBREVILLE
    ...  nature=${nature_future_reductible01.libelle}
    ...  dateinhumation=01/01/2020
    ${defunt_red.id} =  Ajouter le defunt dans le contexte de la concession  ${defunt_red}  ${concession01.id}
    Set Suite Variable  ${defunt_red}

Vérification de la gestion des natures de défunt
    [Documentation]  Accès au module, présence dans le select défunt, création d'un défunt.
    #
    Depuis la page d'accueil  admin  admin
    #
    Depuis le menu 'Administration & Paramétrage'
    Depuis le listing des *natures de défunt*
    La page ne doit pas contenir d'erreur
    #
    Depuis l'onglet 'défunt' de la concession  ${concession01.id}
    Click On Add Button JS
    ${options} =  Get List Items  css=select#nature
    Should Contain  ${options}  ${nature_defunt01.libelle}
    #
    &{defunt01} =  Create Dictionary
    ...  titre=Monsieur
    ...  nom=DUPONT${TESTID}
    ...  prenom=TEST${TESTID}
    ...  datedeces=01/01/2024
    ...  lieudeces=LIBREVILLE
    ...  nature=${nature_defunt01.libelle}
    Saisir les valeurs dans le formulaire du defunt  ${defunt01}
    Click On Submit Button In Subform
    Valid Message Should Contain In Subform  Vos modifications ont bien été enregistrées.

Vérification de l'exclusion des natures de défunt expirées de la liste déroulante d'un défunt
    [Documentation]  Les natures expirées ne doivent pas apparaître dans le select défunt.
    #
    Depuis la page d'accueil  admin  admin
    #
    Depuis le menu 'Administration & Paramétrage'
    Depuis le listing des *natures de défunt*
    La page ne doit pas contenir d'erreur
    Page Should Not Contain  ${nature_expiree01.libelle}
    Page Should Contain  ${nature_future_reductible01.libelle}
    #
    Depuis l'onglet 'défunt' de la concession  ${concession01.id}
    Click On Add Button JS
    ${options} =  Get List Items  css=select#nature
    Should Not Contain  ${options}  ${nature_expiree01.libelle}
    Should Contain  ${options}  ${nature_future_reductible01.libelle}
    Should Contain  ${options}  ${nature_defunt01.libelle}

Vérification du filtrage des natures réductibles dans les opérations
    [Documentation]  Réduction : seuls les défunts réductibles sont proposés.
    ...  Transfert : tous les défunts sont proposés.
    ...  Inhumation : les natures valides sont dans le select, les expirées non.
    #
    Depuis la page d'accueil  admin  admin
    #
    # Réduction
    &{reduction01} =  Create Dictionary
    ...  date=01/01/2026
    ...  heure=10:00
    ...  emplacement_autocomplete_id=${concession01.id}
    ...  emplacement_autocomplete_search=${concession01.famille}
    ${reduction01.id} =  Ajouter l'opération de réduction sur concession  ${reduction01}
    Set Suite Variable  ${reduction01}
    #
    Depuis l'onglet 'opération défunt' de l'opération de réduction sur concession  ${reduction01.id}
    Click On Add Button
    ${options_reduction} =  Get List Items  css=select#defunt
    Should Contain  ${options_reduction}  REDUCT${TESTID} TEST
    Should Not Contain  ${options_reduction}  NONRED${TESTID} TEST
    #
    # Transfert
    &{concession02} =  Create Dictionary
    ...  famille=TRANSFERT${TESTID}
    ...  numero=2
    ...  cimetierelib=${cimetiere01.cimetierelib}
    ...  zonelib=${zone01_cim01.zonetype} ${zone01_cim01.zonelib}
    ...  voielib=${voie01_zone01_cim01.voietype} ${voie01_zone01_cim01.voielib}
    ...  sepulturetype=${type_de_sepulture_01.libelle}
    ${concession02.id} =  Ajouter la concession  ${concession02}
    Set Suite Variable  ${concession02}
    #
    &{transfert01} =  Create Dictionary
    ...  date=01/01/2026
    ...  heure=10:00
    ...  emplacement_autocomplete_id=${concession01.id}
    ...  emplacement_autocomplete_search=${concession01.famille}
    ...  emplacement_transfert_autocomplete_id=${concession02.id}
    ...  emplacement_transfert_autocomplete_search=${concession02.famille}
    ${transfert01.id} =  Ajouter l'opération de transfert  ${transfert01}
    Set Suite Variable  ${transfert01}
    #
    Depuis l'onglet 'opération défunt' de l'opération de transfert  ${transfert01.id}
    Click On Add Button
    ${options_transfert} =  Get List Items  css=select#defunt
    Should Contain  ${options_transfert}  NONRED${TESTID} TEST
    Should Contain  ${options_transfert}  REDUCT${TESTID} TEST
    #
    # Inhumation
    Depuis le formulaire d'ajout d'une opération d'inhumation sur concession
    ${options_nature} =  Get List Items  css=select#defunt_nature
    Should Contain  ${options_nature}  ${nature_non_reductible01.libelle}
    Should Contain  ${options_nature}  ${nature_future_reductible01.libelle}
    Should Not Contain  ${options_nature}  ${nature_expiree01.libelle}