*** Settings ***
Resource  resources/resources.robot
Suite Setup  For Suite Setup
Suite Teardown  For Suite Teardown
Documentation  Tests sur les emplacements (concessions, terrains communaux, etc.)


*** Test Cases ***
Constitution du jeu de données
    [Documentation]  Création du jeu de données de base pour les tests d'emplacement
    #
    Depuis la page d'accueil  admin  admin
    #
    Set Suite Variable  ${testid}  110
    #
    &{cimetiere01} =  Create Dictionary
    ...  cimetierelib=CIMETIERE${testid}-01
    ...  adresse1=RUE DE LA REPUBLIQUE
    ...  adresse2=
    ...  cp=99607
    ...  ville=LIBREVILLE
    ...  observations=
    Ajouter le cimetière  ${cimetiere01}
    Set Suite Variable  ${cimetiere01}
    #
    &{zone01_cim01} =  Create Dictionary
    ...  cimetiere=${cimetiere01.cimetierelib}
    ...  zonetype=CARRE
    ...  zonelib=Z${testid}-01
    Ajouter la zone  ${zone01_cim01}
    Set Suite Variable  ${zone01_cim01}
    #
    &{zone02_cim01} =  Create Dictionary
    ...  cimetiere=${cimetiere01.cimetierelib}
    ...  zonetype=ENCLOS
    ...  zonelib=Z${testid}-02
    Ajouter la zone  ${zone02_cim01}
    Set Suite Variable  ${zone02_cim01}
    #
    &{voie01_zone01_cim01} =  Create Dictionary
    ...  zone=${zone01_cim01.zonetype} ${zone01_cim01.zonelib} (${zone01_cim01.cimetiere})
    ...  voietype=ALLEE
    ...  voielib=V${testid}-01
    Ajouter la voie  ${voie01_zone01_cim01}
    Set Suite Variable  ${voie01_zone01_cim01}
    #
    &{voie02_zone01_cim01} =  Create Dictionary
    ...  zone=${zone01_cim01.zonetype} ${zone01_cim01.zonelib} (${zone01_cim01.cimetiere})
    ...  voietype=DIVISION
    ...  voielib=V${testid}-02
    Ajouter la voie  ${voie02_zone01_cim01}
    Set Suite Variable  ${voie02_zone01_cim01}
    #
    &{voie03_zone02_cim01} =  Create Dictionary
    ...  zone=${zone02_cim01.zonetype} ${zone02_cim01.zonelib} (${zone02_cim01.cimetiere})
    ...  voietype=ILOT
    ...  voielib=v${testid}-03
    Ajouter la voie  ${voie03_zone02_cim01}
    Set Suite Variable  ${voie03_zone02_cim01}
    #
    &{voie04_zone02_cim01} =  Create Dictionary
    ...  zone=${zone02_cim01.zonetype} ${zone02_cim01.zonelib} (${zone02_cim01.cimetiere})
    ...  voietype=DIVISION
    ...  voielib=v${testid}-04
    Ajouter la voie  ${voie04_zone02_cim01}
    Set Suite Variable  ${voie04_zone02_cim01}
    #
    &{cimetiere02} =  Create Dictionary
    ...  cimetierelib=CIMETIERE${testid}-02
    ...  adresse1=RUE DE ROME
    ...  adresse2=
    ...  cp=99607
    ...  ville=LIBREVILLE
    ...  observations=
    Ajouter le cimetière  ${cimetiere02}
    Set Suite Variable  ${cimetiere02}
    #
    &{type_de_sepulture_01} =  Create Dictionary
    ...  code=TDS-${testid}-01
    ...  libelle=Type de sépulture ${testid}-01
    ${type_de_sepulture_01.id} =  Ajouter le *type de sépulture*  ${type_de_sepulture_01}
    Set Suite Variable  ${type_de_sepulture_01}
    #
    &{concession01} =  Create Dictionary
    ...  famille=DURAND${testid}
    ...  numero=12
    ...  cimetierelib=${cimetiere01.cimetierelib}
    ...  zonelib=${zone01_cim01.zonetype} ${zone01_cim01.zonelib}
    ...  voielib=${voie02_zone01_cim01.voietype} ${voie02_zone01_cim01.voielib}
    ...  sepulturetype=${type_de_sepulture_01.libelle}
    ${concession01.id} =  Ajouter la concession  ${concession01}
    Set Suite Variable  ${concession01}

    &{concession_nom_intel} =  Create Dictionary
    ...  famille=DUROND${testid}1
    ...  numero=23
    ...  cimetierelib=${cimetiere01.cimetierelib}
    ...  zonelib=${zone01_cim01.zonetype} ${zone01_cim01.zonelib}
    ...  voielib=${voie02_zone01_cim01.voietype} ${voie02_zone01_cim01.voielib}
    ...  sepulturetype=${type_de_sepulture_01.libelle}
    ${concession_nom_intel.id} =  Ajouter la concession  ${concession_nom_intel}
    Set Suite Variable  ${concession_nom_intel}

    &{entreprise01} =  Create Dictionary
    ...  nomentreprise=ENTREPRISE${testid}-01
    ...  pf=Non
    ...  adresse1=12 rue de la République
    ...  adresse2=Parc de la Durance
    ...  cp=99678
    ...  ville=LIBREVILLE
    ...  telephone=00999999999
    Ajouter l'entreprise  ${entreprise01}
    Set Suite Variable  ${entreprise01}

    &{entreprise02} =  Create Dictionary
    ...  nomentreprise=ENTREPRISE${testid}-02
    ...  pf=Non
    ...  adresse1=12 rue de la République
    ...  adresse2=Parc de la Durance
    ...  cp=99678
    ...  ville=LIBREVILLE
    ...  telephone=00999999999
    Ajouter l'entreprise  ${entreprise02}
    Set Suite Variable  ${entreprise02}

