*** Settings ***
Resource  resources/resources.robot
Suite Setup  For Suite Setup
Suite Teardown  For Suite Teardown
Documentation  Tests sur les défunts


*** Test Cases ***
Constitution du jeu de données
    [Documentation]  Création du jeu de données de base pour les tests de défunt
    #
    Depuis la page d'accueil  admin  admin
    #
    Set Suite Variable  ${TESTID}  111
    #
    &{cimetiere01} =  Create Dictionary
    ...  cimetierelib=CIMETIERE${TESTID}-01
    ...  adresse1=RUE DE LA REPUBLIQUE
    ...  adresse2=
    ...  cp=99607
    ...  ville=LIBREVILLE
    ...  observations=
    Ajouter le cimetière  ${cimetiere01}
    Set Suite Variable  ${cimetiere01}
    #
    &{zone01_cim01} =  Create Dictionary
    ...  cimetiere=${cimetiere01.cimetierelib}
    ...  zonetype=CARRE
    ...  zonelib=Z${TESTID}-01
    Ajouter la zone  ${zone01_cim01}
    Set Suite Variable  ${zone01_cim01}
    #
    &{voie01_zone01_cim01} =  Create Dictionary
    ...  zone=${zone01_cim01.zonetype} ${zone01_cim01.zonelib} (${zone01_cim01.cimetiere})
    ...  voietype=ALLEE
    ...  voielib=V${TESTID}-01
    Ajouter la voie  ${voie01_zone01_cim01}
    Set Suite Variable  ${voie01_zone01_cim01}
    #
    &{type_de_sepulture_01} =  Create Dictionary
    ...  code=TDS-${TESTID}-01
    ...  libelle=Type de sépulture ${TESTID}-01
    ${type_de_sepulture_01.id} =  Ajouter le *type de sépulture*  ${type_de_sepulture_01}
    Set Suite Variable  ${type_de_sepulture_01}
    #
    &{concession01} =  Create Dictionary
    ...  famille=DURAND${TESTID}
    ...  numero=12
    ...  cimetierelib=${cimetiere01.cimetierelib}
    ...  zonelib=${zone01_cim01.zonetype} ${zone01_cim01.zonelib}
    ...  voielib=${voie01_zone01_cim01.voietype} ${voie01_zone01_cim01.voielib}
    ...  sepulturetype=${type_de_sepulture_01.libelle}
    ${concession01.id} =  Ajouter la concession  ${concession01}
    Set Suite Variable  ${concession01}

    &{concession_defunt_lock} =  Create Dictionary
    ...  famille=harald le first
    ...  numero=149
    ...  complement=A
    ...  cimetierelib=${cimetiere01.cimetierelib}
    ...  zonelib=${zone01_cim01.zonetype} ${zone01_cim01.zonelib}
    ...  voielib=${voie01_zone01_cim01.voietype} ${voie01_zone01_cim01.voielib}
    ...  nature_emplacement=concession
    ...  typeconcession=Familiale
    ...  terme=temporaire
    ...  duree=20
    ...  datevente=20/03/2020
    ...  emplacement_date_terme=20/03/2040
    ...  duree_lettre=vingt
    ...  sepulturetype=${type_de_sepulture_01.libelle}
    ${concession_defunt_lock.id} =  Ajouter la concession  ${concession_defunt_lock}
    Set Suite Variable  ${concession_defunt_lock}
    Set Suite Variable  ${concession_defunt_lock.id}

    &{concession_defunt_transfert} =  Create Dictionary
    ...  famille=harald le first
    ...  numero=140
    ...  complement=A
    ...  cimetierelib=${cimetiere01.cimetierelib}
    ...  zonelib=${zone01_cim01.zonetype} ${zone01_cim01.zonelib}
    ...  voielib=${voie01_zone01_cim01.voietype} ${voie01_zone01_cim01.voielib}
    ...  nature_emplacement=concession
    ...  typeconcession=Familiale
    ...  terme=temporaire
    ...  duree=20
    ...  datevente=20/03/2020
    ...  emplacement_date_terme=20/03/2040
    ...  duree_lettre=vingt
    ...  sepulturetype=${type_de_sepulture_01.libelle}
    ${concession_defunt_transfert.id} =  Ajouter la concession  ${concession_defunt_transfert}
    Set Suite Variable  ${concession_defunt_transfert}

    &{concession05} =  Create Dictionary
    ...  famille=DUPONT${TESTID}04
    ...  numero=14
    ...  complement=A
    ...  cimetierelib=${cimetiere01.cimetierelib}
    ...  zonelib=${zone01_cim01.zonetype} ${zone01_cim01.zonelib}
    ...  voielib=${voie01_zone01_cim01.voietype} ${voie01_zone01_cim01.voielib}
    ...  nature_emplacement=concession
    ...  typeconcession=Familiale
    ...  terme=temporaire
    ...  duree=20
    ...  datevente=20/03/2020
    ...  emplacement_date_terme=20/03/2040
    ...  duree_lettre=vingt
    ...  sepulturetype=${type_de_sepulture_01.libelle}
    ${concession05_id} =  Ajouter la concession  ${concession05}
    Set Suite Variable  ${concession05_id}

