*** Settings ***
Resource  resources/resources.robot
Suite Setup  For Suite Setup
Suite Teardown  For Suite Teardown
Documentation  Tests de la table de paramétrage travaux_nature (nature de travaux).
...
...  Vérifie l'accès au listing et le CRUD de base.


*** Test Cases ***

Accès au listing des natures de travaux
    [Documentation]  Vérifie l'accès au listing des natures de travaux
    ...  depuis le menu Divers.
    Depuis la page d'accueil  admin  admin
    Depuis le listing des natures de travaux
    Le titre de la page doit être  Administration & Paramétrage > Divers > Nature Des Travaux
    La page ne doit pas contenir d'erreur

Ajout d'une nature de travaux
    [Documentation]  Crée une nature de travaux simple et vérifie le retour
    ...  de confirmation.
    Depuis la page d'accueil  admin  admin
    &{travaux_nature_035} =  Create Dictionary
    ...  code=TDT-035
    ...  libelle=Nature de travaux 035
    ${travaux_nature_035_id} =  Ajouter la nature de travaux  ${travaux_nature_035}
    Set Suite Variable  ${travaux_nature_035_id}
    Valid Message Should Contain  Vos modifications ont bien été enregistrées.

Modification d'une nature de travaux
    [Documentation]  Modifie le libellé d'une nature de travaux existante.
    Depuis la page d'accueil  admin  admin
    &{travaux_nature_modif} =  Create Dictionary
    ...  libelle=Nature de travaux 035 modifiée
    ...  description=Description ajoutée par le test
    Modifier la nature de travaux  ${travaux_nature_035_id}  ${travaux_nature_modif}
    Valid Message Should Contain  Vos modifications ont bien été enregistrées.

Suppression d'une nature de travaux
    [Documentation]  Supprime la nature de travaux créée dans cette suite.
    Depuis la page d'accueil  admin  admin
    Supprimer la nature de travaux  ${travaux_nature_035_id}