TNR fatal modification colonne/ligne type sepulture non lier emplacement
    [Documentation]  Ce test case permet de verifier la non regression
    ...  sur un bug qui a lieu lors de la modification des champs colonne
    ...  et ligne sur un type de sepulture non lier a un emplacement

    &{type_de_sepulture_tnr_fatal} =  Create Dictionary
    ...  code=TDS-${testid}-tnr_fatal
    ...  libelle=Type de sépulture ${testid}-tnr_fatal
    ...  ligne=10
    ...  colonne=10
    ${type_de_sepulture_tnr_fatal.id} =  Ajouter le *type de sépulture*  ${type_de_sepulture_tnr_fatal}

    Go To  ${PROJECT_URL}${OM_ROUTE_FORM}&obj=sepulture_type&action=3&idx=${type_de_sepulture_tnr_fatal.id}
    Click Element  css=#action-form-sepulture_type-modifier
    Input Text  css=#colonne  5
    Input Text  css=#ligne  5
    Click On Submit Button

Recherche du type de sépulture
    [Documentation]  Ce TestCase permet de vérifier le bon fonctionnement de la
    ...  recherche simple sur le champ *type de sépulture* dans le listing
    ...  des concessions.
    Depuis la page d'accueil  admin  admin
    Depuis le listing des concessions
    Use Simple Search  type de sépulture  plop
    Page Should Contain  Aucun enregistrement.
    Use Simple Search  type de sépulture  ${type_de_sepulture_01.libelle}
    Page Should Contain  ${concession01.famille}

Ajout d'une concession
    [Documentation]  Ce test permet simplement de vérifier l'ajout d'une
    ...  concession avec ses informations obligatoires.
    #
    Depuis la page d'accueil  admin  admin
    #
    Depuis le formulaire d'ajout d'une concession
    Le titre de la page doit être  Emplacements > Concession
    Submenu In Menu Should Be Selected  emplacement  concession
    #
    Click On Submit Button
    Error Message Should Contain  Le champ famille est obligatoire
    Error Message Should Contain  Le champ voie est obligatoire
    Error Message Should Contain  Le champ numéro est obligatoire
    Error Message Should Contain  SAISIE NON ENREGISTRÉE
    #
    &{concession02} =  Create Dictionary
    ...  famille=DUPONT${testid}
    ...  numero=14
    ...  cimetierelib=${cimetiere01.cimetierelib}
    ...  zonelib=${zone01_cim01.zonetype} ${zone01_cim01.zonelib}
    ...  voielib=${voie01_zone01_cim01.voietype} ${voie01_zone01_cim01.voielib}
    Saisir les valeurs dans le formulaire de l'emplacement  ${concession02}
    Click On Submit Button
    Valid Message Should Be  Vos modifications ont bien été enregistrées.