Vérification du style des défunts exhumés dans le listing
    [Documentation]  Ce test case permet de verifier le style des défunts dans le listing
    ...  des défunts.

    &{defunt_exhume} =  Create Dictionary
    ...  titre=Monsieur
    ...  nom=harald le trois
    ...  prenom=sud
    ...  datenaissance=01/01/1970
    ...  lieunaissance=ARLES
    ...  datedeces=25/05/2017
    ...  lieudeces=LIBREVILLE
    ...  exhumation=Oui
    ...  dateexhumation=01/01/2020
    ...  nature=cercueil
    ${defunt_exhume.id} =  Ajouter le defunt dans le contexte de la concession  ${defunt_exhume}  ${concession01.id}

    Depuis l'onglet 'défunt' de la concession  ${concession01.id}
    Element Should Contain  css=tr.tab-data.defunt-exhume  ${defunt_exhume.id}

Vérification du blocage des actions lorsque le défunt est verrouillé
    [Documentation]  Ce test case permet de verifier qu'un defunt verouillé peut
    ...  etre consulter mais pas modifier ni supprimer
    
    # On ajoute le defunt a verouiller
    &{defunt_lock} =  Create Dictionary
    ...  titre=Monsieur
    ...  nom=harald le deux
    ...  prenom=nord
    ...  datenaissance=01/01/1970
    ...  lieunaissance=ARLES
    ...  datedeces=25/05/2017
    ...  lieudeces=LIBREVILLE
    ...  parente=LOLO
    ...  nature=cercueil
    ${defunt_lock.id} =  Ajouter le defunt dans le contexte de la concession  ${defunt_lock}  ${concession_defunt_lock.id}
    Set Suite Variable  ${defunt_lock}
    Set Suite Variable  ${defunt_lock.id}
    
    ${nom_prenom_defunt_to_transfert} =  Convert To Upper Case  ${defunt_lock.nom} ${defunt_lock.prenom}

    # On ajoute l'operation afin de verouiller le defunt
    &{operation_lock} =  Create Dictionary
    ...  date=${DATE_FORMAT_DD/MM/YYYY}
    ...  heure=09:00:00
    ...  emplacement_autocomplete_search=(${concession_defunt_lock.id})
    ...  emplacement_autocomplete_id=${concession_defunt_lock.id}
    ...  emplacement_transfert_autocomplete_search=(${concession_defunt_transfert.id})
    ...  emplacement_transfert_autocomplete_id=${concession_defunt_transfert.id}
    ${operation_lock.id} =  Ajouter l'opération de transfert  ${operation_lock}

    Ajouter un défunt sur l'opération de transfert  ${operation_lock.id}  ${nom_prenom_defunt_to_transfert}

    Depuis le contexte du défunt dans la concession  ${concession_defunt_lock.id}  ${defunt_lock.id}
    # On verifie que les actions pour un defunt verouiller soit limité
    Portlet Action Should Not Be In Form  defunt  modifier
    Portlet Action Should Not Be In Form  defunt  supprimer

Vérification du style des défunts verouillés dans le listing

    Depuis l'onglet 'défunt' de la concession  ${concession_defunt_lock.id}
    Element Should Contain  css=tr.tab-data.defunt-locked  ${defunt_lock.id}

