*** Settings ***
Resource  resources/resources.robot
Suite Setup  For Suite Setup
Suite Teardown  For Suite Teardown
Documentation  Tests sur les courriers


*** Test Cases ***
Constitution du jeu de données
    [Documentation]  Création du jeu de données de base pour les tests de courrier
    #
    Depuis la page d'accueil  admin  admin
    #
    Set Suite Variable  ${testid}  113
    #
    &{cimetiere01} =  Create Dictionary
    ...  cimetierelib=CIMETIERE${testid}-01
    ...  adresse1=RUE DE LA REPUBLIQUE
    ...  adresse2=
    ...  cp=99607
    ...  ville=LIBREVILLE
    ...  observations=
    Ajouter le cimetière  ${cimetiere01}
    Set Suite Variable  ${cimetiere01}
    #
    &{zone01_cim01} =  Create Dictionary
    ...  cimetiere=${cimetiere01.cimetierelib}
    ...  zonetype=CARRE
    ...  zonelib=Z${testid}-01
    Ajouter la zone  ${zone01_cim01}
    Set Suite Variable  ${zone01_cim01}
    #
    &{voie01_zone01_cim01} =  Create Dictionary
    ...  zone=${zone01_cim01.zonetype} ${zone01_cim01.zonelib} (${zone01_cim01.cimetiere})
    ...  voietype=ALLEE
    ...  voielib=V${testid}-01
    Ajouter la voie  ${voie01_zone01_cim01}
    Set Suite Variable  ${voie01_zone01_cim01}
    #
    &{type_de_sepulture_01} =  Create Dictionary
    ...  code=TDS-${testid}-01
    ...  libelle=Type de sépulture ${testid}-01
    ${type_de_sepulture_01.id} =  Ajouter le *type de sépulture*  ${type_de_sepulture_01}
    Set Suite Variable  ${type_de_sepulture_01}
    #
    &{concession01} =  Create Dictionary
    ...  famille=DURAND${testid}
    ...  numero=12
    ...  cimetierelib=${cimetiere01.cimetierelib}
    ...  zonelib=${zone01_cim01.zonetype} ${zone01_cim01.zonelib}
    ...  voielib=${voie01_zone01_cim01.voietype} ${voie01_zone01_cim01.voielib}
    ...  sepulturetype=${type_de_sepulture_01.libelle}
    ${concession01.id} =  Ajouter la concession  ${concession01}
    Set Suite Variable  ${concession01}