Verification de l'option famille obligatoire en cas d'emplacement libre apres modification de l'emplacement
    [Documentation]  Ce test permet de tester si la famille est obligatoire apres avoir créer un
    ...  emplacement libre et qu'apres une modification l'emplacement n'est plus libre.

    Depuis la page d'accueil  admin  admin

    &{concession02} =  Create Dictionary
    ...  cimetierelib=${cimetiere01.cimetierelib}
    ...  zonelib=${zone01_cim01.zonetype} ${zone01_cim01.zonelib}
    ...  voielib=${voie01_zone01_cim01.voietype} ${voie01_zone01_cim01.voielib}
    ...  numero=1001
    ...  libre=Oui
    ${concession02.id} =  Ajouter la concession  ${concession02}

    Depuis le formulaire de modification de la concession  ${concession02.id}

    &{concession02} =  Create Dictionary
    ...  cimetierelib=${cimetiere01.cimetierelib}
    ...  zonelib=${zone01_cim01.zonetype} ${zone01_cim01.zonelib}
    ...  numero=14
    ...  voielib=${voie01_zone01_cim01.voietype} ${voie01_zone01_cim01.voielib}
    ...  libre=Non
    Saisir les valeurs dans le formulaire de l'emplacement  ${concession02}
    Click On Submit Button
    Error Message Should Contain  Le champ famille est obligatoire

    &{concession02} =  Create Dictionary
    ...  cimetierelib=${cimetiere01.cimetierelib}
    ...  zonelib=${zone01_cim01.zonetype} ${zone01_cim01.zonelib}
    ...  numero=14
    ...  voielib=${voie01_zone01_cim01.voietype} ${voie01_zone01_cim01.voielib}
    ...  libre=Non
    ...  famille=Ronaldo
    Saisir les valeurs dans le formulaire de l'emplacement  ${concession02}
    Click On Submit Button
    Valid Message Should Contain  Vos modifications ont bien été enregistrées

Vue sommaire d'un emplacement
    [Documentation]
    #
    Depuis la page d'accueil  admin  admin
    #
    Go To  ${PROJECT_URL}${OM_ROUTE_FORM}&obj=concession&action=12&idx=${concession01.id}
    Wait Until Keyword Succeeds  ${TIMEOUT}  ${RETRY_INTERVAL}  Element Should Contain  css=#form-container  ${concession01.famille}
    La page ne doit pas contenir d'erreur