Vérification du bon fonctionnement du champ de fusion [emplacement.defunts]
    [Documentation]  ...
    Depuis la page d'accueil  admin  admin
    #
    Depuis le listing des lettres-types
    # On désactive la lettre type
    Use Simple Search  id  titre_de_recettes
    Click Element  link:titre_de_recettes
    Sleep  5
    ${lettretype_id} =  Get Text  css=#id
    Modifier la lettre-type  ${lettretype_id}  null  null  null  null  false  null  null
    # On copie la lettre type
    Click On Form Portlet Action  om_lettretype  copier  modale
    Click Element  css=.ui-dialog .ui-dialog-buttonset .ui-button-text-only
    Click On Back Button
    # On accède à la copie de la letttre type et on saisit les champs de fusion à tester
    Click Element  link:copie du ${DATE_FORMAT_DD/MM/YYYY}
    Wait Until Keyword Succeeds  ${TIMEOUT}  ${RETRY_INTERVAL}  Click On Form Portlet Action  om_lettretype  modifier
    # On saisit les champs de fusion de defunt
    ${champs_fusions_defunt} =  Set Variable  [emplacement.defunts]
    Saisir la lettre-type  null  null  null  ${champs_fusions_defunt}  null  true  null  null
    Click On Submit Button
    Valid Message Should Contain  Vos modifications ont bien été enregistrées.
    #
    &{defunt01} =  Create Dictionary
    ...  titre=Monsieur
    ...  nom=SUPONT${TESTID}MERGEFIELDS
    ...  prenom=MARCELMERGEFIELDS
    ...  datenaissance=01/01/1970
    ...  lieunaissance=ARLES
    ...  datedeces=25/05/2017
    ...  lieudeces=LIBREVILLE
    ...  parente=LOLO
    ...  nature=cercueil
    Ajouter le defunt dans le contexte de la concession  ${defunt01}  ${concession05_id}
    #
    &{defunt02} =  Create Dictionary
    ...  titre=Monsieur
    ...  nom=LOLA${TESTID}MERGEFIELDS
    ...  prenom=LOLAMERGEFIELDS
    ...  datenaissance=01/04/1981
    ...  lieunaissance=ARLES
    ...  datedeces=25/05/2020
    ...  lieudeces=LIBREVILLE
    ...  parente=LOLO
    ...  nature=cercueil
    Ajouter le defunt dans le contexte de la concession  ${defunt02}  ${concession05_id}
    # On ajoute un courrier
    &{courrier_edition} =  Create Dictionary
    ...  datecourrier=04/07/2019
    ...  contexte=autre
    ...  lettretype=titre_de_recettes copie du ${DATE_FORMAT_DD/MM/YYYY}
    Ajouter le courrier dans le contexte de la concession  ${courrier_edition}  ${concession05_id}
    # On vérifie que les champs de fusion fonctionnent
    Depuis l'onglet 'courrier' de la concession  ${concession05_id}
    Click Element  link:titre_de_recettes
    Wait Until Keyword Succeeds  ${TIMEOUT}  ${RETRY_INTERVAL}  Click On SubForm Portlet Action  courrier  pdf-edition  new_window
    ${contenu_pdf} =  Create List  ${defunt02.prenom}  ${defunt02.nom}  décédé(e) le 25 mai 2020  à ${defunt02.lieudeces}  ${defunt01.prenom}  ${defunt01.nom}  décédé(e) le 25 mai 2017  à ${defunt01.lieudeces}
    Vérifier Que Le PDF Contient Des Strings  ${OM_PDF_TITLE}  ${contenu_pdf}