Ajout d'un courrier sur une concession
    [Documentation]  Seules les lettres types actives doivent être proposées.
    #
    Depuis la page d'accueil  admin  admin
    #
    # On ajoute un courrier
    &{courrier_merge_fields} =  Create Dictionary
    ...  datecourrier=04/07/2019
    ...  date_en_lettre=04 juillet 2019
    ...  contexte=autre
    ...  lettretype=test_courrier testchampfusioncourrier
    ...  lettretype_id=test_courrier
    ...  objet=plopobjet
    ${courrier_merge_fields.id} =  Ajouter le courrier dans le contexte de la concession  ${courrier_merge_fields}  ${concession01.id}
    Set Suite Variable  ${courrier_merge_fields}
    #
    Ajouter la lettre-type depuis le menu  test113concessionscourrier  test113concessionscourrier actif  test113concessionscourrier  test113concessionscourrier  Requête COURRIER (req_cou)  true
    #
    Depuis l'onglet 'courrier' de la concession  ${concession01.id}
    Click On Add Button JS
    Select From List By Label  css=#contexte  autre
    ${listeRecuperee} =    Get List Items  css=#lettretype
    List Should Contain Value    ${listeRecuperee}  test113concessionscourrier test113concessionscourrier actif
    #
    Modifier la lettre-type  test113concessionscourrier  test113concessionscourrier non actif  null  null  null  false
    #
    Depuis l'onglet 'courrier' de la concession  ${concession01.id}
    Click On Add Button JS
    Select From List By Label  css=#contexte  autre
    ${listeRecuperee} =    Get List Items  css=#lettretype
    List Should Not Contain Value    ${listeRecuperee}  test113concessionscourrier test113concessionscourrier non actif

    # On vérifie que les lettres types avec plus de 40 caractères sont bien ajoutés
    # De plus, un champ de fusion est ajouté pour la vérification de la finalisation
    Ajouter la lettre-type depuis le menu  test dun long libelle avec plein de caractere pour tester lajout  test dun long libelle avec plein de caractere pour tester lajout actif  test dun long libelle avec plein de caractere pour tester lajout  test dun long libelle avec plein de caractere pour tester lajout [typeconcession]  Requête COURRIER (req_cou)  true

    Depuis l'onglet 'courrier' de la concession  ${concession01.id}
    Click On Add Button JS
    Select From List By Label  css=#contexte  autre
    Wait Until Keyword Succeeds  ${TIMEOUT}  ${RETRY_INTERVAL}  Select From List By Label  css=#lettretype  test dun long libelle avec plein de caractere pour test dun long libelle avec plein de caractere pour tester lajout actif

    Click On Submit Button
    Valid Message Should Contain  Vos modifications ont bien été enregistrées.
    La page ne doit pas contenir d'erreur

    # Finalisation du courrier
    Portlet Action Should Be In SubForm  courrier  finalise
    Click On Subform Portlet Action  courrier  finalise
    # Absence des actions de modification et de suppression après finalisation
    Portlet Action Should Not Be In SubForm  courrier  modifier
    Portlet Action Should Not Be In SubForm  courrier  supprimer

    ${concession_new_values} =  Create Dictionary
    ...  typeconcession=Familiale

    # On vérifie que le courrier type ne contient aucune donnée pour le champ de fusion [typeconcession]
    Wait Until Keyword Succeeds  ${TIMEOUT}  ${RETRY_INTERVAL}  Click On SubForm Portlet Action  courrier  pdf-edition  new_window
    ${contenu_pdf} =  Create List  ${concession_new_values.typeconcession}
    Vérifier Que Le PDF Ne Contient Pas Des Strings  ${OM_PDF_TITLE}  ${contenu_pdf}

    # On modifie le type de concession afin de faire apparaitre un champ sur la lettre-type, uniquement APRÈS définalisation/finalisation
    Modifier la concession  ${concession01.id}  ${concession_new_values}
    Depuis l'onglet 'courrier' de la concession  ${concession01.id}
    Wait Until Keyword Succeeds  ${TIMEOUT}  ${RETRY_INTERVAL}  Click Element  link:test dun long libelle avec plein de caractere pour

    # Le type de concession est modifié, le champ de fusion n'apparait toujours pas
    Wait Until Keyword Succeeds  ${TIMEOUT}  ${RETRY_INTERVAL}  Click On SubForm Portlet Action  courrier  pdf-edition  new_window
    Vérifier Que Le PDF Ne Contient Pas Des Strings  ${OM_PDF_TITLE}  ${contenu_pdf}

    # Définalisation, finalisation
    Click On Subform Portlet Action  courrier  definalise
    Click On Subform Portlet Action  courrier  finalise

    # Après l'action de finalisation/définalisation, le champ apparait
    Wait Until Keyword Succeeds  ${TIMEOUT}  ${RETRY_INTERVAL}  Click On SubForm Portlet Action  courrier  pdf-edition  new_window
    Vérifier Que Le PDF Contient Des Strings  ${OM_PDF_TITLE}  ${contenu_pdf}

    # Définalisation
    Click On Subform Portlet Action  courrier  definalise
    # Disparition des actions de modification et de suppression après définalisation
    Portlet Action Should Be In SubForm  courrier  finalise
    Portlet Action Should Be In SubForm  courrier  modifier
    Portlet Action Should Be In SubForm  courrier  supprimer

    # Reset du type de concession et de la lettre-type
    ${concession_new_values} =  Create Dictionary
    ...  typeconcession=
    Modifier la concession  ${concession01.id}  ${concession_new_values}
    Modifier la lettre-type  test dun long libelle avec plein de caractere pour  test dun long libelle avec plein de caractere pour tester lajout actif  test dun long libelle avec plein de caractere pour tester lajout  test dun long libelle avec plein de caractere pour tester lajout  Requête COURRIER (req_cou)  true

Vérification du bon fonctionnement des champs de fusion de courrier
    [Documentation]  ...
    Depuis la page d'accueil  admin  admin
    Depuis le listing des lettres-types
    # On vérifie que les champs de fusion fonctionnent
    Depuis l'onglet 'courrier' de la concession  ${concession01.id}
    Wait Until Keyword Succeeds  ${TIMEOUT}  ${RETRY_INTERVAL}  Click Element  link:test_courrier
    Click On SubForm Portlet Action  courrier  pdf-edition  new_window
    ${contenu_pdf} =  Create List  ${courrier_merge_fields.datecourrier}  ${courrier_merge_fields.lettretype_id}  ${courrier_merge_fields.date_en_lettre}  ${courrier_merge_fields.objet}
    Vérifier Que Le PDF Contient Des Strings  ${OM_PDF_TITLE}  ${contenu_pdf}