Vérification du bon fonctionnement des champs de fusion d'emplacement
    [Documentation]  ...
    Depuis la page d'accueil  admin  admin
    #
    Depuis le listing des lettres-types
    # On désactive la lettre type
    Click Element  link:titre_de_recettes
    Sleep  5
    ${lettretype_id} =  Get Text  css=#id
    Modifier la lettre-type  ${lettretype_id}  null  null  null  null  false  null  null
    # On copie la lettre type
    Click On Form Portlet Action  om_lettretype  copier  modale
    Click Element  css=.ui-dialog .ui-dialog-buttonset .ui-button-text-only
    Click On Back Button
    # On accède à la copie de la letttre type et on saisit les champs de fusion à tester
    Click Element  link:copie du ${DATE_FORMAT_DD/MM/YYYY}
    Sleep  2
    Click On Form Portlet Action  om_lettretype  modifier
    ${champs_fusions_emplacement} =  Set Variable  [emplacement.emplacement] [emplacement.nature] [emplacement.numero] [emplacement.complement] [emplacement.voie] [emplacement.famille] [emplacement.typeconcession] [emplacement.terme] [emplacement.duree] [emplacement.datevente] [emplacement.dateterme] [emplacement.duree_lettre] [emplacement.sepulturetype] [emplacement.zonelib]
    Saisir la lettre-type  null  courrier_test_emplacement_${TESTID}  null  ${champs_fusions_emplacement}  null  true  null  null
    Click On Submit Button
    Valid Message Should Contain  Vos modifications ont bien été enregistrées.

    &{concession05} =  Create Dictionary
    ...  famille=DUPONT${testid}04
    ...  numero=14
    ...  complement=A
    ...  cimetierelib=${cimetiere01.cimetierelib}
    ...  zonelib=${zone01_cim01.zonetype} ${zone01_cim01.zonelib}
    ...  voielib=${voie01_zone01_cim01.voietype} ${voie01_zone01_cim01.voielib}
    ...  nature_emplacement=concession
    ...  typeconcession=Familiale
    ...  terme=temporaire
    ...  duree=20
    ...  datevente=20/03/2020
    ...  emplacement_date_terme=20/03/2040
    ...  duree_lettre=vingt
    ...  sepulturetype=${type_de_sepulture_01.libelle}
    ${concession05_id} =  Ajouter la concession  ${concession05}
    Set Suite Variable  ${concession05_id}

    &{concessionnaire_1} =  Create Dictionary
    ...  titre=Monsieur
    ...  nom=MICHEL
    ...  prenom=HENRI
    ...  datenaissance=10/01/1980
    ...  adresse1=12 RUE DE LA RÉPUBLIQUE
    ...  cp=99678
    ...  ville=LIBREVILLE
    Ajouter le concessionnaire dans le contexte de la concession  ${concessionnaire_1}  ${concession05_id}

    &{concessionnaire_2} =  Create Dictionary
    ...  titre=Madame
    ...  nom=MICHEL
    ...  prenom=JO
    ...  datenaissance=11/01/1980
    ...  adresse1=12 RUE DE LA RÉPUBLIQUE
    ...  cp=99678
    ...  ville=LIBREVILLE
    Ajouter le concessionnaire dans le contexte de la concession  ${concessionnaire_2}  ${concession05_id}

    &{concessionnaire_3} =  Create Dictionary
    ...  nom=SANSTITRE
    ...  marital=NOMMARI
    ...  prenom=TO
    ...  datenaissance=11/01/1980
    ...  adresse1=12 RUE DE LA RÉPUBLIQUE
    ...  adresse2=RUE TEST
    ...  cp=99678
    ...  ville=LIBREVILLE
    Ajouter le concessionnaire dans le contexte de la concession  ${concessionnaire_3}  ${concession05_id}

    # On ajoute un courrier
    &{courrier_edition} =  Create Dictionary
    ...  datecourrier=04/07/2019
    ...  contexte=autre
    ...  lettretype=titre_de_recettes courrier_test_emplacement_${TESTID}
    Ajouter le courrier dans le contexte de la concession  ${courrier_edition}  ${concession05_id}
    # On vérifie que les champs de fusion fonctionnent
    Wait Until Keyword Succeeds  ${TIMEOUT}  ${RETRY_INTERVAL}  Click On SubForm Portlet Action  courrier  pdf-edition  new_window
    ${contenu_pdf} =  Create List  ${concession05_id} ${concession05.nature_emplacement} ${concession05.numero} ${concession05.complement} ${concession05.voielib} [${concession05.zonelib}][${concession05.cimetierelib}] ${concession05.famille}  ${concession05.typeconcession} ${concession05.terme} ${concession05.duree} ${concession05.datevente} ${concession05.emplacement_date_terme} ${concession05.duree_lettre} ${concession05.sepulturetype} ${zone01_cim01.zonelib}
    Vérifier Que Le PDF Contient Des Strings  ${OM_PDF_TITLE}  ${contenu_pdf}

    # On modifie le type de sépulture pour remplir le champ libelle_edition
    &{sepulturetype_args} =  Create Dictionary
    ...  libelle_edition=Caveau
    Modifier le *type de sépulture*  ${type_de_sepulture_01.id}  ${sepulturetype_args}
    Depuis l'onglet 'courrier' de la concession  ${concession05_id}
    Click Element  link:${courrier_edition.datecourrier}
    # On vérifie que les champs de fusion fonctionnent
    Wait Until Keyword Succeeds  ${TIMEOUT}  ${RETRY_INTERVAL}  Click On SubForm Portlet Action  courrier  pdf-edition  new_window
    # On remplace le libelle du type de sepulture de l'emplacement par le contenu du champ libelle_edition
    ${contenu_pdf} =  Create List  ${concession05_id} ${concession05.nature_emplacement} ${concession05.numero} ${concession05.complement} ${concession05.voielib} [${concession05.zonelib}][${concession05.cimetierelib}] ${concession05.famille}  ${concession05.typeconcession} ${concession05.terme} ${concession05.duree} ${concession05.datevente} ${concession05.emplacement_date_terme} ${concession05.duree_lettre} ${sepulturetype_args.libelle_edition}
    Vérifier Que Le PDF Contient Des Strings  ${OM_PDF_TITLE}  ${contenu_pdf}

    # Vérification du champ de fusion "[emplacement.concessionnaires_avec_civilites]"
    # qui affiche la liste des concessionnaires
    Depuis le listing des lettres-types
    # On accède à la copie de la letttre type et on saisit les champs de fusion à tester
    Click Element  link:courrier_test_emplacement_${TESTID}
    Wait Until Keyword Succeeds  ${TIMEOUT}  ${RETRY_INTERVAL}  Click On Form Portlet Action  om_lettretype  modifier
    ${champs_fusions_emplacement} =  Set Variable  [emplacement.concessionnaires_avec_civilites]
    Saisir la lettre-type  null  null  null  ${champs_fusions_emplacement}  null  true  null  null
    Click On Submit Button
    Valid Message Should Contain  Vos modifications ont bien été enregistrées.

    Depuis l'onglet 'courrier' de la concession  ${concession05_id}
    Click Element  link:${courrier_edition.datecourrier}
    # On vérifie que les champs de fusion fonctionnent
    Wait Until Keyword Succeeds  ${TIMEOUT}  ${RETRY_INTERVAL}  Click On SubForm Portlet Action  courrier  pdf-edition  new_window
    ${chaine_concessionnaire_1} =  Catenate  SEPARATOR=   ${concessionnaire_1.titre} ${concessionnaire_1.prenom} ${concessionnaire_1.nom},
    ${chaine_concessionnaire_2} =  Catenate  SEPARATOR=   ${concessionnaire_2.titre} ${concessionnaire_2.prenom} ${concessionnaire_2.nom},
    ${chaine_concessionnaire_3} =  Catenate  SEPARATOR=   ${concessionnaire_3.prenom} ${concessionnaire_3.marital} né(e) ${concessionnaire_3.nom}
    ${contenu_pdf} =  Create List  ${chaine_concessionnaire_1}  ${chaine_concessionnaire_2}  ${chaine_concessionnaire_3}
    Vérifier Que Le PDF Contient Des Strings  ${OM_PDF_TITLE}  ${contenu_pdf}

    # Vérification du champ de fusion "[emplacement.concessionnaires_avec_titre_et_adresse]"
    # qui affiche la liste des concessionnaires avec leur titre et leur adresse
    Depuis le listing des lettres-types
    # On accède à la copie de la letttre type et on saisit les champs de fusion à tester
    Click Element  link:courrier_test_emplacement_${TESTID}
    Wait Until Keyword Succeeds  ${TIMEOUT}  ${RETRY_INTERVAL}  Click On Form Portlet Action  om_lettretype  modifier
    ${champs_fusions_emplacement} =  Set Variable  [emplacement.concessionnaires_avec_titre_et_adresse]
    Saisir la lettre-type  null  null  null  ${champs_fusions_emplacement}  null  true  null  null
    Click On Submit Button
    Valid Message Should Contain  Vos modifications ont bien été enregistrées.

    Depuis l'onglet 'courrier' de la concession  ${concession05_id}
    Click Element  link:${courrier_edition.datecourrier}
    # On vérifie que les champs de fusion fonctionnent
    Wait Until Keyword Succeeds  ${TIMEOUT}  ${RETRY_INTERVAL}  Click On SubForm Portlet Action  courrier  pdf-edition  new_window
    ${chaine_concessionnaire_1} =  Catenate  SEPARATOR=   ${concessionnaire_1.titre} ${concessionnaire_1.prenom} ${concessionnaire_1.nom} demeurant au ${concessionnaire_1.adresse1} ${concessionnaire_1.cp} ${concessionnaire_1.ville},
    ${chaine_concessionnaire_2} =  Catenate  SEPARATOR=   ${concessionnaire_2.titre} ${concessionnaire_2.prenom} ${concessionnaire_2.nom} demeurant au ${concessionnaire_2.adresse1} ${concessionnaire_2.cp} ${concessionnaire_2.ville},
    ${chaine_concessionnaire_3} =  Catenate  SEPARATOR=   ${concessionnaire_3.prenom} ${concessionnaire_3.marital} né(e) ${concessionnaire_3.nom} demeurant au ${concessionnaire_3.adresse1} ${concessionnaire_3.adresse2} ${concessionnaire_3.cp}
    ${contenu_pdf} =  Create List  ${chaine_concessionnaire_1}  ${chaine_concessionnaire_2}  ${chaine_concessionnaire_3}  ${concessionnaire_3.ville}
    Vérifier Que Le PDF Contient Des Strings  ${OM_PDF_TITLE}  ${contenu_pdf}