Vérification de l'indicateur Mort pour la France
    [Documentation]  Ce test vérifie le bon fonctionnement de l'indicateur
    ...  "Mort pour la France" et son affichage via un badge

    Depuis la page d'accueil  admin  admin

    # On ajoute le defunt mort pour la france
    &{defunt_mplf} =  Create Dictionary
    ...  titre=Monsieur
    ...  nom=MPLF${TESTID}
    ...  prenom=HERO${TESTID}
    ...  datenaissance=01/01/1970
    ...  lieunaissance=ARLES
    ...  datedeces=25/05/2017
    ...  lieudeces=LIBREVILLE
    ...  parente=LOLO
    ...  nature=cercueil
    ...  mort_pour_la_france=Oui
    ${defunt_mplf.id} =  Ajouter le defunt dans le contexte de la concession  ${defunt_mplf}  ${concession01.id}

    # On vérifie que le badge s'affiche correctement
    Depuis le contexte de la concession  ${concession01.id}
    Element Should Be Visible  css=#badge_mplf

    &{defunt_modif} =  Create Dictionary
    ...  mort_pour_la_france=Non
    Modifier le défunt dans le contexte de la concession  ${defunt_modif}  ${defunt_mplf.id}  ${concession01.id}

    # On vérifie que le badge ne s'affiche plus
    Depuis le contexte de la concession  ${concession01.id}
    Element Should Not Be Visible  css=#badge_mplf

    # On ajoute un autre defunt mort pour la france
    &{defunt_mplf02} =  Create Dictionary
    ...  titre=Monsieur
    ...  nom=MPLF${TESTID}02
    ...  prenom=HERO${TESTID}02
    ...  datenaissance=01/01/1970
    ...  lieunaissance=ARLES
    ...  datedeces=25/05/2017
    ...  lieudeces=LIBREVILLE
    ...  parente=LOLO
    ...  nature=cercueil
    ...  mort_pour_la_france=Oui
    ${defunt_mplf02.id} =  Ajouter le defunt dans le contexte de la concession  ${defunt_mplf02}  ${concession01.id}

    # On vérifie que le badge s'affiche correctement
    Depuis le contexte de la concession  ${concession01.id}
    Element Should Be Visible  css=#badge_mplf

    &{defunt_modif} =  Create Dictionary
    ...  mort_pour_la_france=Oui
    Modifier le défunt dans le contexte de la concession  ${defunt_modif}  ${defunt_mplf.id}  ${concession01.id}

    # On vérifie que le badge s'affiche toujours
    Depuis le contexte de la concession  ${concession01.id}
    Element Should Be Visible  css=#badge_mplf

Verification du bon fonctionnement des champs de fusion de défunt
    [Documentation]  ...
    Depuis la page d'accueil  admin  admin
    # On désactive l'état défunt
    Depuis le listing des états
    Use Simple Search  id  defunt
    Click Element  link:defunt
    Click On Form Portlet Action  om_etat  modifier
    Saisir l'état  null  null  null  null  null  false  null
    Click On Submit Button
    # On copie l'état
    Click On Form Portlet Action  om_etat  copier  modale
    Click Element  css=.ui-dialog .ui-dialog-buttonset .ui-button-text-only
    Click On Back Button
    # On accède à la copie de l'état et on saisit les champs de fusion à tester
    Click Element  link:copie du ${DATE_FORMAT_DD/MM/YYYY}
    Click On Form Portlet Action  om_etat  modifier
    ${champs_fusions_defunt} =  Set Variable  [defunt.titre] [defunt.nom] [defunt.prenom] [defunt.datenaissance] [defunt.lieunaissance] [defunt.datedeces] [defunt.lieudeces] [defunt.parente] [defunt.nature]
    Saisir l'état  null  null  null  ${champs_fusions_defunt}  null  true  null
    Click On Submit Button
    Valid Message Should Contain  Vos modifications ont bien été enregistrées.
    # On ajoute un défunt
    &{defunt03} =  Create Dictionary
    ...  titre=Monsieur
    ...  nom=LOLA${TESTID}MERGEFIELDS
    ...  prenom=LOLAMERGEFIELDS
    ...  datenaissance=01/04/1981
    ...  lieunaissance=ARLES
    ...  datedeces=25/05/2020
    ...  lieudeces=LIBREVILLE
    ...  parente=LOLO
    ...  nature=cercueil
    ${defunt03.id} =  Ajouter le defunt dans le contexte de la concession  ${defunt03}  ${concession05_id}

    Depuis l'onglet 'défunt' de la concession  ${concession05_id}
    Click Element  css=#action-soustab-defunt-left-etat-defunt-${defunt03.id}
    ${contenu_pdf} =  Create List  ${defunt03.titre}  ${defunt03.nom}  ${defunt03.prenom}  ${defunt03.datenaissance}  ${defunt03.lieunaissance}  ${defunt03.datedeces}  ${defunt03.lieudeces}  ${defunt03.parente}  ${defunt03.nature}
    Vérifier Que Le PDF Contient Des Strings  ${OM_PDF_TITLE}  ${contenu_pdf}

    # On supprime la copie du titre_de_recettes et on réactive le courrier titre_de_recettes pour revenir à un état cohérent
    Depuis le listing des états
    Use Simple Search  id  defunt
    #
    Click Element  link:copie du ${DATE_FORMAT_DD/MM/YYYY}
    Click On Form Portlet Action  om_etat  supprimer
    Click On Submit Button
    Click Element  link:defunt
    Click On Form Portlet Action  om_etat  modifier
    Saisir l'état  null  null  null  null  null  true  null
    Click On Submit Button
    Valid Message Should Contain  Vos modifications ont bien été enregistrées.