Vérification du bon fonctionnement du plan en coupe (paramétrage et déplacement des défunts)
    [Documentation]  Permet de vérifier que l'accès au plan en coupe est fonctionnel
    ...  Ajout d'un type de sépulture au format 2 colonnes * 2 lignes.
    ...  Ajout d'un emplacement avec le type de sépulture contenant le nouveau format
    ...  Ajout de défunts dans l'emplacement.
    ...  Vérification de l'accès au plan en coupe.
    ...  Déplacement d'un défunt.
    ...  Vérification de l'ajout et de la suppression du vide sanitaire sur l'emplacement.
    ...  Vérification du message d'erreur lors de la suppression de colonnes et de lignes
    ...  où un défunt est positionné.

    Depuis la page d'accueil  admin  admin

    # Ajout de l'emplacement
     &{concession_pec} =  Create Dictionary
    ...  famille=DUPONT${testid}pec
    ...  numero=15
    ...  cimetierelib=${cimetiere01.cimetierelib}
    ...  zonelib=${zone01_cim01.zonetype} ${zone01_cim01.zonelib}
    ...  voielib=${voie01_zone01_cim01.voietype} ${voie01_zone01_cim01.voielib}
    ${concessionpec.id} =  Ajouter la concession  ${concession_pec}

    Set Suite Variable  ${concession_pec}

    # On vérifie que l'action du plan en coupe n'est pas présente sur la fiche de l'emplacement
    Depuis le contexte de la concession  ${concessionpec.id}
    Portlet Action Should Not Be In Form  concession  plan-en-coupe

    # Ajout du type de sépulture comportant 2 colonnes et 2 lignes pour le plan en coupe
    &{type_de_sepulture_pec} =  Create Dictionary
    ...  code=TDS-${testid}-pec
    ...  libelle=Type de sépulture 2*2
    ...  colonne=2
    ...  ligne=2
    ${type_de_sepulture_pec.id} =  Ajouter le *type de sépulture*  ${type_de_sepulture_pec}

    &{type_de_sepulture_pec2} =  Create Dictionary
    ...  code=TDS-${testid}-pec2
    ...  libelle=Type de sépulture 2*2 Mieux
    ...  colonne=2
    ...  ligne=2
    ${type_de_sepulture_pec2.id} =  Ajouter le *type de sépulture*  ${type_de_sepulture_pec2}

    Set Suite Variable  ${type_de_sepulture_pec}

    # On modifie l'emplacement pour ajouter le type de sépulture contenant les dimensions
    &{concession_pec_modif} =  Create Dictionary
    ...  sepulturetype=${type_de_sepulture_pec.libelle}
    Modifier la concession  ${concessionpec.id}  ${concession_pec_modif}

    # On vérifie que l'action du plan en coupe est présente sur la fiche de l'emplacement
    Depuis le contexte de la concession  ${concessionpec.id}
    Portlet Action Should Be In Form  concession  plan-en-coupe

    # On accède au plan en coupe et on vérifie qu'il n'y a pas d'erreur
    Click On Form Portlet Action  concession  plan-en-coupe
    La page ne doit pas contenir d'erreur

    # On ajoute deux défunts dans l'emplacement
    &{defunt_pec_01} =  Create Dictionary
    ...  titre=Monsieur
    ...  nom=LOLA${testid}PEC
    ...  prenom=LOLPEC
    ...  datenaissance=01/04/1981
    ...  lieunaissance=ARLES
    ...  datedeces=25/05/2020
    ...  lieudeces=LIBREVILLE
    ...  parente=LOLO
    ...  nature=cercueil
    Ajouter le defunt dans le contexte de la concession  ${defunt_pec_01}  ${concessionpec.id}
    ${id_defunt_pec_01} =  Get Value  css=div.defunt-form #defunt

    &{defunt_pec_02} =  Create Dictionary
    ...  titre=Monsieur
    ...  nom=LOLO${testid}PEC
    ...  prenom=LOLOPEC
    ...  datenaissance=01/08/1981
    ...  lieunaissance=ARLES
    ...  datedeces=25/12/2020
    ...  lieudeces=LIBREVILLE
    ...  parente=LOLO
    ...  nature=cercueil
    Ajouter le defunt dans le contexte de la concession  ${defunt_pec_02}  ${concessionpec.id}
    ${id_defunt_pec_02} =  Get Value  css=div.defunt-form #defunt

    # On accède au plan en coupe et on vérifie que les défunts sont positionné dans la colonne de gauche
    # en dehors de la grille
    Depuis le contexte de la concession  ${concessionpec.id}
    Click On Form Portlet Action  concession  plan-en-coupe
    # Les cartes des défunts sont identifiées avec id="widget_<id_defunt>"
    # La colonne listant les défunts non positionnés a pour identifiant id="column"
    Element Should Contain  css=#column  ${id_defunt_pec_01} - ${defunt_pec_01.nom} ${defunt_pec_01.prenom}
    Element Should Contain  css=#column  ${id_defunt_pec_02} - ${defunt_pec_02.nom} ${defunt_pec_02.prenom}

    # Déplacement du deuxième défunt sur la case 1;2 dans le plan en coupe en utilisant l'action 11 de défunt
    Go To  ${PROJECT_URL}app/index.php?module=form&obj=defunt&action=11&idx=${id_defunt_pec_02}&x=1&y=2&validation=1

    # Vérification du positionnement des défunts
    Depuis le contexte de la concession  ${concessionpec.id}
    Click On Form Portlet Action  concession  plan-en-coupe
    Element Should Contain  css=#column  ${id_defunt_pec_01} - ${defunt_pec_01.nom} ${defunt_pec_01.prenom}
    Element Should Contain  css=.column_1_2  ${id_defunt_pec_02} - ${defunt_pec_02.nom} ${defunt_pec_02.prenom}

    # On modifie l'emplacement pour ajouter le vide sanitaire
    &{concession_pec_modif} =  Create Dictionary
    ...  videsanitaire=Oui
    Modifier la concession  ${concessionpec.id}  ${concession_pec_modif}

    # Le défunt positionné doit être déplacé d'une ligne
    Depuis le contexte de la concession  ${concessionpec.id}
    Click On Form Portlet Action  concession  plan-en-coupe
    Element Should Contain  css=#column  ${id_defunt_pec_01} - ${defunt_pec_01.nom} ${defunt_pec_01.prenom}
    Element Should Contain  css=.column_1_3  ${id_defunt_pec_02} - ${defunt_pec_02.nom} ${defunt_pec_02.prenom}

    # Déplacement du deuxième défunt dans le vide sanitaire case 1;1
    Go To  ${PROJECT_URL}app/index.php?module=form&obj=defunt&action=11&idx=${id_defunt_pec_02}&x=1&y=1&validation=1

    Depuis le contexte de la concession  ${concessionpec.id}
    Click On Form Portlet Action  concession  modifier
    Select From List By Label  css=#videsanitaire  Non
    Click On Submit Button
    Error Message Should Contain  Le vide sanitaire ne peut pas être supprimé car des défunts sont placés à l'intérieur.

    # Déplacement du deuxième défunt en dehors du vide sanitaire case 2;2
    Go To  ${PROJECT_URL}app/index.php?module=form&obj=defunt&action=11&idx=${id_defunt_pec_02}&x=2&y=2&validation=1

    # On modifie l'emplacement pour enlever le vide sanitaire
    &{concession_pec_modif} =  Create Dictionary
    ...  videsanitaire=Non
    Modifier la concession  ${concessionpec.id}  ${concession_pec_modif}

    # On modifie l'emplacement pour modifier le type de sépulture contenant les mêmes dimensions que le type précédent
    # La modification doit s'effectuer correctement
    &{concession_pec_modif} =  Create Dictionary
    ...  sepulturetype=${type_de_sepulture_pec2.libelle}
    Modifier la concession  ${concessionpec.id}  ${concession_pec_modif}

    &{concession_pec_modif} =  Create Dictionary
    ...  sepulturetype=${type_de_sepulture_pec.libelle}
    Modifier la concession  ${concessionpec.id}  ${concession_pec_modif}

    # Vérification du message d'erreur lors de la modification des colonnes et lignes du type de sépulture
    Depuis le contexte du *type de sépulture*  ${type_de_sepulture_pec.id}

    # Suppression d'une colonne -> KO
    Click On Form Portlet Action  sepulture_type  modifier
    Input Text  css=#colonne  1
    Click On Submit Button
    Error Message Should Contain  Le type de sépulture ne peut pas être modifié car des défunts sont placés dans les emplacements.

    # Ajout de deux colonnes -> OK
    Input Text  css=#colonne  6
    Click On Submit Button
    Valid Message Should Contain  Vos modifications ont bien été enregistrées.

    # Suppression d'une ligne -> KO
    Click On Form Portlet Action  sepulture_type  modifier
    Input Text  css=#ligne  0
    Click On Submit Button
    Error Message Should Contain  Le type de sépulture ne peut pas être modifié car des défunts sont placés dans les emplacements.

    # Ajout de deux lignes -> OK
    Input Text  css=#ligne  6
    Click On Submit Button
    Valid Message Should Contain  Vos modifications ont bien été enregistrées.

    # Suppression de la permission permettant de déplacer les défunts
    Depuis le listing  om_droit
    Use Simple Search  libellé  positionner
    Click On Link  defunt_positionner
    Click On Form Portlet Action  om_droit  supprimer
    Click On Submit Button

    Depuis le contexte de la concession  ${concessionpec.id}
    Click On Form Portlet Action  concession  plan-en-coupe
    ${class} =  Get Element Attribute  css=.column_1_1  class
    Should Contain  ${class}  column_locked

Vérification du bon fonctionnement du plan en coupe (verrouillage de cases et gestion des permissions)
    [Documentation]  Test case dépendant du précédent (on utilise le même type de sépulture)
    ...  Vérification du verrouillage des cases.
    ...  Vérification de la bonnes gestion des permissions

    Depuis la page d'accueil  admin  admin

    Depuis le contexte de la concession  ${concessionpec.id}

    Click On Form Portlet Action  concession  plan-en-coupe
    Element Should Be visible  css=#but_case_1_1
    ${class} =  Get Element Attribute  css=.column_1_1  class
    Should Contain  ${class}  cellUnlocked

    # Verrouillage de la case
    Click Button  css=#but_case_1_1

    Depuis le contexte de la concession  ${concessionpec.id}
    Click On Form Portlet Action  concession  plan-en-coupe
    Element Should Be visible  css=#but_case_1_1
    ${class} =  Get Element Attribute  css=.column_1_1  class
    Should Contain  ${class}  cellLocked

    Element Should Contain  css=.column_1_1 span  Emplacement verrouillé

    # Suppression de la permission permettant le verrouillage des cases
    Depuis le listing  om_droit
    Use Simple Search  libellé  verrouiller
    Click On Link  emplacement_verrouiller
    Click On Form Portlet Action  om_droit  supprimer
    Click On Submit Button

    Depuis le contexte de la concession  ${concessionpec.id}
    Click On Form Portlet Action  concession  plan-en-coupe
    Element Should Not Be visible  css=#but_case_1_1

Vérification de la présence ou non de certains champs sur les formualires du terrain communal
    [Documentation]  Vérification de la présence ou non de certains champs
    ...  sur les terrains communaux
    Depuis la page d'accueil  admin  admin
    # Consultation de l'exemble de terrain communal déjà présent
    Depuis le contexte du terrain communal  10
    Wait Until Keyword Succeeds  ${TIMEOUT}  ${RETRY_INTERVAL}  Click On Form Portlet Action  terraincommunal  modifier
    # Le champ numéro d'acte doit être présent dans le formulaire
    Element Should Be Visible  numeroacte
    Element Should Not Be Visible  typeconcession
    Element Should Not Be Visible  numerocadastre
    Element Should Not Be Visible  daterenouvellement
    Element Should Not Be Visible  sepulturetype